[原创]：Autolisp编程心得
院里搞形式主义，要求没人每年交一篇论文，并不少于3000字。刚好想写点什么，就使劲拼凑一下，敷衍一篇，过几天交上去，先贴出来，让大家提提意见。都是个人心得，不怕贻笑大方，权当抛砖引玉吧。Autolisp编程心得
1.养成良好的书写习惯
众所周知，Lisp是一种表结构语言，括号必须成对出现，在调试时往往为遗漏了一个括号大
费周折，所以，养成一个好的编程习惯是学好Lisp所必须的。
⑴选择一个较好的编辑器，这是一个基本条件，建议使用Visual Lisp编辑器或Lisplink等
专用编辑器，此类编辑器可以对函数突出显示。
⑵按Lisp（DCL）专有格式书写，并经常对程序进行“格式化”，及时发现语法错误，并有
利于调试是查找错误。
⑶使用自定义函数，并辅助以适当得注释，在较大程序中按功能使用自定义函数可以使得程
序条理化。
2.函数中循环与转移的使用
在高级语言中一般有类似“goto”的语句实现转移，在AutoLisp中没有转移的函数。我们可
以使用自定义函数实现转移，用if及cond辅助实现条件转移。
当我们需要实现在满足一定条件时进行循环的功能，一般使用while函数，但有时需要判断
的条件较复杂时，使用while函数往往不能实现或使得程序不够简洁。这时我们可以使用“转移”，
将需要实现的功能作为（子）函数，使用恰当，可以在程序中任意“转移”。
一般认为，当一段代码在不同处重复使用时，我们才会使用子函数定义，其实，利用函数的
更大的优点是使得程序更加结构化。这就使得我们不必拘泥于程序中的循环语句，而使用函数的
循环调用，辅助适当的判断，实现“转移”，如A->B->A。当然也可以进行自身调用，构成一个
“标准的”循环。
如例一中，“程序执行完毕返回”与“空选返回”两种情况如果使用循环语句，其条件是完
全不同的，而将函数本身作为子函数调用，程序简洁明了。
3.initget函数中关键字“ ”（空格）的使用
空格可以被用作关键字，一般多用来定义鼠标右键退出。
⑴当用户输入函数不支持控制位（如entsel、nentsel、nentselp）时，可直接使用
“(initget " ")”。
⑵当用户输入函数支持控制位（如getpoint等）时，可使用“(initget 1 " ")”禁止空输
入，而将回车等空输入作为关键字使用。
⑶当同时使用其它关键字时，应该将空格作为一系列关键字的最后一个，用
“(initget "C")”（两个空格）调用，否则无效。
见例一。
************************************************
;;例一
(defun ett_ct()
(initget "C") ;关键字“C”及空格
(setq s0 (entsel "\n设置颜色C / 选取文本:"))
(cond
( (= s0 "C") (ett_col)) ;转设置颜色子函数
( (= s0 "") nil) ;空格退出
( (and (= (type s0) 'LIST) ;选择实体
(= (cdr (assoc 0 (entget (car s0)))) "TEXT") ;判别文本
)
... ;操作内容
(ett_ct) ;编辑后返回选择
)
(t (ett_ct)) ;空选返回选择
)
)
************************************************
有时需要进行复杂的判断，使用如“(= s0 "")”语句可能不能准确判别输入的空格关键字
与空选择，可以使用“(= (type s0) 'STR)”语句。
4.Lisp的暂停与while的特殊使用
Lisp一般在交互输入时才会暂停，如果只需要实现屏幕显示暂停，可使用grread函数，
grread函数对所有合法的输入设备均会作出反应，有时我们只希望对键盘有反应，可使用while
函数进行循环。
*******************
(princ "\nPress ENTER to continue:")
(while (/= (car (grread)) 2))
*******************
while用于满足一定条件的循环，其标准语法为：
(while testexpr )
其中expr解释为“在 testexpr 为 nil 之前要求值的一个或多个表达式”，为可选项（在
R14之前没有方括号，但仍为可选项）。
正常我们使用while时，总会有expr项，更多的时候，我们是为了expr项才会使用这种循环
语句，所有我们往往有expr项是不可缺少的感觉。这里我们使用while函数的语法是while函数的
特例，即没有expr项的情况。
如果希望对鼠标右键同时反应，可以使用：
*******************
(princ "\nPress ENTER to continue:")
(while (and (/= (setq a(car (grread))) 2) ;键盘
(/= a 11) ;鼠标右键（SHORTCUTMENU＝0）
(/= a 25) ;鼠标右键（SHORTCUTMENU≠0）
)
)
*******************
5.输入距离
Lisp语言中输入距离的函数为getdist，但我们有时需要输入负值，有时需要在输入距离的
同时得到角度，使用getdist函数就显得无能为力，这时，我们可以灵活使用其它交互输入函数
如getpoint、getcorner等，通过计算得到我们所需要的值。
例二是一段输入长度的同时得到默认角度的代码，使用getpoint函数。
************************************************
;;例二
(setq pt0(getpoint "\n直线基点: ")
pt1(getpoint pt0 "\n直线长度: ") ;长度及角度可用键盘或鼠标定位
dst(distance pt0 pt1) ;计算长度
ang(angle pt0 pt1) ;计算默认角度
ang1 (getangle pt0 (strcat "\n直线方向<" (angtos ang 1) ">: "))
)
************************************************
例三是可以按阵列方式输入行列间距的代码，输入距离为正值，修改部分代码可输入负值，
使用getcorner函数，同时使用initget的控制位128。
************************************************
;;例三
(defun lc_dist ()
(initget 128) ;允许任意输入
(setq disr (getpoint "\n指定单位单元或输入行间距: "))
(if (= (type disr) 'LIST) ;鼠标输入
(progn
(initget 1)
(setq dis (getcorner disr "\n指定对角点: ") ;鼠标输入对角
disc (abs (- (car dis) (car disr))) ;正值行距
disr (abs (- (cadr dis) (cadr disr))) ;正值列距
) ;计算行列间距
)
(if (= (type disr) 'STR) ;键盘输入行距
(if (setq dis (distof disr)) ;判断输入的是否距离
(progn
(initget 6)
(setq disc (getdist "\n输入列间距: ")) ;输入列距
)
(progn ;键盘输入格式不符返回
(princ "\n需要正数值或两个二维角点。")
(lc_dist)
)
)
(progn ;空输入返回
(princ "\n需要正数值或两个二维角点。")
(lc_dist)
)
)
)
)
************************************************
6.数学运算函数的数量界限
在Lisp中对表中数据进行求和、求最大值等数学运算时，往往直观的对表直接赋予运算函数，
使用语句如“(eval (cons 'MAX numlist))”，一般都可以进行计算，但当表中数据数量大于
255时，将会出现错误“bad argument value: does not fit in byte: 256”。
对于这种情况，我们不必对数据表进行分段，可以直接使用函数apply，语法更简单：(apply
'MAX numlist)。apply可将数据表传送给指定的函数进行求值而不受数据数量的影响。
受表中数据数量影响的数学运算函数有：+、-、*、/、max、min、logand及logior。
7.选择集与表
选择集是一种特殊结构的表，只能通过特定的函数进行操作，但这些函数对大量重复的操作
只能通过循环实现，显得力不从心，不能体现Lisp语言表结构的优越性。
其实我们只要通过存取实体名或实体句柄，将它们存为一个普通结构的表，完全可以通过常
规表操作函数实现对实体的操作。
例四是一段使用apply、mapcar函数联合求文本选择集中文本基点最大y值得代码，只是一个
示例，如果结合VL-sort函数，可轻松实现对文本的排序。
************************************************
;;例四
(setq sl nil i-1)
(repeat (sslength (setq ss (ssget '((0 . "TEXT"))))) ;选择文本
(setq i(1+ i)
en (ssname ss i) ;从选择集中取出文本
sl (cons en sl) ;构造包含实体名的表
)
)
(setq maxy (apply 'max ;求文本基点最大y值
(mapcar
'(lambda (x)
(caddr (assoc 10 (entget x))) ;提取y值
)
sl
)
)
)
************************************************
当然，选择集也有其优势的一面，比如对选择集中实体的删除操作非常简单、选择集中的实
体不会重复及选择集可以与Acad命令交互使用等特征是一般表所不具备的，所以，编程时应根据
程序要求，灵活运用。
8.cal的使用与加载
Acad随机附带了一些外部定义命令，其中cal（计算器）命令是最常用的命令之一，在加载
gromcal.arx后cal可以在Lisp程序中像其它函数一样使用，这就使得我们在程序中对文本的四则
运算处理变得简单，如“(cal "1+2/3")”，其中字符串"1+2/3"可以从图形的文本中提取，也可
以是符合cal要求格式的任一字符串（详见Acad联机帮助）。
需要注意的是，在Acad中gromcal.arx只能加载一次，重复加载将使Acad以外退出（无提示）。
需要使用cal函数的Lisp程序，应在程序尾部加上以下代码：
*******************
(if (or (= (type c:cal) 'LIST) ;R14使用
(= (type c:cal) 'SUBR) ;R2000+使用
)
(arxload "geomcal.arx")
)
*******************
9.Undo处理
一个完善的程序应该有较好的出错处理，这是在所有Lisp教材上都提及的，但程序的Undo处
理就说得很少或没有提及。
其实Undo处理对程序来说也是非常重要的，尤其对有较多输出的复杂程序而言，不能解决
Undo问题，使用起来会极不方便。
对于Undo问题的解决，一种方法是尽量少用或不用command函数，即不调用原始命令，这是一
种较好的方法，但必须注意的是，一段程序必须至少有一次调用command函数，否则Undo命令将取
消程序运行前的前一次命令，解决的方法是在程序运行的起始位置加一个无谓的command，如
“(command "color" "")”。
有时不使用command函数不能达到我们要求的一些功能，或使得程序过于复杂，我们可能需要
使用一些command函数（原始命令），这是就应该在程序中进行Undo处理，即使用Undo命令的编组
功能。
例五是一段程序出错函数与Undo处理的示例。
************************************************
;;例五
(defun newerr (s) ;出错函数
(if s
(progn
(term_dialog) ;使用对话框时使用
(if olderr (setq *error* olderr)) ;出错函数恢复
(if oldvar (setvar ... oldvar)) ;系统变量恢复
(if olderr (setq *error* olderr)) ;出错函数恢复
(command "_.undo" "_e") ;Undo编组结束
)
)
(princ)
)
(defun c:my(/ ...) ;主程序（主函数）
(setvar "cmdecho" 0) ;取消命令回显提示
(command "_.undo" "_BE") ;Undo编组开始
(setq olderr *error* *error* newerr) ;调用自定义出错函数
(setq oldvar (getvar ...)) ;保存相关系统变量
(setvar ... ;设置系统变量
... ;程序段
...
(setvar ... oldvar) ;恢复系统变量
(setq *error* olderr) ;恢复出错函数
(command "_.undo" "_E") ;结束Undo命令编组
(princ) ;取消程序返回值
)
************************************************
10.程序调试是块注释的使用
我们经常会加上或屏蔽一段代码辅助程序调试，此时最常用的是在需要暂时屏蔽的代码前使
用行注释符号“;”，对于较多的代码就需要使用块注释“;|——|;”，如果一段代码需要频繁屏
蔽，将行注释与块注释组合使用，可以带来极大方便。
下图是组合使用的示例。
[分享]：LISP编程技巧之问答篇
要熟练应用VLISP编程，除多练多写外，平时还要注意积累一些编程技巧和一些实用函数，这样写程序时才能得心应手，从而达能事半功倍的效果。我先贴一篇，以抛砖引玉，希望大家把平时编程心得和收集的一些好技巧贴上来大家分享吧。
[
Vlisp编程技巧摘要(1)
;;;**********************************************************
1.如何获取多义线上的所有顶点
Code:
(defun C:getp (/ ent PLTYPE obj vtx vtxlst n ptlst)
(vl-load-com)
(setq ent (entsel "\n选取多线<Exit>:\n"))
(if ent
(progn
(setq PLTYPE (cdr (assoc 0 (entget (car ent)))))
(if (or (= "POLYLINE" PLTYPE) (= "LWPOLYLINE" PLTYPE))
(progn
(setq obj (vlax-ename->vla-object (car ent)))
(setq vtx (vla-get-Coordinates obj))
(setq vtxlst (vlax-safearray->list (vlax-variant-value vtx)))
(setq n 0)
(setq ptlst nil)
(repeat (/ (length vtxlst) 2)
(setq ptlst (append ptlst (list (list (nth n vtxlst) (nth (1+ n) vtxlst)))))
(setq n (+ n 2))
)
(if ptlst ptlst nil)
)
(prompt "\n选取实体不是多义线!")
);if
)
);if
)
;;;**********************************************************
2.在对话框的文本栏里输入，怎样让它实时显示为密码“ * ”？
A.设计对话框时，控件的属性中加：password_char = "*";
srt : dialog {
label = "密码" ;
: edit_box {
label = "输入密码(&S):";
key = "password";
password_char = "*";
fixed_width = true;
width = 8;
}
ok_only;
}
(defun c:srt ( )
(setq filename "srt.dcl")
(if (> (setq index_value (load_dialog filename)) 0) ;装载对话框
(progn
(setq dlgname "srt")
(if (not (new_dialog dlgname index_value)) (exit));显视对话框
(action_tile "password" "(mypass)")
(action_tile "ok" "(done_dialog 0)")
(start_dialog)
)
(alert "\n不能载装指定的DCL文件定义的对话框!")
);;;END IF
(princ)
)
(defun mypass ()
(setq a1 $value)
)
B.使用DOSLib输入密码的函数
;;;********************************************************
3.怎样可以实现不用工具中的选项，来调出屏幕菜单？
;;屏幕菜单切换
(defun C:pmmenu ()
(vl-load-com)
(setq sd
(vla-get-display
(vla-get-preferences (vlax-get-acad-object))
)
)
(if (= (vla-get-displayscreenmenu sd) :vlax-true)
(vla-put-displayscreenmenu sd :vlax-false)
(vla-put-displayscreenmenu sd :vlax-true)
)
(vlax-release-object sd)
(princ)
)
;;********************************************************
4.怎么样用Vlisp来读取AutoCAD中搜索路径?
(vla-get-supportpath (vla-get-files (vla-get-preferences (vlax-get-acad-object))))
或：
(getenv "ACAD")
或：
(acet-pref-supportpath-list)获取支持路径。
;;********************************************************
5.如何捕获列表框（list_box）的双击操作?
在edit_box,list_box,image_button,slider中，有一个$reason变量，用来
表示你执行了什么操作 。在list_box中，双击的变量值是4。
可在你的代码中加入判断：
(action_tile "listbox" "(fun1).....")
(defun fun1()
.....
(if (= $reason 4)
.....
)
.....
)
;;********************************************************
6.如何用VLISP创建目录？
例如：
A. (vl-mkdir "c:\\hqd9639")
B. (setq SYS (vlax-create-object "Scripting.FileSystemObject"))
(setq FOLDER (vlax-invoke-method SYS 'CREATEFOLDER "c:\\hqd9639"))
;;********************************************************
7.如何用(entsel)亮显选择物体?
code:
(if (setq ent (entsel "\nPick Object"))
(progn
(redraw (car ent) 3)
;;(redraw (car ent) 4);;;不亮显
)
)
;;********************************************************
8.如何隐藏选择实体?
code:
(if (setq ent (entsel "\nPick Object"))
(progn
(redraw (car ent) 1);;;隐藏实体
;;(redraw (car ent) 2);;;显示实体
)
)
;;********************************************************
9.状态栏进度条的设计示例
(defun c:hqd1 ()
(acet-ui-progress "已经完成" 100)
(setq x 0)
(while (< x 100)
(princ (strcat "\n" (itoa x)))
(acet-ui-progress -1)
(setq x (1+ x))
)
(acet-ui-progress)
)
;;********************************************************
10. 如何用VLISP获取所有配置文件(Profiles)列表?
code:
(defun c:getAllProfiles ()
(setq a (vla-get-profiles (vla-get-preferences (vlax-get-acad-object))))
(vla-GetAllProfileNames a 'hqd)
(if hqd (setq lst (vlax-SafeArray->List hqd)))
)
;;********************************************************
11.如何在CAD中插入时间和日期?
Code:
(defun C:inttime()
(setq pt0 (getpoint "\n请指定插入位置点 :"))
(setq date0 (menucmd "M=$(edtime,$(getvar,date), DD.MM.YYYY hh:mm:ss)"))
(command "text" "j" "m" pt0 5.0 0 date0)
(princ)
)
;;********************************************************
12.如何用LISP打开WINDOWS的选择目录对话框?
方法有5种:
a.(setq bmpdir (xdrx_getdir "选择目录" "" "请选取目录" ))
b.(dos_getdir "选择目录:" "c:\\")
c.(setq picdir (Odcl_BrowseFolder "选取文件目录"""))
d.(acet-ui-pickdir "选择目录" "" "请指定目录")
e:
Code:
(defun qf_getFolder (msg / WinShell shFolder path catchit)
(vl-load-com)
(setq winshell (vlax-create-object "Shell.Application"))
; (vlax-dump-object winshell T)
(setq shFolder (vlax-invoke-method WinShell 'BrowseForFolder 0 msg 1))
(setq
catchit (vl-catch-all-apply
'(lambda ()
(setq shFolder (vlax-get-property shFolder 'self))
(setq path (vlax-get-property shFolder 'path))
)
)
)
(if (vl-catch-all-error-p catchit)
nil
path
)
)
;;********************************************************
看樓主很有心得,請問您都編了那些方面的程序(沒有不敬之意) ************************************************
;;例一
(defun ett_ct()
(initget "C") ;关键字“C”及空格
(setq s0 (entsel "\n设置颜色C / 选取文本:"))
(cond
( (= s0 "C") (ett_col)) ;转设置颜色子函数
( (= s0 "") nil) ;空格退出
( (and (= (type s0) 'LIST) ;选择实体
(= (cdr (assoc 0 (entget (car s0)))) "TEXT") ;判别文本
)
... ;操作内容
(ett_ct) ;编辑后返回选择
)
(t (ett_ct)) ;空选返回选择
)
)
************************************************
其中(setq s0 (entsel "\n设置颜色C / 选取文本:"))
正确的写法应该是：(setq s0 (entsel "\n设置颜色C /< 选取文本>:"))
;;例五
(defun newerr (s) ;出错函数
(if s
(progn
(term_dialog) ;使用对话框时使用
(if olderr (setq *error* olderr)) ;出错函数恢复
(if oldvar (setvar ... oldvar)) ;系统变量恢复
(if olderr (setq *error* olderr)) ;出错函数恢复
(command "_.undo" "_e") ;Undo编组结束
)
)
(princ)
)
...
我认为if语句是不必要的
另外可以直接
(defun *error* (s) .....)
这句(setq olderr *error* *error* newerr)改为 (setq olderr *error* )就可以了 最初由 陌生人 发布
************************************************
;;例一
(defun ett_ct()
(initget "C") ;关键字“C”及空格
(setq s0 (entsel "\n设置颜色C / 选取文本:"))
...
第一个关于“<>”的问题是我疏忽，谢谢指正。
第二个关于“if”的问题，我这样理解，在Lisp程序中，改变系统变量与设置出错函数不应该在程序开始全部完成，应该根据不同的进程设置不同的系统变量或出错函数，这点对大的程序非常重要，而这时，就应该将原始的系统变量保存，但在程序出错时，可能有些变量还没有改变设置，也就是说“Oldvar”还没有被设置，此时执行“(setvar ... oldvar)”是错误的。文中例五中多了一句“(if olderr (setq *error* olderr)) ”，是本人疏忽。
第三个问题中“(setq olderr *error* *error* newerr)”出现在主程序开始，与例五的前半段“(defun newerr()....)”是对应的，其目的是将原来的出错函数保存，然后换成自己的出错函数。 例图里面的“取消屏蔽”是什么意思？ 在Lisp中使用“;”（引号）表示注释，这是书上有的，同样，Lisp也有“块”注释，使用“;|”及“|;”成对，这是一般书上没有的。在文中，我将这种功能引申利用与程序调试，当需要不执行其中一段代码时，可以使用这种方法，就像是“屏蔽”。当然，也可使用引号逐句“注释”，但对较长段就比较费事了。 我把另一主题合并过来了.找起来方便一点.
删了点贴，没扣分，捧场的话，老板不喜欢的.当然还是为了找起来方便一点.
欢迎大家续下去，有问题也先来看看.
不管原创还是整理。好贴以后给钱或分会增加一点的. 回應樓主
看了悄悄話得知您發了訊息給小弟,謝謝,小弟$不夠只能藉此回覆,先說報歉,
以下所言實有感而發
1.花了心血完成的東西教人使用,別人認為這是工作上你應該提供的,您做何
感想,使用上出了狀況,怪你教的不夠,您做何感想,當對方工作上需限時完
時才有求於你,您做何感想
2.的確,網路是個提供交流的地方,不管問題的深度如何,大家各取所需可以得到
自己想找的答案,但看看網上的發言,有多少人的問題在一本基礎的相關書籍
中就能找到答案,回想自己為了在cad的應用上能更上層樓,買了多少書籍,白
天上班,晚上寫程序,遇到難題先翻書找答案,花了五年的時間稍認為自己有
相當的功力,之後才上網尋求靈感,在此真的遇到不少高手,遇到不少狂妄之
輩,也遇到不少想不勞而獲之徒,但相信大多數是有困難而尋求幫助者
3.曾在此討論區看到某樓主好心分享心得,卻遭冷嘲熱諷,被譏太膚淺,卻不見班
主制止,而該樓主也在此網站消失了,試想原一位熱心想提供心得參與討論的
人,卻被一些狂妄之輩潑了一盆冷水,真是情何以堪,也有費心提出問題只為收
集他人的程序, 真深入問他問題想幫他解決時,他卻又無聲無息,遇此想不勞而
獲之徒,您會想提供原程序為他人做嫁嗎?
[讨论]：学习AUTOLISP程序设计的一点看法
虽然使用CAD绘图有了几年，但对于AUTOLISP程序却是一窍不通，最近终于有点时间可以去摸索一下，有了一些看法，愿和大家讨论。设计的实践中,我总结出(当然也参考了其他朋友的经验)了部分编程技巧,仅供大家参考!
1)加载程序之前应先判断文件是否已经被加载
在调用用户自己定义的函数之前,应先将包含该函数的文件调入内存(LOAD "文件").但如果每次调用前都加载该程序,则会浪费很多时间.因此判别文件是否已经调入内存,则是非常重要的,这种用法在菜单文件十分普遍
..
( if (not rectan) (load "les2"));(rectan);
..
在文件内同样可以实现同样的检测
2)抑制函数运行后返回nil
在一个Autolisp函数运行结束后，它常会在命令行上返回一个nil，令人遗憾。其实只要我们问在该函数的最后一行加上（PRINC）语句后，即可抑制nil的产生。
当然如果对需要一个结果的函数，则不可采用此法。
3）几个自动执行函数
a)加载自动执行函数
(defun s::startup()
...
)
一旦该函数在acad.lsp函数中定义,在autocad启动时,就会自动加载该函数.
b)存盘自动执行函数
定义
(defun S::save()
....
)
该函数与(s::startup)相似,在存储文件时将会被自动执行.例如:在保存文件时,对被保存文件生成备份文件等,就可能需要此功能文件
c)退出时自动执行文件
定义
(defun s::exit()
...
)
4)怎样判断两个实数相等
对于计算出来的实数,即使真的相等,但对计算机来说,其往往不是绝对相等(如2.00 与2.000就不等).因此判断其相等就需要采用差值方法
(equal expr1 expr2 )
其中任选项FUZZ指定表达式EXPR1 EXPR2 的最大允许差值.即如果实际差值小于FUZZ,则判断结果为真,反之为假.
(if (equal a b 0.001)
(prompt "These numbers are equal")
(prompt "These numbers are not equal")
)
5)取系统的环境变量
对编制自己的系统来说,最好将自己的所有编制程序集中在自己独立的目录下,如\acad\lisp等.然后在将该目录添加到ACAD环境中.
在自己编制的程序中,为了确保所要调用函数或文件在AUTOCAD的搜索路径下,就需要判断自己编制的程序目录是否在ACAD环境内.此时就要用(getnev)函数
如(setq nev (getenv "acad"))
其将返回ACAD系统环境,如"C:\\ACAD\\SUPPORT;C:\\ACAD\\FONTS;C:\\ACAD\\LISP 最初由 ll_j 发布
在Lisp中使用“;”（引号）表示注释，这是书上有的，同样，Lisp也有“块”注释，使用“;|”及“|;”成对，这是一般书上没有的。在文中，我将这种功能引申利用与程序调试，当需要不执行其中一段代码时，可以使用这种?..
其实cad帮助是最好的教科书,一般书上没有| 的用法,(其实我见到的很多书上还是有的)但是cad的帮助里面肯定是有的
以下是cad帮助的摘录:
VLISP 代码格式编排程序能识别五种类型的 AutoLISP 注释，并根据注释的类型确定其位置。
Visual LISP 注释格式
注释格式编排程序 设置格式后的外观
;| 行内 |; 外观和其他表达式一样，多行注释则要换行显示。
; 单个分号 开始于注释列位置，缩进位置与“单分号注释缩进”格式选项中的定义一致。
;; 当前列 换行显示，其缩进量和上一行程序代码相同。
;;; 顶头或 0 列 换行显示，无缩进。
;_ 函数结束 显示在前一个表达式后。
下例说明了每种注释样式：
文本最初为：
(defun foo (x)
;|inline comment |;
(list 1 2 3) ;comment-column comment
;;current-column comment
;;; heading or 0-column comment
) ;_ function-closing comment
设置格式以后：
(defun foo (x) ;|inline comment |;
(list 1 2 3) ;comment-column comment
;;current-column comment
;;; heading or 0-column comment
) ;_ function-closing comment 当你把开发的带有DCL文件的LSP程转交给他人使用时，一般要把两个文件分别交付。如果直接在LSP程序中创建DCL文件（一般也都比较小），再编译成FAS，然后再交给他人，那就只有一个文件了，而且表面上还可以对DCL文件加密（当然，程序运行时会泄密的，但不好好想想也不是那么容易发现的。）
简单举例：
(setq filename (vl-filename-mktemp "test.dcl")) ;创建DCL文件
(setq dclfile (open filename "a"))
(princ
"test :dialog{
:edit_box{
key = \"eb1\";}
:edit_box{
key = \"eb2\";}
:slider{ key =\"sld\";}
:button{
label= \"OK\";
key = \"ok\";
is_default=true;}
}" dclfile);写DCL文件
(close dclfile)
;主程序
(setq dcl_id1 (load_dialog filename))
(new_dialog "test" dcl_id1)
(action_tile "eb1" "(alert \"edit_box1回调！\")")
(action_tile "eb2" "(alert \"edit_box2回调！\")")
(action_tile "sld" "(alert \"slider回调！\")")
(action_tile "ok" "(done_dialog)")
(start_dialog)
(unload_dialog dcl_id1)
(vl-file-delete filename) ;删除DCL文件
顺便也提一个上例中的问题:当从eidt_box中出来点击slider时,为什么只有点击点击slider游标会激活edit_box的action，点击slider的其它部分则不会激活呢?怎么解决这个问题? 看到了大家以上的留言我也想了好多，由于我是初学autolisp的以前没有人教还不能上网，一天到晚拿着陈波雄老师的数学习。在单位领导不让回家又没有电脑只好晚上10以后再去上班来学习，想起那段苦日子也有一点点的欣慰我还是坚持了下去虽然现在的我水平不怎么样但是没有那段时间的话可能现在什么都不懂。和大家讲讲我刚开始学习的时候应该注意的问题吧
1要注意局域变量和全局变量的使用（我刚开始的时候嫌麻烦就不用局域变量，可是到最后呢机器不释放内存机器越来越慢和其它一些错误。）
2最好是定义每个变量的时候尽量不要重名。（我在以前都用 a s d f 等一些字母左变量时间长了所有的程序都是一样的，有的时候运行完程序发现不对才知道原来是和以前的一些变量冲突了。）
3要尽量的实用子函数因为那样会节省我们的调试时间。也更加的清晰了我们的编程思路。
我就先说到这里以上是我的一点心得，我不希望其它爱好者步我的后尘。
祝大家越学越好
谢谢斑竹的鼓励我以后会更加的努力为大家都做事情的。我太高兴了，这是我在晓东第一次收到鼓励。谢谢你aeo斑竹。谢谢 "LISPDOC"不止可以检查局部变量，索性用它作最后处理。
下面演示为本人喜欢用的方法： 最初由 陌生人 发布
LISPDOC哪儿有下载？
试试这个：
http://custom.lab.unb.br/pub/asme/AI/