[VBA程序]：SendMessage问题，请教斑竹！！

qren25

VBA程序中调用SendMessage来执行命令，命令执行过程中带有点和选择集，需要参数化传递，请问该如何编写？能否贴出段示例代码，先谢谢诸位！是否得用lisp函数先参数话字符串？
VBA刚入门，请教诸位了！
点和选择集的实际值都需要在过程中传递给Command，该怎样做？

雪山飞狐(lzh)

是SendCommand吧，用选择集只能用ActiveSelectionSet和PickfirstSelectionSet，点转化为"x,y"形式的字符串

qren25

应该是SendCommand,非常感谢！如果有相关实例能否贴一段上来？不情之请，不好意思

雪山飞狐(lzh)

快速选取一层的所有对象,进行相应的操作
Sub QSelLayerControl()
'程序功能:快速选取一层的所有对象,进行相应的操作
    Dim i  As AcadEntity
    Dim ss As AcadSelectionSet
    Dim ft(0) As Integer, fd(0)
    Dim pLayer As String
    Dim pControl As String
    pLayer = ThisDrawing.Utility.GetString(0, vbCrlLf & "请输入层名:")
    ft(0) = 8: fd(0) = pLayer
    Set ss = ThisDrawing.ActiveSelectionSet
    ss.Clear
    ss.Select acSelectionSetAll, , , ft, fd
    If ss.Count = 0 Then
        ss.Delete
        ThisDrawing.Utility.Prompt "层内没有对象或层不存在!"
    Else
        ThisDrawing.Utility.InitializeUserInput 1, "Move Copy Erase"
        pControl = ThisDrawing.Utility.GetKeyword(vbCr & "请输入操作名[Move(移动)/Copy(复制)/Erase(删除)]:")
        ThisDrawing.SendCommand "." & pControl & vbCr & "p" & vbCr & vbCr
    End If
'附:将下列代码Copy到acad200?doc.lsp中,执行命令QSLC
'    (defun C:QSLC()
'    (setvar "cmdecho" 0)
'    (command "-vbarun" "qsellayercontrol")
'    (setvar "cmdecho" 1)
'    (princ)
'    )
End Sub

雪山飞狐(lzh)

上面是选择集的例子，下面是点的例子
Sub lt()
Dim pnt, dot
pnt = ThisDrawing.Utility.GetPoint
dot = ThisDrawing.Utility.GetPoint
ThisDrawing.SendCommand ".Line" & vbCr & pnt(0) & "," & pnt(1) & vbCr & dot(0) & "," & dot(1) & vbCr & vbCr
End Sub

qren25

非常感谢斑竹！