[求助]：现在相编个程序能实现move功能的

zhouri

move功能不能保存前面的输入数据，我希望就是能每次移动相同的距离（水平或垂直），不永重复输入数据。求编程思想。

xyp1964

[php]
;|
mm.lsp 定距移动
* C:mm
-- XYP@bsedi.com
2004.12.04
|;
;;;加载mm.lsp，运行mm。
(prompt "\n\r      加载定距移动程序。")
;;;-------------------------------------------
;;;主程序
;;;*定距移动
(defun c:mm (/ ss1 pt1 pt2)
  (@cmdla0)
  (setvar "orthomode" 1)
  (setvar "osmode" 0)
  (princ "\n\t窗口选择 : ")
  (setq        NO2 (@ureal 1 "" "距离" NO2)
        Ss1 (ssget)
        pt1 (getpoint "\n\t起点 : ")
  )
  (while (setq pt2 (getpoint pt1 "\n\t方向<退出> : "))
    (if        (= (car pt1) (car pt2))
      (czyd)
      (spyd)
    )
    (YDST)
    (setq pt1 pt2)
  )
  (@cmdla0)
)
;;垂直移动
(defun czyd ()
  (if (> (cadr pt2) (cadr pt1))
    (setq pt2 (list (car pt1) (+ (cadr pt1) NO2)))
    (setq pt2 (list (car pt1) (- (cadr pt1) NO2)))
  )
)
;;水平移动
(defun spyd ()
  (if (> (car pt2) (car pt1))
    (setq pt2 (list (+ (car pt1) NO2) (cadr pt1)))
    (setq pt2 (list (- (car pt1) NO2) (cadr pt1)))
  )
)
;;移动实体
(defun YDST () (command "move" ss1 "" pt1 pt2))
;;;*

;;;-------------------------------------------
;;;通用子程序
(defun @CMDLA0 ()
  (setq cmdech (getvar "CMDECHO"))
  (setq oom (getvar "orthomode"))
  (setq osm (getvar "osmode"))
  (SETQ LA (getvar "clayer"))
  (setq rmode (getvar "regenmode"))
  (setq pw (getvar "plinewid"))
  (setvar "regenmode" 0)
  (setvar "CMDECHO" 0)
  (princ)
)
(defun @CMDLA1 ()
  (setvar "CMDECHO" cmdech)
  (setvar "orthomode" oom)
  (setvar "osmode" osm)
  (setvar "clayer" LA)
  (setvar "regenmode" rmode)
  (setvar "plinewid" pw)
  (princ)
)

(defun @ureal (bit kwd msg def / inp)
  (if def
    (setq msg (strcat "\n" msg "<" (rtos def 2) ">: ")
          bit (* 2 (fix (/ bit 2)))
    )
    (setq msg (strcat "\n" msg ": "))
  )
  (initget bit kwd)
  (setq inp (getreal msg))
  (if inp
    inp
    def
  )
)
(DEFUN @PXYP (TXT1)
  (SETQ        TXT1 (STRCAT "\n\r      程序命令: "
                     TXT1
                     "      -- xyp@bsedi.com"
             )
  )
  (PRINC TXT1)
  (Princ)
)
(@pxyp "mm  (定距移动)")
(princ)
;;;-------------------------------------------
;;;END
[/php]