[求助]：LISP程序实现DRAWING中的文字计算

likaizhang

DWG图形中的两个数字，我想先分别选择后赋值给两个变量，在将这两个变量进行相加计算后返回结果
应用LSP程序能否实现，请智者出招

hadeseyes

碰到类似问题,关注中

hi71400

这是我写的，将pkpm的柱剖面列表画法的两个分尺寸相加（合并）的函数
(defun zrh_att (n ss) (cdr (assoc n ss)))
defun c:zrh_txtplus (/ obj1 obj2 ent1 ent2 pt1 pt2 pt3 pt4 txt1 txt2)
  (command "_.undo" "_group")
  (setvar "cmdecho" 0)
  (while (and (setq obj1 (car (entsel "\n第一个数字：")))
              (setq obj2 (car (entsel "\n第二个数字：")))
         ) ;_ end of and
    (if        (= "TEXT"
           (zrh_att 0 (entget obj1))
           (zrh_att 0 (entget obj2))
        ) ;_ end of =
      (progn
        (setq ent1 (entget obj1)
              ent2 (entget obj2)
        ) ;_ end of setq
        (if (equal (zrh_att 50 ent1) (zrh_att 50 ent2) 1E-3)
          (progn
            (setq pt1  (zrh_att 10 ent1)
                  pt2  (zrh_att 11 ent1)
                  pt3  (zrh_att 10 ent2)
                  pt4  (zrh_att 11 ent2)
                  pt3  (zrh_mid pt1 pt3)
                  pt4  (zrh_mid pt2 pt4)
                  txt1 (zrh_att 1 ent1)
                  txt2 (zrh_att 1 ent2)
                  txt1 (itoa (+ (atoi txt1) (atoi txt2)))
            ) ;_ end of setq
            (setq ent1 (subst (cons 10 pt3) (assoc 10 ent1) ent1))
            (setq ent1 (subst (cons 11 pt4) (assoc 11 ent1) ent1))
            (setq ent1 (subst (cons 1 txt1) (assoc 1 ent1) ent1))
            (entmod ent1)
            (entdel obj2)
          ) ;_ end of progn
          (prompt "\n请选择相同方向的尺寸数字。")
        ) ;_ end of if
      ) ;_ end of progn
      (prompt "\n没有选择到尺寸数字。")
    ) ;_ end of if
  ) ;_ end of while
  (redraw)
  (command "_.undo" "_E")
  (princ)
) ;_ end of defun