[VBA程序]：请教高手,VBA代码问题

WJCK

Private Sub CommandButton1_Click()
Dim point1(0 To 2) As Double
Dim point2(0 To 2) As Double
Dim point3(0 To 2) As Double
Me.hide
ThisDrawing.Utility.GetPoint point1, "输入起点"
ThisDrawing.Utility.GetPoint point2, "输入终点"
Dim distant As Double
MsgBox point2(0) & point2(1)
distant = point1(1) - point2(1)
point3(0) = point2(0)
point3(1) = point2(1)
point3(2) = point2(2)
point3(1) = point2(1) - 10 * distant
Dim pline As AcadLWPolyline
Dim point(0 To 5) As Double
point(0) = point1(0)
point(1) = point1(1)
point(2) = point2(0)
point(3) = point2(1)
point(4) = point3(0)
point(5) = point3(1)


Set pline = ThisDrawing.ModelSpace.AddLightWeightPolyline(point)


Me.Show

End Sub
各位高手帮我看看,那错了.调试没问题.运行是总是出现一跟直线拈在坐标原点上,输入的点总是坐标原点.为什么???*-*8 *-*8

雪山飞狐(lzh)

dim point1,point2

dashan

不是能运行就说明没错，最多只能说语法上正确，是否能达到目的可就不一定了。

建议
1.变量前有表示类型的前缀
2.通过.GetPoint获取点的话要把其返回到一个Variant类型的变量（因为数组是不能整体赋值的），具体使用方法去看一下帮助。
3.MsgBox point2(0) & point2(1) X,Y坐标用","隔开
4.多些空行


这么写会好一些

Private Sub CommandButton1_Click()
  Dim vntPoint1 As Variant
  Dim vntPoint2 As Variant
  Dim vntPoint3 As Variant
  
  Me.hide
  
  vntPoint1 = ThisDrawing.Utility.GetPoint(, "输入起点")

  vntPoint2 = ThisDrawing.Utility.GetPoint(vntPoint1, "输入终点")
  MsgBox vntPoint2(0) & "," & vntPoint2(1)

   Dim dblDistance As Double
  dblDistance = vntPoint1(1) - vntPoint2(1)
  
  vntPoint3 = vntPoint1
  vntPoint3(1) = vntPoint2(1) - 10 * dblDistance
  
  Dim objPline As AcadLWPolyline
  Dim adblPoint(0 To 5) As Double
  adblPoint(0) = vntPoint1(0)
  adblPoint(1) = vntPoint1(1)
  adblPoint(2) = vntPoint2(0)
  adblPoint(3) = vntPoint2(1)
  adblPoint(4) = vntPoint3(0)
  adblPoint(5) = vntPoint3(1)
  
  Set objPline = ThisDrawing.ModelSpace.AddLightWeightPolyline(adblPoint)
  ThisDrawing.Regen acActiveViewport
  
  Me.Show

End Sub

WJCK

谢谢楼上的大哥指教.问题解决了.这个论坛真是太好了.我找了好久.希望能多放一些教材上去.大家在这交流挺不错的.谢谢了呀.