[求助]：想向“柔柔”要个源代码

lxuming · 发表于 2005-4-21 13:56:16

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

向柔柔要个标高符号的源代码。谢谢。

邮箱：lxuming@163.com

柔柔 · 发表于 2005-4-22 00:17:48

我这是编着玩玩的，不合适地方请自己修改。
这个版块不大来，没及时看到。

[FONT=courier new]
;
; LEVEL.LSP 建筑标高标注程序 CYN 2003.8.7
; 最近一次修改: 2003.8.7
; 全局变量: #dwg_scl_cyn 图纸比例因子
; #level_0_cyn 坐标值与标注值差
; #bg_strhigh_cyn 标注文字字高
;;-----------------------------------------------------------------------------------------
(defun level_err(s)
(if (/= s "Function cancelled")
(princ (strcat "\nError: " s))
)
(setvar "OSMODE" os)
(setvar "CMDECHO" cmd)
(command "_.UNDO" "_E")
)
;;-----------------------------------------------------------------------------------------
(defun c:level (/ os cmd temp xx ename move_pt pt0 pt1 pt2 pt3 pt4 pt5 pt6
p1 p2 ang a b c ang1 ang2 angstr levelbg_cyn str)
(setq os (getvar "OSMODE"))
(setq cmd (getvar "CMDECHO"))
(setq *error* level_err)
(setvar "CMDECHO" 0)
(if (= #dwg_scl_cyn nil) (setq #dwg_scl_cyn (getvar "DIMSCALE")))
(if (= #dwg_scl_cyn 0.0) (setq #dwg_scl_cyn 1.0))
(if (= #bg_strhigh_cyn nil) (setq #bg_strhigh_cyn 2.5))
(setq temp T)
(while temp
(prompt (strcat "\n文字字高 High = " (rtos #bg_strhigh_cyn)
", 比例因子 Scale = " (rtos #dwg_scl_cyn)))
(initget "High Scale")
(setq pt0 (getpoint "\n指示标注位置或 [字高(H), 比例因子(S)] : "))
(cond
((= pt0 "High")
(setq xx (getreal (strcat "\n字体高度 <"(rtos #bg_strhigh_cyn)">:")))
(if xx (setq #bg_strhigh_cyn xx))
)
((= pt0 "Scale")
(setq xx (getreal (strcat "\n比例因子 <"(rtos #dwg_scl_cyn)">:")))
(if xx (setq #dwg_scl_cyn xx))
)
(T
(setq temp nil)
)
)
)
(setvar "OSMODE" 0)
(setq pt1 pt0)
(level_dwg 0.0 0.5 pi 0.0)
;;-----------------------------------------------------------------------------------------
(prompt "\n指示引出标注位置< 原地标注 >：")
(setq temp T)
(while temp
(setq move_pt (grread T 4 0))
(cond
((= 5 (car move_pt))
(setq pt1 (cadr move_pt))
(setq pt1 (polar pt1 (* pi 0.5) (* #dwg_scl_cyn 2.5)))
(if (> (car pt1) (car pt0))
(progn
(level_dwg 0.0 0.5 pi 0.0)
(setq p1 (polar pt1 pi (* #dwg_scl_cyn 3.0)))
(setq p2 (polar p1 0.0 (* #dwg_scl_cyn 5.0)))
)
(progn
(level_dwg 0.0 0.5 0.0 pi)
(setq p1 (polar pt1 0.0 (* #dwg_scl_cyn 3.0)))
(setq p2 (polar p1 pi (* #dwg_scl_cyn 5.0)))
)
)
(redraw)
(grdraw pt0 p1 3 1)
(grdraw p1 p2 3 1)
)
((= 3 (car move_pt))
(setq pt1 (cadr move_pt))
(setq pt1 (polar pt1 (* pi 0.5) (* #dwg_scl_cyn 2.5)))
(redraw)
(command "_pline" pt0 "w" "0.0" "" p1 p2 "")
(setq temp nil)
(setq ang 0.0)
)
((or (= 12 (car move_pt)) (= 25 (car move_pt)))
(redraw)
(setq pt1 pt0)
(level_dwg 0.0 0.5 pi 0.0)
(setq temp nil)
)
)
)
;;-----------------------------------------------------------------------------------------
(defun level_xz_cyn ()
(prompt "\n指示旋转方向点< 正交 >：")
(setq temp T)
(while temp
(setq move_pt (grread T 4 0))
(cond
((= 5 (car move_pt))
(setq move_pt (cadr move_pt))
(redraw)
(grdraw pt1 move_pt 5 1)
(setq ang (angle pt1 move_pt))
(level_dwg ang 0.5 pi 0.0)
)
((= 3 (car move_pt)) (setq temp nil))
((or (= 12 (car move_pt)) (= 25 (car move_pt)))
(cond
((equal ang 0.0 0.78) (setq ang 0.0))
((equal ang (* pi 0.5) 0.78) (setq ang (* pi 0.5)))
((equal ang pi 0.78) (setq ang pi))
((equal ang (* pi 1.5) 0.78) (setq ang (* pi 1.5)))
)
(level_dwg ang 0.5 pi 0.0)
(setq temp nil)
)
)
)
)
;;-----------------------------------------------------------------------------------------
(if (= pt1 pt0) (level_xz_cyn))
(prompt "\n指示标高标记方向：")
(setq temp T)
(while temp
(setq move_pt (grread T 4 0))
(if (= 5 (car move_pt))
(progn
(setq move_pt (cadr move_pt))
(redraw)
(grdraw pt1 move_pt 2 1)
(setq ang1 (angle pt1 move_pt))
(setq ang2 (- ang1 ang))
(cond
((and (< ang2 0.0) (> ang2 (* pi -0.5))) (level_dwg ang 1.5 pi 0.0))
((and (< ang2 (* pi -0.5)) (> ang2 (* pi -1.0))) (level_dwg ang 1.5 0.0 pi))
((and (< ang2 (* pi -1.0)) (> ang2 (* pi -1.5))) (level_dwg ang 0.5 0.0 pi))
((and (< ang2 (* pi -1.5)) (> ang2 (* pi -2.0))) (level_dwg ang 0.5 pi 0.0))
((and (> ang2 0.0) (< ang2 (* pi 0.5))) (level_dwg ang 0.5 pi 0.0))
((and (> ang2 (* pi 0.5)) (< ang2 pi)) (level_dwg ang 0.5 0.0 pi))
((and (> ang2 pi) (< ang2 (* pi 1.5))) (level_dwg ang 1.5 0.0 pi))
((and (> ang2 (* pi 1.5)) (< ang2 (* pi 2.0))) (level_dwg ang 1.5 pi 0.0))
)
)
(setq temp nil)
)
)
(redraw)
;;-----------------------------------------------------------------------------------------
(if (= #level_0_cyn nil)
(setq levelbg_cyn (/ (fix (cadr pt0)) 1000.0))
(setq levelbg_cyn (/ (fix (- (cadr pt0) #level_0_cyn)) 1000.0))
)
(setq xx (getreal (strcat "\n标高值 <" (rtos levelbg_cyn 2 3) ">:")))
(if xx
(setq levelbg_cyn xx
#level_0_cyn (- (cadr pt0) (* xx 1000.0))
)
)
(if (= (fix levelbg_cyn) levelbg_cyn)
(setq str (strcat (rtos levelbg_cyn) ".000"))
(progn
(if (= (/ (fix (* levelbg_cyn 10.0)) 10.0) levelbg_cyn)
(setq str (strcat (rtos levelbg_cyn) "00"))
(progn
(if (= (/ (fix (* levelbg_cyn 100.0)) 100.0) levelbg_cyn)
(setq str (strcat (rtos levelbg_cyn) "0"))
(setq str (rtos levelbg_cyn 2 3))
)
)
)
)
)
(if (= levelbg_cyn 0.0) (setq str "%%p0.000"))
(if (and (> (angle pt2 pt5) 1.95) (<= (angle pt2 pt5) 4.85))
(setq angstr (/ (* (angle pt5 pt2) 180) pi))
(setq angstr (/ (* (angle pt2 pt5) 180) pi))
)
(command "text" "_middle" pt6 (* #bg_strhigh_cyn #dwg_scl_cyn) angstr str)
(setvar "CMDECHO" cmd)
(setvar "OSMODE" os)
)
;;-----------------------------------------------------------------------------------------
(defun level_dwg (ang a b c)
(if ename (entdel ename))
(setq pt2 (polar pt1 (+ ang (* pi a)) (* #dwg_scl_cyn 2.5))
pt3 (polar pt2 (+ ang b) (* #dwg_scl_cyn 2.5))
pt4 (polar pt3 (+ ang c) (* #dwg_scl_cyn 5.0))
pt5 (polar pt3 (+ ang c) (* #dwg_scl_cyn 14.0))
pt6 (polar pt2 (+ ang c) (* #dwg_scl_cyn 5.0))
pt6 (polar pt6 (+ ang (* pi a)) (* #dwg_scl_cyn 2.5))
)
(command "_pline" pt4 "w" "0.0" "" pt1 pt3 pt5 "")
(setq ename (entlast))
)
;;-----------------------------------------------------------------------------------------
[/FONT]

[FONT=courier new] 
; 
; LEVEL.LSP  建筑标高标注程序  CYN 2003.8.7 
; 最近一次修改: 2003.8.7 
; 全局变量: #dwg_scl_cyn     图纸比例因子 
;           #level_0_cyn     坐标值与标注值差 
;           #bg_strhigh_cyn  标注文字字高 
;;----------------------------------------------------------------------------------------- 
(defun level_err(s) 
      (if (/= s "Function cancelled") 
        (princ (strcat "\nError: " s)) 
      ) 
      (setvar "OSMODE" os) 
      (setvar "CMDECHO" cmd) 
      (command "_.UNDO" "_E") 
 ) 
;;----------------------------------------------------------------------------------------- 
(defun c:level (/ os cmd temp xx ename move_pt pt0 pt1 pt2 pt3 pt4 pt5 pt6 
                  p1 p2  ang a b c ang1 ang2 angstr levelbg_cyn str) 
  (setq os (getvar "OSMODE")) 
  (setq cmd (getvar "CMDECHO")) 
  (setq *error* level_err) 
  (setvar "CMDECHO" 0) 
  (if (= #dwg_scl_cyn nil) (setq #dwg_scl_cyn (getvar "DIMSCALE"))) 
  (if (= #dwg_scl_cyn 0.0) (setq #dwg_scl_cyn 1.0)) 
  (if (= #bg_strhigh_cyn nil) (setq #bg_strhigh_cyn 2.5)) 
  (setq temp T) 
  (while temp 
     (prompt (strcat "\n文字字高 High = " (rtos #bg_strhigh_cyn) 
                     ", 比例因子 Scale = " (rtos #dwg_scl_cyn))) 
     (initget "High Scale") 
     (setq pt0 (getpoint "\n指示标注位置 或 [字高(H), 比例因子(S)] : ")) 
     (cond 
       ((= pt0 "High") 
          (setq xx (getreal (strcat "\n字体高度 <"(rtos #bg_strhigh_cyn)">:"))) 
          (if xx (setq #bg_strhigh_cyn xx)) 
       ) 
       ((= pt0 "Scale") 
          (setq xx (getreal (strcat "\n比例因子 <"(rtos #dwg_scl_cyn)">:"))) 
          (if xx (setq #dwg_scl_cyn xx)) 
       ) 
       (T 
         (setq temp nil) 
       ) 
     ) 
   ) 
   (setvar "OSMODE" 0) 
   (setq pt1 pt0)   
   (level_dwg 0.0 0.5 pi 0.0) 
;;----------------------------------------------------------------------------------------- 
   (prompt "\n指示引出标注位置< 原地标注 >：") 
   (setq temp T) 
   (while temp 
     (setq move_pt (grread T 4 0)) 
     (cond 
       ((= 5 (car move_pt)) 
         (setq pt1 (cadr move_pt)) 
         (setq pt1 (polar pt1 (* pi 0.5) (* #dwg_scl_cyn 2.5))) 
         (if (> (car pt1) (car pt0)) 
           (progn 
              (level_dwg 0.0 0.5 pi 0.0) 
              (setq p1 (polar pt1 pi (* #dwg_scl_cyn 3.0))) 
              (setq p2 (polar p1 0.0 (* #dwg_scl_cyn 5.0))) 
           ) 
           (progn 
              (level_dwg 0.0 0.5 0.0 pi) 
              (setq p1 (polar pt1 0.0 (* #dwg_scl_cyn 3.0))) 
              (setq p2 (polar p1 pi (* #dwg_scl_cyn 5.0))) 
           ) 
         ) 
         (redraw) 
         (grdraw pt0 p1 3 1) 
         (grdraw p1 p2 3 1) 
       ) 
       ((= 3 (car move_pt)) 
         (setq pt1 (cadr move_pt)) 
         (setq pt1 (polar pt1 (* pi 0.5) (* #dwg_scl_cyn 2.5))) 
         (redraw) 
         (command "_pline" pt0 "w" "0.0" "" p1 p2 "") 
         (setq temp nil) 
         (setq ang 0.0) 
       ) 
       ((or (= 12 (car move_pt)) (= 25 (car move_pt))) 
          (redraw) 
          (setq pt1 pt0) 
          (level_dwg 0.0 0.5 pi 0.0) 
          (setq temp nil) 
       ) 
     ) 
   ) 
;;----------------------------------------------------------------------------------------- 
   (defun level_xz_cyn () 
      (prompt "\n指示旋转方向点< 正交 >：") 
      (setq temp T) 
      (while temp 
        (setq move_pt (grread T 4 0)) 
        (cond 
          ((= 5 (car move_pt)) 
            (setq move_pt (cadr move_pt)) 
            (redraw) 
            (grdraw pt1 move_pt 5 1) 
            (setq ang (angle pt1 move_pt)) 
            (level_dwg ang 0.5 pi 0.0) 
          ) 
          ((= 3 (car move_pt)) (setq temp nil)) 
          ((or (= 12 (car move_pt)) (= 25 (car move_pt))) 
            (cond 
              ((equal ang 0.0 0.78)  (setq ang 0.0)) 
              ((equal ang (* pi 0.5) 0.78)  (setq ang (* pi 0.5))) 
              ((equal ang pi 0.78)  (setq ang pi)) 
              ((equal ang (* pi 1.5) 0.78)  (setq ang (* pi 1.5))) 
            ) 
            (level_dwg ang 0.5 pi 0.0) 
            (setq temp nil) 
          ) 
        ) 
      ) 
   ) 
;;----------------------------------------------------------------------------------------- 
   (if (= pt1 pt0) (level_xz_cyn)) 
   (prompt "\n指示标高标记方向：") 
   (setq temp T) 
   (while temp      
     (setq move_pt (grread T 4 0)) 
     (if (= 5 (car move_pt)) 
       (progn 
          (setq move_pt (cadr move_pt)) 
          (redraw) 
          (grdraw pt1 move_pt 2 1) 
          (setq ang1 (angle pt1 move_pt)) 
          (setq ang2 (- ang1 ang)) 
           (cond 
             ((and (< ang2 0.0) (> ang2 (* pi -0.5)))            (level_dwg ang 1.5 pi 0.0)) 
             ((and (< ang2 (* pi -0.5)) (> ang2 (* pi -1.0)))    (level_dwg ang 1.5 0.0 pi)) 
             ((and (< ang2 (* pi -1.0)) (> ang2 (* pi -1.5)))    (level_dwg ang 0.5 0.0 pi)) 
             ((and (< ang2 (* pi -1.5)) (> ang2 (* pi -2.0)))    (level_dwg ang 0.5 pi 0.0)) 
             ((and (> ang2 0.0) (< ang2 (* pi 0.5)))             (level_dwg ang 0.5 pi 0.0)) 
             ((and (> ang2 (* pi 0.5)) (< ang2 pi))              (level_dwg ang 0.5 0.0 pi)) 
             ((and (> ang2  pi) (< ang2 (* pi 1.5)))             (level_dwg ang 1.5 0.0 pi)) 
             ((and (> ang2 (* pi 1.5)) (< ang2 (* pi 2.0)))      (level_dwg ang 1.5 pi 0.0)) 
          ) 
        ) 
        (setq temp nil)    
     ) 
   ) 
   (redraw) 
;;----------------------------------------------------------------------------------------- 
   (if (= #level_0_cyn nil) 
       (setq levelbg_cyn (/ (fix (cadr pt0)) 1000.0)) 
       (setq levelbg_cyn (/ (fix (- (cadr pt0) #level_0_cyn)) 1000.0)) 
   ) 
 
   (setq xx (getreal (strcat "\n标高值 <" (rtos levelbg_cyn 2 3) ">:"))) 
   (if xx 
       (setq levelbg_cyn xx 
             #level_0_cyn (- (cadr pt0) (* xx 1000.0)) 
       ) 
   ) 
 
   (if (= (fix levelbg_cyn) levelbg_cyn) 
      (setq str (strcat (rtos levelbg_cyn) ".000")) 
      (progn 
         (if (= (/ (fix (* levelbg_cyn 10.0)) 10.0) levelbg_cyn) 
            (setq str (strcat (rtos levelbg_cyn) "00")) 
            (progn 
              (if (= (/ (fix (* levelbg_cyn 100.0)) 100.0) levelbg_cyn) 
                (setq str (strcat (rtos levelbg_cyn) "0")) 
                (setq str (rtos levelbg_cyn 2 3)) 
              ) 
            ) 
         ) 
      ) 
   ) 
 
   (if (= levelbg_cyn 0.0) (setq str "%%p0.000")) 
   (if (and (> (angle pt2 pt5) 1.95) (<= (angle pt2 pt5) 4.85))         
        (setq angstr (/ (* (angle pt5 pt2) 180) pi)) 
        (setq angstr (/ (* (angle pt2 pt5) 180) pi)) 
   ) 
   (command "text" "_middle" pt6 (* #bg_strhigh_cyn #dwg_scl_cyn) angstr str)    
   (setvar "CMDECHO" cmd) 
   (setvar "OSMODE" os) 
) 
;;----------------------------------------------------------------------------------------- 
   (defun level_dwg (ang a b c) 
      (if ename (entdel ename)) 
      (setq pt2 (polar pt1 (+ ang (* pi a)) (* #dwg_scl_cyn 2.5)) 
            pt3 (polar pt2 (+ ang b) (* #dwg_scl_cyn 2.5)) 
            pt4 (polar pt3 (+ ang c) (* #dwg_scl_cyn 5.0)) 
            pt5 (polar pt3 (+ ang c) (* #dwg_scl_cyn 14.0)) 
            pt6 (polar pt2 (+ ang c) (* #dwg_scl_cyn 5.0)) 
            pt6 (polar pt6 (+ ang (* pi a)) (* #dwg_scl_cyn 2.5)) 
      ) 
      (command "_pline" pt4 "w" "0.0" "" pt1 pt3 pt5 "") 
      (setq ename (entlast)) 
   ) 
;;----------------------------------------------------------------------------------------- 
 
  [/FONT]

本程序的优点是几乎不用键盘，因为本人不习惯“快捷键”，尽量让鼠标一统天下。

lxuming · 发表于 2005-4-22 07:37:05

谢谢，柔柔。

xyp1964 · 发表于 2005-4-22 07:57:27

标高符号与数值是分开的，觉得还是利用属性块比较方便。
还应强制标注到一个类似的“标高”层。

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：想向“柔柔”要个源代码

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子