.....................................

god · 发表于 2005-5-10 09:28:47

"狂刀"的程序是不错，佩服。不过是不是应当改成一点即刷，而不是按了空格后才显示刷新效果。
不过acad2006的刷子已经有这个功能了，贱人老弟是不是太执着于专业精神了

贱人 · 发表于 2005-5-10 09:46:51

本帖最后由贱人于 2025-4-18 05:57 编辑

.....................................

狂刀 · 发表于 2005-5-10 09:48:12

;这个是一选一刷的版本.
[php]
(defun c:plmw (/ el w ss)
  (princ "\n刷线宽----by 狂刀. ")
  (if (and (setq el (entsel "\n选参照多义线宽度:"))
   (setq w (cdr (assoc 43 (entget (car el)))))
   )
(while (setq ss (ssget ":s" '((0 . "*POLYLINE,ARC,LINE"))))
   (command ".pedit" "m" ss  "")
   (if (NOT (wcmatch (cdr (assoc 0 (entget(ssname ss 0))))
         "*POLYLINE"
         )
   )
(COMMAND "")
   )
   (command "w" w "j" 1e-4 "")
)
  )
  (princ)
)[/php]

贱人 · 发表于 2005-5-10 10:02:45

本帖最后由贱人于 2025-4-18 05:57 编辑

.....................................

god · 发表于 2005-5-10 20:51:15

要刷园也可以，加个命令，先把园打断，变成圆弧

haijiangl · 发表于 2005-5-14 22:27:23

可以刷圆，把圆变成donut
代码长了一点，主要是要养成一个好的编程习惯，在程序出错或用户退出的时候，恢复原来的系统设置。

[FONT=courier new]
;;====================
;;单选物体，带过滤列表及提示
(defun lhj_sel (str fi_list / pt ename ss loop ename)
(princ "\n")
(princ str)
(setq loop T)
(while loop
(setq pt (grread t 4 2))
(if (= 3 (car pt))
(setq loop nil)
)
)
(setq pt (cadr pt))
(setq ss (ssget pt fi_list))
(if ss
(setq ename (ssname ss 0))
(setq ename nil)
)
)
;;=====================================
;;获取实体dxf组码内容
;; (lhj_dxf 实体名 dxf码编号)
;;例：(lhj_dxf textname 10)，获取文字左下点标
(defun lhj_dxf (ename code / elist res)
(setq elist (entget ename))
(setq res (cdr (assoc code elist)))
)
;;==========================================
;;初始化，读取系统变量。结束时，恢复系统变量
;; osmode 0
;; cmdecho 1
;; clayer 2
;; textstyle 3
;; cecolor 4
;; dimstyle 5
;; plinewid 6
;; filletrad 7
(defun lhj_start ()
(setq lhj_s_lst
(list
(getvar "osmode")
(getvar "cmdecho")
(getvar "clayer")
(getvar "textstyle")
(getvar "cecolor")
(getvar "dimstyle")
(getvar "plinewid")
(getvar "filletrad")
(getvar "attdia")
)
)
(setq old_error *error*)
(setvar "cmdecho" 0)
(command "undo" "be")
(setvar "osmode" 0)
(setvar "attdia" 0)
(princ)
)
(defun lhj_end ()
(setvar "osmode" (nth 0 lhj_s_lst))
(setvar "clayer" (nth 2 lhj_s_lst))
(setvar "textstyle" (nth 3 lhj_s_lst))
(setvar "cecolor" (nth 4 lhj_s_lst))
(command "dimstyle" "r" (nth 5 lhj_s_lst))
(setvar "plinewid" (nth 6 lhj_s_lst))
(setvar "filletrad" (nth 7 lhj_s_lst))
(setvar "attdia" (nth 8 lhj_s_lst))
(setq *error* old_error)
(command "undo" "e")
(setvar "cmdecho" (nth 1 lhj_s_lst))
(princ)
)
;;-----------------------------
;; 定义pline刷
;;-----------------------------
(defun c:matchplwid (/ pl0 ss ssl en el plw mode rad)
;初始化程序=======
(lhj_start)
(defun *error* (msg)
(princ "\n")
(princ "\n:::lhj_tools:::")
(princ msg)
(princ ",程序退出!")
(if pl0
(redraw pl0 4)
)
(lhj_end)
)
;初始化结束=======
;主程序===========
(setq pl0 (lhj_sel
"\n:::LHJ_TOOLS:::请选取源PLINE:"
'((0 . "LWPOLYLINE"))
)
)
(if pl0
(progn
(redraw pl0 3)
(setq plw (lhj_dxf pl0 43))
(princ "\n:::LHJ_TOOLS:::请选取要修改宽度的PLINE/LINE/CIRCLE/ARC:")
(setq ss (ssget '((0 . "LWPOLYLINE,line,circle,arc"))))
(redraw pl0 4)
(if ss
(progn
(setq ssl (sslength ss))
(setvar "plinewid" plw)
(while (> ssl 0)
(setq en (ssname ss (setq ssl (1- ssl)))
mode (lhj_dxf en 0)
)
(cond ((or (= mode "ARC") (= mode "LINE"))
(progn
(command "pedit" en "y" "w" plw)
(command)
)
)
((= mode "LWPOLYLINE")
(progn
(command "pedit" en "w" plw)
(command)
)
)
((= mode "CIRCLE")
(progn
(setvar "clayer" (lhj_dxf en 8))
(setq rad (lhj_dxf en 40))
(command "donut"
(- (* rad 2) plw)
(+ (* rad 2) plw)
(lhj_dxf en 10)
)
(command)
(entdel en)
)
)
)
)
)
(princ "\n:::LHJ_TOOLS:::没有选择到要修改宽度的物体!")
)
)
(princ "\n:::LHJ_TOOLS:::没有选择到PLINE!")
)
;主程序结束=======
(lhj_end)
(princ)
)
[/FONT]

[FONT=courier new] 
;;==================== 
;;单选物体，带过滤列表及提示 
(defun lhj_sel (str fi_list / pt ename ss loop ename) 
  (princ "\n") 
  (princ str) 
  (setq loop T) 
 
  (while loop 
    (setq pt (grread t 4 2)) 
    (if (= 3 (car pt)) 
      (setq loop nil) 
    ) 
  ) 
  (setq pt (cadr pt)) 
  (setq ss (ssget pt fi_list)) 
  (if ss 
    (setq ename (ssname ss 0)) 
    (setq ename nil) 
  ) 
) 
 
;;===================================== 
;;获取实体dxf组码内容 
;; (lhj_dxf 实体名 dxf码编号) 
;;例：(lhj_dxf textname 10)，获取文字左下点标 
 
(defun lhj_dxf (ename code / elist res) 
  (setq elist (entget ename)) 
  (setq res (cdr (assoc code elist))) 
) 
 
;;========================================== 
;;初始化，读取系统变量。结束时，恢复系统变量 
;;  osmode             0 
;;  cmdecho         1 
;;  clayer             2 
;;  textstyle          3 
;;  cecolor        4 
;;  dimstyle        5 
;;  plinewid    6 
;;  filletrad   7 
 
 
(defun lhj_start () 
  (setq        lhj_s_lst 
         (list 
           (getvar "osmode") 
           (getvar "cmdecho") 
           (getvar "clayer") 
           (getvar "textstyle") 
           (getvar "cecolor") 
           (getvar "dimstyle") 
           (getvar "plinewid") 
           (getvar "filletrad") 
           (getvar "attdia") 
         ) 
  ) 
  (setq old_error *error*) 
  (setvar "cmdecho" 0) 
  (command "undo" "be") 
  (setvar "osmode" 0) 
  (setvar "attdia" 0) 
  (princ) 
) 
 
 
(defun lhj_end () 
  (setvar "osmode" (nth 0 lhj_s_lst)) 
  (setvar "clayer" (nth 2 lhj_s_lst)) 
  (setvar "textstyle" (nth 3 lhj_s_lst)) 
  (setvar "cecolor" (nth 4 lhj_s_lst)) 
  (command "dimstyle" "r" (nth 5 lhj_s_lst)) 
  (setvar "plinewid" (nth 6 lhj_s_lst)) 
  (setvar "filletrad" (nth 7 lhj_s_lst)) 
  (setvar "attdia" (nth 8 lhj_s_lst)) 
  (setq *error* old_error) 
  (command "undo" "e") 
  (setvar "cmdecho" (nth 1 lhj_s_lst)) 
  (princ) 
) 
 
 
;;----------------------------- 
;;     定义pline刷 
;;----------------------------- 
(defun c:matchplwid (/ pl0 ss ssl en el plw mode rad) 
 
 ;初始化程序======= 
  (lhj_start) 
 
  (defun *error* (msg) 
    (princ "\n") 
    (princ "\n:::lhj_tools:::") 
    (princ msg) 
    (princ ",程序退出!") 
    (if        pl0 
      (redraw pl0 4) 
    ) 
    (lhj_end) 
  ) 
 ;初始化结束======= 
 
 ;主程序=========== 
  (setq        pl0 (lhj_sel 
              "\n:::LHJ_TOOLS:::请选取源PLINE:" 
              '((0 . "LWPOLYLINE")) 
            ) 
  ) 
  (if pl0 
    (progn 
      (redraw pl0 3) 
      (setq plw (lhj_dxf pl0 43)) 
      (princ "\n:::LHJ_TOOLS:::请选取要修改宽度的PLINE/LINE/CIRCLE/ARC:") 
      (setq ss (ssget '((0 . "LWPOLYLINE,line,circle,arc")))) 
      (redraw pl0 4) 
      (if ss 
        (progn 
          (setq ssl (sslength ss)) 
          (setvar "plinewid" plw) 
          (while (> ssl 0) 
            (setq en   (ssname ss (setq ssl (1- ssl))) 
                  mode (lhj_dxf en 0) 
            ) 
            (cond ((or (= mode "ARC") (= mode "LINE")) 
                   (progn 
                     (command "pedit" en "y" "w" plw) 
                     (command) 
                   ) 
                  ) 
 
                  ((= mode "LWPOLYLINE") 
                   (progn 
                     (command "pedit" en "w" plw) 
                     (command) 
                   ) 
                  ) 
 
                  ((= mode "CIRCLE") 
                   (progn 
                     (setvar "clayer" (lhj_dxf en 8)) 
                     (setq rad (lhj_dxf en 40)) 
                     (command "donut" 
                              (- (* rad 2) plw) 
                              (+ (* rad 2) plw) 
                              (lhj_dxf en 10) 
                     ) 
                     (command) 
                     (entdel en) 
                   ) 
                  ) 
            ) 
          ) 
        ) 
        (princ "\n:::LHJ_TOOLS:::没有选择到要修改宽度的物体!") 
      ) 
    ) 
    (princ "\n:::LHJ_TOOLS:::没有选择到PLINE!") 
  ) 
 
 
 ;主程序结束======= 
 
  (lhj_end) 
  (princ) 
) 
  [/FONT]

账号		自动登录	找回密码
密码			立即注册

[求助] .....................................