[编程申请]：交换LINE两个端点的坐标

lengliqun · 发表于 2005-7-30 12:02:28

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

求第一个LSP程序(能框选多选)，这一程序在CAD中进行向量计算的时候非常有用：
每条LINE线有两个端点P1(x1,y1)与p2(x2,y2)
1、对与Y轴不平行（即x1≠x2）的LINE线，若x1>x2，则交换两个端点的坐标变成P1(x2,y2)与P2(x1,y1)，否则不交换；
2、对与Y轴平行（即x1=x2）的LINE线,若y1 < y2，则交换两个端点的坐标变成P1(x2,y2)与P2(x1,y1)，否则不交换；

求第二个LSP程序(能框选多选)，这一程序同样在CAD中进行向量计算的时候非常有用：无条件则交换LINE线两个端点的坐标P1(x2,y2)与P2(x1,y1)成P1(x2,y2)与P2(x1,y1)。

eachy · 发表于 2005-7-30 17:16:38

(defun c:tt (/ ss n el sp ep x1 x2 y1 y2 l1 l2)
(if (setq ss (ssget '((0 . "line"))))
(progn
(setq n -1)
(repeat (sslength ss)
(setq el (entget (ssname ss (setq n (1+ n))))
sp (cdr (setq l1 (assoc 10 el)))
ep (cdr (setq l2 (assoc 11 el)))
x1 (car sp)
y1 (cadr sp)
x2 (car ep)
y2 (cadr ep)
)
(if
(or (and (equal x1 x2)
(< y1 y2)
)
(and (/= x1 x2) (> x1 x2))
)
(entmod (subst (cons 10 ep) l1 (subst (cons 11 sp) l2 el)))
)
)
)
)
(princ)
)

lemonx · 发表于 2005-7-30 19:15:01

想了半天，有什么实际应用吗？

xyp1964 · 发表于 2005-7-30 21:16:45

[FONT=courier new](load "xyp_lib")
;|加载通用函数(可在签名栏直接下载)
如果已经下载xyp_lib并放到搜索路径下可以不再下载!
利用以下任何一种方式即可加载和运行通用函数内的所有子程序：
1.在acad.lsp中增加(load"xyp_lib")
2.在每个程序内增加(load"xyp_lib")
3.在command下，输入(load"xyp_lib")
4.在菜单.mnl中增加(load"xyp_lib")
5.将xyp_lib.vlx文件直接拽到cad屏幕
[COLOR=red] ★通用函数下载地址：[/COLOR][url]http://www.xdcad.net/forum/attachment.php?s=&postid=1606661[/url]|;
;;;框选多选，无条件交换LINE线两个端点的坐标P1(x1,y1)与P2(x2,y2)成P1(x2,y2)与P2(x1,y1)
(defun c:test02 ()
(CMDLA0)
(setq ss (ssget '((0 . "LINE")))
i -1
)
(while (setq s1 (ssname ss (setq i (1+ i))))
(setq pt10 (dxf 10 (entget s1))
pt11 (dxf 11 (entget s1))
)
(sub_upd s1 10 pt11)
(sub_upd s1 11 pt10)
)
(CMDLA1)
)[/FONT]

青马 · 发表于 2005-7-30 22:03:05

xyp没有看明白他的意思，他说的是始终第一点为左边的点，第二点为右边的点，你的命令只是简单的换了一下直线的起点和终点,我说的情况是直线的斜率不为零的情况

lengliqun · 发表于 2005-7-30 22:29:49

eachy斑竹解决的是第一个问题的LSP
xyp斑竹解决的是第二个问题的LSP
青马同志没看清问题

青马 · 发表于 2005-7-30 23:27:27

//xbbcad
;颠倒直线的两端点,即交换实体对象组代码10和11，
;用于解决直线、dimension、多段线的线型换向问题
(defun C:ddl(/ tmp ed ent m n endpt1 endpt2 newline name)
(princ "\n交换直线、多段线或标注的起点和终点.请选择直线、多段线或标注:\n")
;选择直线或标注，注意逻辑组的使用
(setq tmp (ssget (list (cons -4 "<OR")(cons 0 "LINE") (cons 0 "LWPOLYLINE") (cons 0 "DIMENSION") (cons -4 "or>"))))
(if tmp
(progn
(setq n (sslength tmp) m 0)
(repeat n
(setq ent (ssname tmp m))
(setq ed (entget ent))
;(ts "\nent=")
;(ts ent)
(setq name (cdr (assoc 0 ed)))
(if (= name "LWPOLYLINE")
(lwpolyline_reverse ent ed)
(progn
(setq endpt1 (cons 11 (cdr (assoc 10 ed) )))
(setq endpt2 (cons 10 (cdr (assoc 11 ed) )))
(setq ed (subst endpt1 (assoc 11 ed) ed))
(setq ed (subst endpt2 (assoc 10 ed) ed))
(setq newline ed)
;删除原对象并生成相同句柄的新对象，注意：
;enddel 对象名称ent不是对象数据表ed
;endmod entmake 的不是对象名称ent是对象数据表ed
(entdel ent)
(entmake newline)
)
);end if
(setq m (1+ m))
);end repeat
)
);end if tmp
(princ "\n共处理了")
(if m (princ m) (princ "0"))
(princ "条直线(多段线、标注)。")
(princ)
);end C:ddl
;---------------------------------------------------------------------------
;多段线的换向程序,修改自明经通道
(DEFUN lwpolyline_reverse (lwpent data / num data one points tempnum tempent)
(SETQ points nil)
(FOREACH one data
(PROGN (IF (= (CAR one) 10)
(SETQ points (APPEND points (LIST one)))
)
)
)
(SETQ points (REVERSE points))
(SETQ tempnum 0)
(SETQ tempent nil)
(FOREACH one data
(PROGN (IF (= (CAR one) 10)
(SETQ tempent (APPEND tempent (LIST (NTH tempnum points)))
tempnum (1+ tempnum)
)
(SETQ tempent (APPEND tempent (LIST one)))
)
)
)
(entdel lwpent)
(entmake tempent)
(PRINC)
);end lwpolyline_reverse

//xbbcad 
;DDL: Copyright By WWZ,2003-12-3 
;颠倒直线的两端点,即交换实体对象组代码10和11， 
;用于解决直线、dimension、多段线的线型换向问题 
 
(defun C:ddl(/ tmp ed ent m n endpt1 endpt2 newline name) 
 (princ "\n交换直线、多段线或标注的起点和终点.请选择直线、多段线或标注:\n")    
 ;选择直线或标注，注意逻辑组的使用 
 (setq tmp (ssget (list (cons -4 "<OR")(cons 0 "LINE") (cons 0 "LWPOLYLINE") (cons 0 "DIMENSION") (cons -4 "or>")))) 
 (if tmp 
   (progn 
     (setq n (sslength tmp) m 0) 
     (repeat n 
         (setq ent (ssname tmp m)) 
         (setq ed  (entget ent))       
         ;(ts "\nent=") 
         ;(ts ent) 
         (setq name (cdr (assoc 0 ed))) 
         (if (= name "LWPOLYLINE") 
           (lwpolyline_reverse ent ed) 
           (progn                
             (setq endpt1 (cons 11 (cdr (assoc 10 ed) )))          
             (setq endpt2 (cons 10 (cdr (assoc 11  ed) )))                   
             (setq ed (subst endpt1 (assoc 11 ed) ed))    
             (setq ed (subst endpt2 (assoc 10 ed) ed)) 
             (setq newline ed) 
             ;删除原对象并生成相同句柄的新对象，注意： 
             ;enddel 对象名称ent不是对象数据表ed 
             ;endmod entmake 的不是对象名称ent是对象数据表ed 
             (entdel  ent) 
             (entmake newline)                           
          ) 
         );end if    
         (setq m (1+ m)) 
     );end repeat 
   ) 
 );end if tmp 
 (princ "\n共处理了") 
 (if m (princ m) (princ "0")) 
 (princ "条直线(多段线、标注)。") 
 (princ) 
   
);end C:ddl 
 
;--------------------------------------------------------------------------- 
;多段线的换向程序,修改自明经通道 
(DEFUN lwpolyline_reverse (lwpent data / num data one points tempnum tempent) 
   
       (SETQ points nil) 
       (FOREACH one data 
            (PROGN (IF (= (CAR one) 10) 
                       (SETQ points (APPEND points (LIST one))) 
                   ) 
            ) 
        ) 
         
        (SETQ points (REVERSE points)) 
        (SETQ tempnum 0) 
        (SETQ tempent nil) 
         
        (FOREACH one data 
            (PROGN (IF (= (CAR one) 10) 
                       (SETQ tempent (APPEND tempent (LIST (NTH tempnum points))) 
                             tempnum (1+ tempnum) 
                       ) 
                       (SETQ tempent (APPEND tempent (LIST one))) 
                   ) 
            ) 
        )       
        (entdel  lwpent) 
        (entmake tempent) 
         
        (PRINC) 
);end lwpolyline_reverse

sange · 发表于 2005-7-31 01:10:58

AUTOCAD果然高深莫测，开眼见了

账号		自动登录	找回密码
密码			立即注册

[编程申请]：交换LINE两个端点的坐标

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

浏览过的版块