[求助]：如何计算当前UCS下的实体包围盒？

小菜

我上面的说法也有点问题，点表包围盒这一步是多余的，直接变换就可以了，还是用程序说明问题吧，试一下就知道了
经过测试，用vla-rotate旋转实体的方法耗时是矩阵变换的5倍左右，效率不高。
eachy的程序我试了一下，有时候会出现：错误: Automation Error. Description was not provided，图见附件
[PHP]
(defun c:test (/ obj pts p1 p2)
  (setq obj (vlax-ename->vla-object (car(entsel))))
  (setq pts (ucsbndbox obj))
  (setq p1 (car pts) p2 (cadr pts)
        pts (list p1 (list (car p1) (cadr p2)) p2 (list (car p2) (cadr p1)))
  )
  (command "pline" (car pts) (cadr pts) (caddr pts) (last pts) "c")
)
(defun ObjBndBox (obj / ll ur)
  (if (vl-catch-all-error-p (vl-catch-all-apply 'vla-getboundingbox (list obj 'll 'ur)))
          nil
         (list (vlax-safearray->list ll) (vlax-safearray->list ur))
  )
)
(defun ucsbndbox (obj / pts)  
(if (zerop (getvar "worlducs"))
  (progn
    (vla-TransformBy obj (ucs2wcs_matrix))
    (setq pts (objbndbox obj))
    (vla-TransformBy obj (wcs2ucs_matrix))
    pts
  )
  (objbndbox obj)
  )
)
(defun ucs2wcs_matrix ()
  (vlax-tmatrix
    (append
      (mapcar
        '(lambda (vector origin)
           (append (trans vector 1 0 t) (list origin))
         )
        (list '(1 0 0) '(0 1 0) '(0 0 1))
        (trans '(0 0 0) 0 1)
      )
      (list '(0 0 0 1))
    )
  )
)
(defun wcs2ucs_matrix ()
  (vlax-tmatrix
    (append
      (mapcar
        '(lambda (vector origin)
           (append (trans vector 0 1 t) (list origin))
         )
        (list '(1 0 0) '(0 1 0) '(0 0 1))
        (trans '(0 0 0) 1 0)
      )
      (list '(0 0 0 1))
    )
  )
)
[/PHP]

它山之石

晕 受不了了
凭什么斑主能贴图
俺就不能

小菜 没明白 你这两个函数得到的结果有什么不同
(setq pts (ucsbndbox obj))
(setq pts (ObjBndBox obj))

哦 终于搞明白你的意思了
WCS下 UCS下 晕了
可恶的论坛
无法看图也无法下载

。。。。。。

小菜

eachy版主的程序有一点小错误，总体上是无比英明正确的，通过学习，把我的程序进行了简化，现在二者基本是一样的