类似xdrx_curve_extend的剪切功能

liuyj

xdrx_curve_extend实在是太好用了，能够一次延伸一组曲线到指定点，可惜没有一个类似的剪切程序，xdrx_curve_trim与它并不是对应的。各位大神能否写一个不用trim命令的程序，一次将一组曲线的指定侧部分截掉。用法如下：（func ss p0 pt），p0是边界点，pt是指定侧的任意点，用来判断截去的部分。

newer

裁剪的参数应该是个边界，不能是一个点

裁剪边界你希望是直线？

另外，下面这个图形，如果点到圆外面，你希望得到的图形是什么？

qqqincccken

谢谢提供，学习一下了！！！

Lispboy

写个函数，试试，裁剪边界可以是直线实体，直线两点表，几何实体（kXLine,kLingSeg2d/3d)

(defun XD::Curve:Trim (ss bound pt / #direction #pointOnLine dis1 p1 p2 tf x xline)
  (if (= (type ss) 'PICKSET)
    (setq ss (xdrx_pickset->ents ss))
  )
  (cond
    ((= (type bound) 'LIST))
    ((= (type bound) 'ENAME)
      (if (setq tf (xdge::type bound))
        (progn
          (if (xdrx_string_regexps "kLine[2|3]d" tf)
            (progn
              (xdge::getpropertyvalue bound "pointOnLine" "direction")
              (setq bound (list #pointOnLine (mapcar
                                               '+
                                               #pointOnLine
                                               #direction
                                             )
                          )
              )
            )
            (setq bound (xdge::getpropertyvalue bound "hasstartpoint"
                                                "hasendpoint"
                        )
            )
          )
        )
        (setq bound (xdrx_getpropertyvalue bound "vertices"))
      )
    )
  )
  (setq p1 (car bound)
        p2 (cadr bound)
        xline (xdge::constructor "kLine3d" p1 p2)
  )
  (xdrx_setmark)
  (mapcar
    '(lambda (x)
       (apply
         'xdrx_curve_getsplitcurves
         (cons x (xdrx_entity_intersectwith x xline))
       )
     )
    ss
  )
  (setq ss (append
             ss
             (xdrx_pickset->ents (xdrx_getss))
           )
        dis1 (xdrx_point_dist2Line pt p1 p2)
  )
  (mapcar
    '(lambda (x)
       (if (> (* dis1 (xdrx_point_dist2line (xdrx_getpropertyvalue x "midpoint")
                                            p1 p2
                      )
              ) 0
           )
         (xdrx_entity_delete x)
       )
     )
    ss
  )
  (xdge::free xline)
  t
)

(defun c:tt()
   (if (and (setq ss (ssget '((0 . "*line,arc,circle,ellipse"))))
            (setq e (xdrx_entsel "\n拾取裁剪边界<退出>:" '((0 . "line"))))
            (setq pt (getpoint (xdrx_getpropertyvalue (car e) "midpoint") "\n裁剪方向<退出>:"))
      )
      (xd::curve:trim ss (car e) pt)
   )
   (princ)
)

liuyj

xdrx_curve_extend不也可以只用一个点做延伸到的位置吗？我理解应该是这个点和点距曲线或延长线的最近点组成的点表作为边界，这样就可以用lispboy的函数了。

newer

liuyj 发表于 2016-10-26 00:33

延伸可以假定，因为延伸，曲线的方向是固定轨迹的，可以用一个点和这个轨迹垂直，求得延伸到的点。

而边界不行， 边界只给一个点，怎么假定边界的第二点呢？ 总平行或者垂直X轴吗？你要是个斜的边界怎么办？

liuyj

其实我要求的不含封闭曲线，如果点在曲线上，很简单，如果点不在曲线上，将点和到曲线的最近点组成点表，但是不绘出边界曲线。换个说法，就是将曲线的指定侧的端点延伸或缩短到指定的位置

newer

liuyj 发表于 2016-10-26 10:57

你是要裁剪一根吗？

下面这个图，要裁剪那些白色线， 你只给一点，怎么能确定裁掉他们呢？




LISPBOY的函数够通用了，你要是想按你的一点p1，可以根据你的图形，计算一个第二点p2给函数就行了

(xd::curve:trim ss (list p1 p2) pt)

liuyj

我给的要求是两点，上面的函数已经够用了。

alexmai1

cad 自带程序 qextrim 就可以做到你的想法

newer

alexmai1 发表于 2017-5-4 20:09

楼主是想要个函数，自己写LISP去做想做的事。

coverne

试试lispboy的

igood

alexmai1 发表于 2017-5-4 20:09

谢谢，这个命令好强大