数字文字求和

Lisphk · 发表于 2017-1-5 15:48:33

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

(defun C:STX (/ cpent elist en ip newtxt pt ss sum sumtxt txt)
  (princ "\n\t\t>>>  Select text to get summ >>>")
  (if
    ;;select texts/mtexts on screen :
    (setq ss (ssget '((0 . "*TEXT"))))
     ;; if selected then :
     (progn
       ;; store the first text entity for using 'em further :
       (setq cpent (ssname ss 0))
       ;; set initial sum to zero :
       (setq sum 0.)
       ;; loop trough selected texts/mtexts :
       (while
         ;; get the first text in selection :
         (setq en (ssname ss 0))
          ;; get entity list of them :
          (setq elist (entget en))
          ;; get the textstring by key 1 from entity list :
          (setq txt (cdr (assoc 1 elist)))
          ;; create output string :
          (setq        sumtxt
                 ;; concatenate strings :
                 (strcat
                   ;; convert digits to string :
                   (rtos
                     ;; add to summ the digital value of text :
                     (setq sum (+ (atof txt) sum))
                     ;; 2 is for metric units (3 for engineering) :
                     2
                     ;; set precision by current :
                     (getvar "dimdec")
                   )
                 )
          )
          ;; delete entity from selection set :
          (ssdel en ss)
       )
       ;; display message in the command line:
       (princ (strcat "\nSumm=" sumtxt))
       (setq pt (getpoint "\nSpecify the new text location: "))
       ;; get the insertion point of stored entity :
       (setq ip (cdr (assoc 10 (entget cpent))))
       ;; copy text entity to the new destination point :
       (command "_copy" cpent "" ip pt)
       ;; get the last created entity :
       (setq newtxt (entlast))
       ;; get entity list of them :
       (setq elist (entget newtxt))
       ;; modify entity list with new text string :
       (entmod (subst (cons 1 sumtxt) (assoc 1 elist) elist))
       ;; update changes :
       (entupd newtxt)
     )
  )
  (princ)
)
(princ "\nStart command with STX...")
(princ)

Lisphk · 发表于 2017-1-5 15:52:01

另外一个版本，屏幕打印求和结果

(defun c:add (/ txtss badset total cntr ent elist str nstr)
  (setvar "cmdecho" 0)
  (setq        total 0
        cntr  0
        nstr  (list)
  )
  (princ "\nSelect numbers to add: ")
  (setq txtss (ssget '((0 . "TEXT"))))
  (while (< cntr (sslength txtss))
    (setq ent        (ssname txtss cntr)
          elist        (entget ent)
    )
    (setq str (cdr (assoc 1 elist)))
    (if        (and (> (strlen str) 3) (wcmatch str "*`,*"))
      (repeat (/ (strlen str) 4)
        (setq nstr (cons (substr str (- (strlen str) 2) 3) nstr))
        (setq str (substr str 1 (- (strlen str) 4)))
      )                                        ;repeat
    )                                        ;if
    (if        nstr
      (foreach v nstr
        (setq str (strcat str v))
      )
    )                                        ;if
    (setq total (+ total (atof str)))
    (setq cntr (1+ cntr))
    (setq nstr (list))
  )                                        ;while
  (princ (strcat "\nTotal: " (rtos total 2 2)))
  (setvar "cmdecho" 0)
  (princ)
)                                        ;eof

shenfjliu · 发表于 2017-1-5 22:17:59

下载！学习学习！谢谢！

yanchao316 · 发表于 2017-1-6 12:56:05

确实是难得好帖啊，顶先

此城无心忘少年 · 发表于 2017-1-10 09:28:10

快捷键是？？？？？？？？？？

yoyoho · 发表于 2017-1-10 11:33:56

下载！学习！谢谢！

sicky111 · 发表于 2017-1-11 23:02:37

楼主一如既往的活跃。

比目大神 · 发表于 2017-3-31 08:46:07

啥也不说了，感谢楼主分享哇！

lywzcf · 发表于 2017-6-3 21:22:52

楼主，你好

请教，一楼那程序，，这句(entmod (subst (cons 1 sumtxt) (assoc 1 elist) elist))它是如何运作的？

账号		自动登录	找回密码
密码			立即注册

[每日一码] 数字文字求和

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。