API里两个函数的问题

liuyj · 发表于 2020-6-19 21:54:43

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

1、xdrx_geom_IsParallel-p 经常失效，也不能设精度
2、xdrx_curve_getoffsetcurves 对直线有时向左偏移，有时向右偏移，找不到规律

newer · 发表于 2020-6-19 22:12:04

本帖最后由 newer 于 2020-6-19 22:14 编辑

把你代码都贴出来，看你是怎么用的
偏移直线的时候，你注意直线的方向了吗？你要先排序，固定好直线的起始点

XDSoft · 发表于 2020-6-19 23:39:44

getoffsetcurves 对直线，正数，总是往直线前进（起点，终点）方向的左侧偏移

如果两个方向，你输入正数都想向左上偏移，那么你就需要处理

(defun c:tt ()
(if (and (setq e1 (car (xdrx-entsel "\n选择直线<退出>:")))
(setq dis (getreal "\n输入偏移距离（负数右下):"))
)
(progn (xdrx-getpropertyvalue e1 "startpoint" "endpoint")
(if (or (> (car #startpoint) (car #endpoint))
(< (cadr #startpoint) (cadr #endpoint))
)
(xdrx-curve-reverse e1)
)
(xdrx-curve-getoffsetcurves dis e1)
)
)
(princ)
)

XDSoft · 发表于 2020-6-19 23:55:14

xdrx_geom_IsParallel-p 下版本API加入精度控制
通过(xdrx-document-setprec 0.1 角度) 控制，角度是度，不是弧度
或者系统变量 (xdrx-setvar "tolEqualVector" 度数)
那么就是在多少度偏差内，是否平行

xdrx_geom_IsParallel-p 本质上是执行向量是否平行，最后执行的是 (xdrx_vector_IsParallel v1 v2)
xdrx_geom_IsParallel-p比 xdrx_vector_IsParallel 拓展的功能是除了判断向量是否平行，还能直接判断两个直线实体，或者几何直线实体是否平行

现在，你可以通过 xdrx_vector_IsParallel 来判断，这个函数支持精度 (xdrx_vector_IsParallel v1 v2 tol) tol是度

(defun c:tt ()
(if (and (setq e1 (car (xdrx-entsel "\n选择直线1<退出>:")))
(setq e2 (car (xdrx-entsel "\n选择直线2<退出>:")))
(setq tol (getreal "输入误差（度):"))
(xdrx-setvar "tolequalvector" tol)
(mapcar 'set '(p1 p2) (xdrx-getpropertyvalue e1 "get"))
(mapcar 'set '(p3 p4) (xdrx-getpropertyvalue e2 "get"))
(xdrx-vector-isparallel
(xdrx-vector-normalize (mapcar '- p2 p1))
(xdrx-vector-normalize (mapcar '- p4 p3))
)
)
(xdrx-prompt "\n两直线容差内平行")
(xdrx-prompt "\n两直线容差内不平行")
)
(princ)
)

可以写成

(defun c:tt ()
(if (and (setq e1 (car (xdrx-entsel "\n选择直线1<退出>:")))
(setq e2 (car (xdrx-entsel "\n选择直线2<退出>:")))
(setq tol (getreal "输入误差（度):"))
(xdrx-setvar "tolequalvector" tol)
(setq v1 (xdrx-getpropertyvalue e1 "direction")
v2 (xdrx-getpropertyvalue e2 "direction"))
(xdrx-vector-isparallel
v1
v2
)
)
(xdrx-prompt "\n两直线容差内平行")
(xdrx-prompt "\n两直线容差内不平行")
)
(princ)
)

liuyj · 发表于 2020-6-20 00:30:53

本帖最后由 liuyj 于 2020-6-20 00:33 编辑

就想写个对于任意曲线都适用的判断平行的函数

;;判断两直线平行,不考虑重合.
;;参数: li1,li2 为直线实体名.
;;返回: 平行返回T,不平行返回nil.
(defun is= (li1 li2 / v1 v2 an1 an2)
(setq v1 (vlax-curve-getfirstderiv li1 (vlax-curve-getstartparam li1))
v2 (vlax-curve-getfirstderiv li2 (vlax-curve-getstartparam li2))
an1 (angle '(0. 0. 0.) v1)
an2 (angle '(0. 0. 0.) v2)
)
(equal (rem (- an1 an2) PI) 0. 1e-3)
)
;;;曲线是否平行,对所有曲线均适用
(defun parallel (e1 e2 pfuzz / pts dis perpt)
;; rem reduces angles > pi so range is 0 - 180 deg
(cond ((and (= (dxf1 0 e1) "LINE") (= (dxf1 0 e2) "LINE"))
;;; (xdrx_geom_IsParallel-p e1 e2)
(is= e1 e2)
)
((and (= (dxf1 0 e1) "ARC") (= (dxf1 0 e2) "ARC"))
(if (and (vlax-property-available-p (vlax-ename->vla-object e1) 'center)
(vlax-property-available-p (vlax-ename->vla-object e2) 'center)
)
(equal (vla-get-center (vlax-ename->vla-object e1))
(vla-get-center (vlax-ename->vla-object e2))
pfuzz
)
)
)
(T
(setq pts (xdrx_curve_getSamplePoints e1 6)
perpt (xdrx_curve_getClosestPoint e2 (car pts) T)
dis (distance (car pts) perpt)
)
(vl-every '(lambda (d) (equal dis d pfuzz))
(mapcar '(lambda (p) (distance p (xdrx_curve_getClosestPoint e2 p T))) (cdr pts))
)
)
)
)

;;判断两直线平行,不考虑重合. 
;;参数: li1,li2 为直线实体名. 
;;返回: 平行返回T,不平行返回nil. 
(defun is= (li1 li2 / v1 v2 an1 an2) 
  (setq        v1  (vlax-curve-getfirstderiv li1 (vlax-curve-getstartparam li1)) 
        v2  (vlax-curve-getfirstderiv li2 (vlax-curve-getstartparam li2)) 
        an1 (angle '(0. 0. 0.) v1) 
        an2 (angle '(0. 0. 0.) v2) 
  ) 
  (equal (rem (- an1 an2) PI) 0. 1e-3) 
) 
;;;曲线是否平行,对所有曲线均适用 
(defun parallel        (e1 e2 pfuzz / pts dis perpt) 
  ;;  rem reduces angles > pi so range is 0 - 180 deg 
  (cond        ((and (= (dxf1 0 e1) "LINE") (= (dxf1 0 e2) "LINE")) 
;;;         (xdrx_geom_IsParallel-p e1 e2) 
         (is= e1 e2) 
        ) 
        ((and (= (dxf1 0 e1) "ARC") (= (dxf1 0 e2) "ARC")) 
         (if (and (vlax-property-available-p (vlax-ename->vla-object e1) 'center) 
                  (vlax-property-available-p (vlax-ename->vla-object e2) 'center) 
             ) 
           (equal (vla-get-center (vlax-ename->vla-object e1)) 
                  (vla-get-center (vlax-ename->vla-object e2)) 
                  pfuzz 
           ) 
         ) 
        ) 
        (T 
         (setq pts   (xdrx_curve_getSamplePoints e1 6) 
               perpt (xdrx_curve_getClosestPoint e2 (car pts) T) 
               dis   (distance (car pts) perpt) 
         ) 
         (vl-every '(lambda (d) (equal dis d pfuzz)) 
                   (mapcar '(lambda (p) (distance p (xdrx_curve_getClosestPoint e2 p T))) (cdr pts)) 
         ) 
        ) 
  ) 
)

后来发现还是精度的问题，差一点点都不行，就这么改了一下

liuyj · 发表于 2020-6-20 00:44:37

偏移的问题我是做了判断的

;;;点在曲线的哪一侧
(defun onwhichside (e pt / p1 p2)
(if (= (xdrx_getpropertyvalue e "IsA") "AcDbLine")
(setq p1 (dxf1 10 e)
p2 (dxf1 11 e)
)
(if (setq p1 (xdrx_curve_getclosestpoint e pt T))
(setq p2 (mapcar '+ p1 (xdrx_curve_getfirstderiv e p1)))
)
)
(xdrx_line_OnwhichSide p1 p2 pt)
)
(defun curve_getoffsetcurves (e pt / ds p1 ob side)
(if (setq p1 (xdrx_curve_getclosestpoint e pt T))
(setq ds (distance pt p1))
)
(setq ob (vlax-ename->vla-object e)
side (onwhichside e pt)
)
(if (= (xdrx_getpropertyvalue e "IsA") "AcDbLine")
(cond ((= side -1) (vla-offset ob ds))
((= side 1) (vla-offset ob (* -1 ds)))
)
(cond ((= side -1) (vla-offset ob (* -1 ds)))
((= side 1) (vla-offset ob ds))
)
)
)

可是偏移的时候，不总是向指定点方向偏移，只好这样修改了

newer · 发表于 2020-6-20 01:06:16

liuyj 发表于 2020-6-20 00:30
就想写个对于任意曲线都适用的判断平行的函数
后来发现还是精度的问题，差一点点都不行，就这么改了一下
...

很多API直接得到属性的，用lisp看着太乱了。
用xdrx_vector_IsParallel

dyjwyqz5221 · 发表于 2020-6-20 14:45:56

XDSoft 发表于 2020-6-19 23:55
xdrx_geom_IsParallel-p 下版本API加入精度控制
通过(xdrx-document-setprec 0.1 角度) 控制，角度是度， ...

(xdrx-vector-isparallel
         (xdrx-vector-normalize (mapcar '- p2 p1))
         (xdrx-vector-normalize (mapcar '- p4 p3))
)

不用换算成单位方向向量也可以吧，
(xdrx-vector-isparallel  (mapcar '- p2 p1) (mapcar '- p4 p3))

liuyj · 发表于 2020-6-20 15:54:05

我也觉得应该不用

XDSoft · 发表于 2020-6-20 18:29:17

dyjwyqz5221 发表于 2020-6-20 14:45
(xdrx-vector-isparallel
(xdrx-vector-normalize (mapcar '- p2 p1))
(xdr ...

函数内部自动处理成单位向量了
但编程时候是种风格，明确概念

既然青春留不住 · 发表于 2020-6-21 10:22:58

账号		自动登录	找回密码
密码			立即注册

[BUG报告] API里两个函数的问题

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

点评

评分

点评

点评

评分