【挑战】表按照给定的数重新分组

newer · 发表于 2017-6-6 18:46:13

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

本帖最后由 newer 于 2017-6-6 19:19 编辑

表按照给定的数重新分组

例如：
(group1 '(1 2 3 4 5 6 7) 2) => '((1 2)(3 4)(5 6)(7 nil))
(group1 '(1 2 3 4 5 6 7) 3) => '((1 2 3)(4 5 6)(7 nil nil))

分享一个，递归的

(defun GroupByNum-1 (lst num / rtn)
(setq rtn nil)
(if lst
(cons (reverse (repeat num
(progn (setq rtn (cons (car lst) rtn)
lst (cdr lst)
)
rtn
)
)
)
(GroupByNum-1 lst num)
)
)
)

测试效率

(xd::benchmark
'((GroupByNum-1 lst)
(GroupByNum-2 lst 2) ;;根据需要自己修改，有几项填几项
(GroupByNum-3 lst 2) ;;根据需要自己修改，有几项填几项
(GroupByNum-4 lst 2) ;;根据需要自己修改，有几项填几项
(GroupByNum-5 lst 2) ;;根据需要自己修改，有几项填几项
)
)

ayl1004 · 发表于 2017-6-6 19:39:55

什么都好，就是num=0的时候爆CAD了

/db_自贡黄明儒_ · 发表于 2017-6-6 19:42:06

N版的表太长，不方面阅读。

;;(GroupByNum-2 '(1 2 3 4 5 6 7) 2) => ((1 2) (3 4) (5 6) (7 nil))
(defun GroupByNum-2 (L n / rtn)
(while L
(setq LTemp nil)
(repeat n
(setq LTemp (cons (car L) LTemp))
(setq L (cdr L))
)
(setq rtn (cons (reverse LTemp) rtn))
)
(reverse rtn)
)

newer · 发表于 2017-6-6 19:51:08

/db_自贡黄明儒_ 发表于 2017-6-6 19:42

(xd::benchmark
'((GroupByNum-1 lst 2)
(GroupByNum-2 lst 2)
)
)

Elapsed milliseconds / relative speed for 65536 iteration(s):

(GROUPBYNUM-2 LST 2).....1640 / 1.04 <fastest>
(GROUPBYNUM-1 LST 2).....1704 / 1 <slowest>

GroupByNum-2 胜出

marting · 发表于 2017-6-6 19:57:27

来一个

(defun GroupByNum-3 (l n)
(defun f (a b n i)
(if (> n 0)
(f (cdr a) (cons (car a) b) (1- n) i)
(cons (reverse b) (GroupByNum-3 a i))
)
)
(if l
(f l nil n n)
)
)

newer · 发表于 2017-6-6 20:08:33

marting 发表于 2017-6-6 19:57

1000个元素的表

(xd::benchmark
'((GroupByNum-1 lst 2)
(GroupByNum-2 lst 2)
(GroupByNum-3 lst 2)
)
)

Elapsed milliseconds / relative speed for 2048 iteration(s):

(GROUPBYNUM-3 LST 2).....1875 / 1.46 <fastest>
(GROUPBYNUM-2 LST 2).....2718 / 1.01
(GROUPBYNUM-1 LST 2).....2734 / 1 <slowest>

GroupByNum-3 胜出，快出近50%了，优势比较大。

q3_2006 · 发表于 2017-6-6 20:13:25

(defun LM:group<n ( l n / a b m )
(while l
 (setq m n)
 (while (and l (< 0 m))
 (setq a (cons (car l) a)
 l (cdr l)
 m (1- m)
 )
 )
 (setq b (cons (reverse a) b)
 a nil
 )
)
(reverse b)
)

/db_自贡黄明儒_ · 发表于 2017-6-6 20:20:22

本帖最后由 /db_自贡黄明儒_ 于 2017-6-6 20:22 编辑

newer 发表于 2017-6-6 20:08

M快那么多,是不是因为定义了一个函数的缘故？那我改一下呢。;;(GroupByNum-4 '(1 2 3 4 5 6 7) 2) => ((1 2) (3 4) (5 6) (7 nil))
(defun GroupByNum-4 (L n / F L LTEMP)
  (defun F ()
(repeat n
   (setq LTemp (cons (car L) LTemp))
   (setq L (cdr L))
)
(reverse LTemp)
  )
  (while L
(setq LTemp nil)
(setq rtn (cons (F) rtn))
  )
  (reverse rtn)
)

newer · 发表于 2017-6-6 20:23:02

q3_2006 发表于 2017-6-6 20:13

(xd::benchmark
'((GroupByNum-1 lst 2)
(GroupByNum-2 lst 2)
(GroupByNum-3 lst 2)
(LM:group<n lst 2)
)
)

Elapsed milliseconds / relative speed for 1024 iteration(s):

(LM:GROUP<N LST 2).......1000 / 1.53 <fastest>
(GROUPBYNUM-3 LST 2).....1063 / 1.44
(GROUPBYNUM-2 LST 2).....1500 / 1.02
(GROUPBYNUM-1 LST 2).....1531 / 1 <slowest>

LM:group<n 胜出，GroupByNum-3 稍微落后，领先于其他两个较多。

wowan1314 · 发表于 2017-6-6 20:51:20

插一脚

(defun t11 (l n / j jj i)
(setq i (1+ n))
(foreach m l
(if (> (setq i (1- i)) 0)
(setq j (cons m j))
(setq jj (cons (reverse j) jj) i n j (cons m nil))
)
)
(if (= (setq i (length j)) n)
(reverse jj)
(progn
(while (> n i)
(setq j (cons nil j) i (1+ i))
)
(reverse (cons (reverse j) jj))
)
)
)

newer · 发表于 2017-6-6 21:27:30

wowan1314 发表于 2017-6-6 20:51

换到笔记本，G3表现有些差距

(xd::benchmark
'((GroupByNum-1 lst 2)
(GroupByNum-2 lst 2)
(GroupByNum-3 lst 2)
(LM:group<n lst 2)
(t11 lst 2)
)
)

Elapsed milliseconds / relative speed for 32768 iteration(s):

(T11 LST 2)..............1859 / 1.24 <fastest>
(GROUPBYNUM-2 LST 2).....1922 / 1.2
(LM:GROUP<N LST 2).......1937 / 1.19
(GROUPBYNUM-1 LST 2).....2187 / 1.06
(GROUPBYNUM-3 LST 2).....2313 / 1 <slowest>

T11 胜出，前三项差距都不大。

newer · 发表于 2017-6-6 21:28:39

/db_自贡黄明儒_ 发表于 2017-6-6 20:20

老黄，你这个我一放进去测试，CAD就死。单独能执行。

Lispboy · 发表于 2017-6-6 22:04:57

本帖最后由 newer 于 2017-6-6 22:27 编辑

来一个，这个是纯粹为了追求速度，小表没优势，请大表测试

(defun GroupByNum-5 (l n / b lst)
(setq b (list '(reverse a)))
(repeat (/ n 4)
(setq b (cons '(setq
a
(cons (cadddr l) (cons (caddr l) (cons (cadr l) (cons (car l) a))))
l
(cddddr l)
)
b
)
)
)
(setq n (rem n 4))
(repeat (/ n 3)
(setq b (cons '(setq
a
(cons (caddr l) (cons (cadr l) (cons (car l) a)))
l
(cdddr l)
)
b
)
)
)
(setq n (rem n 3))
(repeat (/ n 2)
(setq b (cons '(setq
a
(cons (cadr l) (cons (car l) a))
l
(cddr l)
)
b
)
)
)
(setq n (rem n 2))
(repeat (/ n 1)
(setq b (cons '(setq
a
(cons (car l) a)
l
(cdr l)
)
b
)
)
)
(eval (cons 'defun (cons 'f1 (cons '(a) b))))
(while l (setq lst (cons (f1 nil) lst)))
(reverse lst)
)

(defun GroupByNum-5 (l n / b lst) 
 (setq b (list '(reverse a))) 
 (repeat (/ n 4) 
  (setq b (cons '(setq 
                  a 
                  (cons (cadddr l) (cons (caddr l) (cons (cadr l) (cons (car l) a)))) 
                  l 
                  (cddddr l) 
                 ) 
                b 
          ) 
  ) 
 ) 
 (setq n (rem n 4)) 
 (repeat (/ n 3) 
  (setq b (cons '(setq 
                  a 
                  (cons (caddr l) (cons (cadr l) (cons (car l) a))) 
                  l 
                  (cdddr l) 
                 ) 
                b 
          ) 
  ) 
 ) 
 (setq n (rem n 3)) 
 (repeat (/ n 2) 
  (setq b (cons '(setq 
                  a 
                  (cons (cadr l) (cons (car l) a)) 
                  l 
                  (cddr l) 
                 ) 
                b 
          ) 
  ) 
 ) 
 (setq n (rem n 2)) 
 (repeat (/ n 1) 
  (setq b (cons '(setq 
                  a 
                  (cons (car l) a) 
                  l 
                  (cdr l) 
                 ) 
                b 
          ) 
  ) 
 ) 
 (eval (cons 'defun (cons 'f1 (cons '(a) b)))) 
 (while l (setq lst (cons (f1 nil) lst))) 
 (reverse lst) 
)

newer · 发表于 2017-6-6 22:21:42

本帖最后由 newer 于 2017-6-6 22:25 编辑

Lispboy 发表于 2017-6-6 22:04

32768个元素的表，15个一组，测试
由于是大表，递归的1,3没加入测试。

(defun c:bench ()
(setq lst '(1 2))
(repeat 14
(setq lst (append lst lst))
)
(xd::quickbench
'(
; (GroupByNum-1 lst 15)
(GroupByNum-2 lst 15)
; (GroupByNum-3 lst 15)
(LM:group<n lst 15)
(t11 lst 15)
(GroupByNum-5 lst 15)
)
)
)

GROUPBYNUM-5 确实是为大表而生的，性能快的不是一点半点，
上面测试小表时候表现好的 LM:GROUP<N 在大表下性能最低了。

/db_自贡黄明儒_ · 发表于 2017-6-6 22:41:49

再战

;;(GroupByNum-6 '(1 2 3 4 5 6 7) 2) => ((1 2) (3 4) (5 6) (7 nil))
(defun GroupByNum-6 (L n / I LTEMP RNT)
(setq i n)
(foreach x L
(if (not (> i 0))
(setq rnt (cons (reverse Ltemp) rnt)
i n
Ltemp nil
)
)
(setq Ltemp (cons x Ltemp)
i (1- i)
)
)
(while (> i 0)
(setq Ltemp (cons nil Ltemp)
i (1- i)
)
)
(if Ltemp
(setq rnt (cons (reverse Ltemp) rnt))
)
(reverse rnt)
)
;;(GroupByNum-7 '(1 2 3 4 5 6 7) 2) => ((1 2) (3 4) (5 6) (7 nil))
(defun GroupByNum-7 (L n / I LTEMP RNT)
(setq i n)
(while (and L (> i 0))
(while (> i 0)
(setq Ltemp (cons (car L) Ltemp)
L (cdr L)
i (1- i)
)
)
(setq rnt (cons (reverse Ltemp) rnt)
i n
Ltemp nil
)
)
(reverse rnt)
)

;;(GroupByNum-6 '(1 2 3 4 5 6 7) 2) => ((1 2) (3 4) (5 6) (7 nil)) 
(defun GroupByNum-6 (L n / I LTEMP RNT) 
  (setq i n) 
  (foreach x L 
    (if        (not (> i 0)) 
      (setq rnt          (cons (reverse Ltemp) rnt) 
            i          n 
            Ltemp nil 
      ) 
    ) 
    (setq Ltemp        (cons x Ltemp) 
          i        (1- i) 
    ) 
  ) 
  (while (> i 0) 
    (setq Ltemp        (cons nil Ltemp) 
          i        (1- i) 
    ) 
  ) 
  (if Ltemp 
    (setq rnt (cons (reverse Ltemp) rnt)) 
  ) 
  (reverse rnt) 
) 
 
;;(GroupByNum-7 '(1 2 3 4 5 6 7) 2) => ((1 2) (3 4) (5 6) (7 nil)) 
(defun GroupByNum-7 (L n / I LTEMP RNT) 
  (setq i n)   
  (while (and L (> i 0)) 
    (while (> i 0) 
      (setq Ltemp (cons (car L) Ltemp) 
            L          (cdr L) 
            i          (1- i) 
      ) 
    ) 
    (setq rnt        (cons (reverse Ltemp) rnt) 
          i        n 
          Ltemp        nil 
    ) 
  ) 
  (reverse rnt) 
)

账号		自动登录	找回密码
密码			立即注册

[有奖答题] 【挑战】表按照给定的数重新分组

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

评分

评分

评分

评分