;;reset startpoint of lightweightpolyline 
(defun c:tt (/ e p el el1 pam pam0 pam1 pam2 el2 el3)
  (if (and (setq e (entsel "\nSelect LightweightPolyline: "))
	   (setq p (getpoint "\nPick Startpoint to: "))
      )
    (progn
      (setq el	 (entget (car e));_ dxf list
	    el1	 (vl-remove-if-not
		   '(lambda (x) (vl-position (car x) '(10 40 41 42)))
		   (member (assoc 10 el) el)
		 );_property of coordinate (point startwidth endwidth bulge ...)
	    el2	 (reverse (cdr (member (assoc 10 el) (reverse el))));_lwpolyline dxf header
	    pam	 (vlax-curve-getparamatpoint
		   (car e)
		   (vlax-curve-getclosestpointto (car e) p)
		 );_ get index of pline
	    pam1 (fix pam);_ previous index
	    pam2 (1+ pam1);_ next index
      )
      (if (>= (- pam pam1) 0.5)
	(setq pam0 pam2)
	(setq pam0 pam1)
      );_ near index
      (setq p (nth (* 4 pam0) el1));_ A set of four 
      (setq el3	(append	(member p el1)
			(reverse (cdr (member p (reverse el1))))
		)
      );_ reset points
      (entmod (append el2 el3))
    )
  )
  (princ)
)