[求助]：选择集中提取实体

小妹丁

在SSGET生成的选择集（包含线段和圆弧）中，分别提出最大圆弧半径和最小圆弧半径的实体。
我想不到办法。
（最好是LISP，如是VLISP请加点注解。）
多谢先！

aidraft

(DEFUN TEST(ss / lst)
  (setq lst (sset->EnList ss))
  (setq lst (vl-remove-if-not '(lambda (e) (= (cdr (assoc 0 (entget e))) "ARC")) lst))
  (setq lst (vl-sort lst '(lambda (e1 e2) (< (cdr (assoc 40 (entget e1)))
                                             (cdr (assoc 40 (entget e2)))))))
  (setq en1 (car lst); Smallest radius
        en2 (last lst)); Greatest radius
)
(defun sset->EnList (ss / idx RetLst)
  (setq idx -1)
  (repeat (sslength ss)
    (setq RetLst (cons (ssname ss (setq idx (1+ idx))) RetLst)))
)

小妹丁

真的很好，看来要学VLISP了。

wkai

AutoLisp的代码
[PHP](defun max_min_rad (s / e entlst n )
  (repeat (setq n (sslength s))
    (setq e (ssname s (setq n (1- n))))
    (setq entlst (cons (list (cdr (assoc 40 (entget e))) e) entlst))
  )
  (list        (cadr (assoc (apply 'max (mapcar 'car entlst)) entlst))
        (cadr (assoc (apply 'min (mapcar 'car entlst)) entlst))
  )
)[/PHP]
测试
[PHP](defun c:test ()
  (and (setq s (ssget '((0 . "ARC"))))
       (mapcar '(lambda (x) (redraw x 3)) (max_min_rad s))
  )
)[/PHP]

小妹丁

最初由 wkai 发布
[B]AutoLisp的代码
[PHP](defun max_min_rad (s / e entlst n )
  (repeat (setq n (sslength s))
    (setq e (ssname s (setq n (1- n))))
    (setq entlst (cons (list (cdr (assoc 40 (entget e))) e) entlst)... [/B]

选集中不能过滤其它对象，要同时得到最大半径和最小半径对象。

wkai

To 小妹丁：
1 选择时已经过滤了呀，只能选到ARC
2 max_min_rad  函数返回的就是最大和最小半径的圆弧呀！

小妹丁

最初由 wkai 发布
[B]To 小妹丁：
1 选择时已经过滤了呀，只能选到ARC
2 max_min_rad  函数返回的就是最大和最小半径的圆弧呀！ [/B]

选择时还要可以选到其它对象，不能只选圆弧。
[php]
(defun max_min_rad (s)
  (repeat (setq n (sslength s))
    (setq e (ssname s (setq n (1- n))))
    (setq entlst (cons (list (cdr (assoc 40 (entget e))) e) entlst))
  )
  (setq
    kk
     (list (cadr (assoc (apply 'max (mapcar 'car entlst)) entlst))
           (cadr (assoc (apply 'min (mapcar 'car entlst)) entlst))
     )
  )
  (setq maxrac (car kk))；最大圆弧
  (setq minrac (cadr kk))；最小圆弧
)

(defun c:test ()
  (setq s (ssget '((0 . "ARC"))))；这里不要过滤
  (max_min_rad s)
)
[/php]

wkai

[PHP](defun max_min_rad (s / n e s maxrac minrac)
  (repeat (setq n (sslength s))
    (setq e (ssname s (setq n (1- n))))
    (and (= "ARC" (cdr (assoc 0 (entget e))))
         (setq entlst (cons (list (cdr (assoc 40 (entget e))) e) entlst))
    )
  )
  (setq        maxrac (cadr (assoc (apply 'max (mapcar 'car entlst)) entlst))
        minrac (cadr (assoc (apply 'min (mapcar 'car entlst)) entlst))
  )  
)[/PHP]

梦断江南

[php]
(defun m-indxf (ss fil id / i e a lst)
  (if (and ss (setq i -1 ss (ssget "p" fil)))
    (progn
     (while (setq e (ssname ss (setq i (1+ i))))
      (if (setq a (assoc id (entget e)))(setq lst (cons (cdr a) lst)))
     )
    (if (setq lst (vl-sort lst '< )) (list (car lst)(last lst)) nil)
    )
    nil)
)[/php]
[php]
;应用:
(defun c:tt ( / ss)
  (setq ss (ssget))
  (m-indxf ss '((0 . "ARC")) 40)
)
[/php]

小妹丁

最初由 梦断江南 发布
[B][php]
(defun m-indxf (ss fil id / i e a lst)
  (if (and ss (setq i -1 ss (ssget "p" fil)))
    (progn
     (while (setq e (ssname ss (setq i (1+ i))))
      (if (setq a (assoc id (entget e)))(set... [/B]

我试了一下，只返回半径，没有实体，过滤的方法很好，方便。

梦断江南

[php]
(defun m-indxf (ss fil id / i e a lst)
  (if (and ss (setq i -1 ss (ssget "p" fil)))
    (progn
     (while (setq e (ssname ss (setq i (1+ i))))
      (if (setq a (assoc id (entget e)))(setq lst (cons (list e (cdr a)) lst)))
     )
    (if (setq lst (vl-sort lst '(lambda(x y)(<(cadr x)(cadr y)))))
      (list (car lst)(last lst))
      nil)
    )
    nil)
)
[/php]

命令: tt
选择对象: 指定对角点: 找到 4 个
选择对象:
((<图元名: 7ef8ae78> 1467.33) (<图元名: 7ef8ae50> 10750.9))