[求助]：大家来编一个五角星程序

xxming

大家来编一个五角星程序

zhynt

什么意思？有什么用？有什么要求？

zhouri

似乎没什么难度，像我这种初学者也问题不大。

xxming

;谁能完善程序，给五角星能填充上实体颜色
(defun c:5poly()
  (setq os (getvar "osmode")
        cmdcho (getvar "cmdecho"))
  (setvar "osmode" 0)
  (setvar "cmdecho" 0)
  (tsc)
  (setq pt1 (getpoint "\n插入点"))
  (setq pt2 (polar pt1 (angtof "-108") (sc 75.6836)))
  (setq pt3 (polar pt2 (angtof "36.00") (sc 75.6836)))
  (setq pt4 (polar pt3 pi (sc 75.6836)))
  (setq pt5 (polar pt4 (angtof "-36.00") (sc 75.6836)))
  (command "pline" pt1 pt2 pt3 pt4 pt5 "c" )
  (setvar "osmode" os)
  (setvar "cmdecho" cmdcho)
)
;比例因子
(defun tsc()
(if (= tscale nil)
(setq tscale 1)
)
(initget 6)
(setq input (getreal(strcat "\n输入比例因子<"
                            (rtos tscale)
                            ">")))
(if input
  (setq tscale input)
)
)

;比例放大或缩小

(defun sc(x)
  (* x tscale)
)

xyp1964

[php]
;;;加载通用函数
;;;下载：http://www.xdcad.net/forum/showthread.php?s=&threadid=325268
(load "xyp_lib")
;;;“伪”五角星程序
(defun c:test (/ pt1 s1)
  (cmdla0)
  (command ".undo" "BE")
  (jzhz)
  (setq        pt1 (getpoint "\n五角星中心点 : ")
        hh  (ureal 1 "" "\n高度" hh)
        CO  (ureal 1 "" "\n颜色" CO)
  )
  (command "text" "j" "mc" pt1 hh "" "★")
  (setq s1 (entlast))
  (command "chprop" s1 "" "c" (fix CO) "")
  (command ".undo" "E")
  (cmdla0)
)
[/php]

aeo

最初由 xxming 发布
[B];谁能完善程序，给五角星能填充上实体颜色
(defun c:5poly()
  (setq os (getvar "osmode")
        cmdcho (getvar "cmdecho"))
  (setvar "osmode" 0)
  (setvar "cmdecho" 0)
  (tsc)
  (setq pt1 (getpoint "\n?.. [/B]

你这个是正五边形吧?

临时写了一个

[php]
;;;BY Aeo
(defun c:wjx( / ang cen k p1 p2 p3 pts r)
(if(and(setq cen(getpoint "\n中心点 "))
        (setq r(getdist "\n半径"cen))
        (setq ang (* 0.1 pi)
               k (* r(/ (sin(* pi 0.2))(cos(* pi 0.2))))
               pts '("c")
        )
    )
   (progn
    (repeat 5
      (setq p1(polar cen ang r)
            p2(polar p1(+ ang pi(* pi 0.1))k)
            p3(polar p1(- (+ ang pi) (* pi 0.1))k)
            pts(append (list p3 p1 p2) pts)
            ang(+ ang(* pi 0.4))  ;;72度
      )
    )
    (apply 'command (cons "pline" pts))
  ))
  (entlast);;you can hatch the last-ename
)
[/php]

aeo

n角星
[php]
;;;By Aeo
(defun c:xin( / ang ang0 ang1 cen gg k no p1 p2 p3 pts r)
(if(and(setq no(getint "\n几角星: "))
        (or(> no 4)(prompt "\n请大于4"))
        (setq cen(getpoint "\n中心点 "))
        (setq r(getdist "\n半径"cen))
        (setq ang0(/ pi no 0.5))
        (setq gg (- 1(cos ang0))
              k  (* r(/ gg (sin ang0)))
              ang (/ (- pi ang0 ang0)2)
              ang1 ang
              pts '("c")
        )
    )
   (progn
    (repeat no
      (setq p1(polar cen ang r)
            p2(polar p1(+ ang pi ang1)k)
            p3(polar p1(- (+ ang pi) ang1)k)
            pts(append (list  p1 p2) pts)
            ang(+ ang ang0)  
      )
    )
    (apply 'command (cons "pline" pts))
  ))
  ;(entlast)       ;;you can hatch the last-ename
  (princ)
)
[/php]

xlmx-whj

很好用没想到cad也可方便的画星形了。要是能用多边形边长来决定星形大小就更好了，老大要是能加入控制n角星内角半径可调就更好了。看它沉底了我顶上去。