[求助]：画流速矢量图

y562288 · 发表于 2005-9-17 16:45:37

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

知道原点，其他的点离他的距离和角度都知道，怎么用程序一次性全部画出来，当然啦，可以一个一个的按照@长度<角度的方法画出来，希望找到简便方法，求助！！！

请勿在程序库板块发提问贴（请看程序库置顶贴规定）
扣分后转移到相应板块－－－by 梦断江南 [/COLOR]

eachy · 发表于 2005-9-17 17:26:52

(polar pt angle distance)

y562288 · 发表于 2005-9-18 09:33:20

eachy 老兄，可以具体点么？或者是个lsp程序之类的，非常感谢啊

eachy · 发表于 2005-9-18 12:17:51

最初由 y562288 发布
[B]eachy 老兄，可以具体点么？或者是个lsp程序之类的，非常感谢啊 [/B]

请把你的要求写详细，知道点？点是什么格式？是文件还是在纸上？
你对Lisp熟知程度如何？

y562288 · 发表于 2005-9-18 16:24:28

我对lsp不太熟悉，在大学学过，现在忘记差不多了。我要求的是已知一个原点，其他的都是相对于这个原点的长度和角度，如270，转角80度。用极轴可以@270<-80这样的形式实现，但是由于点太多，要是这样一个个的输入的话，太麻烦了，希望找到一个小的程序可以一次性的画出来，其实和风玫瑰和波玫瑰图差不多了，只是这个的方向不是一定的24个方向了，我的qq24434145，可以直接交流，谢谢！

eachy · 发表于 2005-9-18 20:27:01

你还是没有说清点是什么格式，文本文件还是其他什么？

y562288 · 发表于 2005-9-18 20:46:46

谢谢关心，我的格式是excel格式的，长度和点分别是一列，就是要把excel里面的东西怎么在cad中画出来，当然啦，可以转换为直角坐标再来用多义线画，这样比较麻烦，而且长度变成了小数。

eachy · 发表于 2005-9-19 12:06:38

Excel 文件？

y562288 · 发表于 2005-9-19 14:16:49

是阿，文本文档也可以的啊，反正就是可以自己打进去的，word也可以，关键就是怎么在cad总快速画出来啊，yangquan@ctesi.com.cn是本人的邮箱呢，就是word或者excel或者文本文档，记事本等上的数据（长度，转角），怎么把他在excel中画出来呢？

eachy · 发表于 2005-9-19 22:32:20

文件格式要求为文本格式，每行两个数据，以空格分隔，第一个为距离，第二个为角度(度单位)，如
1.19 120
1.20 130
2.15 140
1.19 150
1.17 160

(defun xd-mkline (p1 p2)
(if (setq ent (entmakex (list '(0 . "LINE")
'(100 . "AcDbEntity")
'(100 . "AcDbLine")
(cons 10 p1)
(cons 11 p2)
'(210 0. 0. 1.)
)
)
)
ent
)
)
;;文件转换为表
;;fn 全路径文件名
(defun xd-readfile (fn / f l ll)
(setq f (open fn "r"))
(while (setq l (read-line f))
(setq ll (cons (read (strcat "(" l ")")) ll))
)
(close f)
ll
)
;;制作做块头
(defun xd-MKblock (blockname pt / blocktype)
(if (or (/= 'STR (type blockname)) (= "" blockname))
(setq blockname "*A")
)
(if (= (substr blockname 1 1) "*")
(setq blocktype 1
blockname "*A"
)
(setq blocktype 0)
)
(entmake (list
'(0 . "BLOCK")
'(100 . "AcDbEntity")
'(100 . "AcDbBlockBegin")
(cons 2 blockname)
(cons 70 blocktype) ;_'(70 . 2);_属性块
(cons 10 pt)
)
)
)
;;;做块尾
(defun xd-MKENDBLK ()
(entmake '((0 . "ENDBLK")))
)
;;;插入图块
(defun xd-MkINSERT (bname ins-pt)
(entmakex (list
'(0 . "INSERT")
'(100 . "AcDbEntity")
'(100 . "AcDbBlockReference")
;;'(66 . 1);_属性
(cons 2 bname)
(cons 10 ins-pt)
)
)
)
(defun xd-dtr (j$) (* (/ j$ 180.0) pi))
(defun c:tt (/ fn p lst blkna)
(if (and (setq fn (getfiled "Select Points file" "" "txt" 8))
(setq p (getpoint "\nBase Point: "))
)
(progn
(command ".undo" "be")
(setq lst (xd-readfile (findfile fn)))
(xd-MKblock "*U" p)
(xd-mkline (polar p pi 0.2)
(polar p 0. 0.2)
)
(xd-mkline (polar p (/ pi 2) 0.2)
(polar p (- (/ pi 2)) 0.2)
)
(mapcar
'(lambda (x)
(xd-mkline p (setq p1 (polar p (xd-dtr (cadr x)) (car x))))
(xd-mkline p1 (polar p1 (+ (angle p1 p) (xd-dtr 10.)) 0.1))
(xd-mkline p1 (polar p1 (- (angle p1 p) (xd-dtr 10.)) 0.1))
)
lst
)
(setq blkna (xd-mkendblk))
(xd-mkinsert blkna p)
(command ".undo" "end")
)
)
(princ)
)

(defun xd-mkline (p1 p2) 
  (if (setq ent        (entmakex (list        '(0 . "LINE") 
                                '(100 . "AcDbEntity") 
                                '(100 . "AcDbLine") 
                                (cons 10 p1) 
                                (cons 11 p2) 
                                '(210 0. 0. 1.) 
                          ) 
                ) 
      ) 
    ent 
  ) 
) 
;;文件转换为表 
;;fn 全路径文件名 
(defun xd-readfile (fn / f l ll) 
  (setq f (open fn "r")) 
  (while (setq l (read-line f)) 
    (setq ll (cons (read (strcat "(" l ")")) ll)) 
  ) 
  (close f) 
  ll 
) 
;;制作做块头 
(defun xd-MKblock (blockname pt / blocktype) 
  (if (or (/= 'STR (type blockname)) (= "" blockname)) 
    (setq blockname "*A") 
  ) 
  (if (= (substr blockname 1 1) "*") 
    (setq blocktype 1 
          blockname "*A" 
    ) 
    (setq blocktype 0) 
  ) 
  (entmake (list 
             '(0 . "BLOCK") 
             '(100 . "AcDbEntity") 
             '(100 . "AcDbBlockBegin") 
             (cons 2 blockname) 
             (cons 70 blocktype) ;_'(70 . 2);_属性块 
             (cons 10 pt) 
           ) 
  ) 
) 
;;;做块尾 
(defun xd-MKENDBLK () 
  (entmake '((0 . "ENDBLK"))) 
) 
;;;插入图块 
(defun xd-MkINSERT (bname ins-pt) 
  (entmakex (list 
              '(0 . "INSERT") 
              '(100 . "AcDbEntity") 
              '(100 . "AcDbBlockReference") 
              ;;'(66 . 1);_属性 
              (cons 2 bname) 
              (cons 10 ins-pt) 
            ) 
  ) 
) 
(defun xd-dtr (j$) (* (/ j$ 180.0) pi)) 
(defun c:tt (/ fn p lst blkna) 
  (if (and (setq fn (getfiled "Select Points file" "" "txt" 8)) 
           (setq p (getpoint "\nBase Point: ")) 
      ) 
    (progn 
      (command ".undo" "be") 
      (setq lst (xd-readfile (findfile fn))) 
      (xd-MKblock "*U" p) 
      (xd-mkline (polar p pi 0.2) 
                 (polar p 0. 0.2) 
      ) 
      (xd-mkline (polar p (/ pi 2) 0.2) 
                 (polar p (- (/ pi 2)) 0.2) 
      ) 
      (mapcar 
        '(lambda (x) 
           (xd-mkline p (setq p1 (polar p (xd-dtr (cadr x)) (car x)))) 
           (xd-mkline p1 (polar p1 (+ (angle p1 p) (xd-dtr 10.)) 0.1)) 
           (xd-mkline p1 (polar p1 (- (angle p1 p) (xd-dtr 10.)) 0.1)) 
         ) 
        lst 
      ) 
      (setq blkna (xd-mkendblk)) 
      (xd-mkinsert blkna p) 
      (command ".undo" "end") 
    ) 
  ) 
  (princ) 
)

y562288 · 发表于 2005-9-20 08:57:28

非常感谢eachy ，现在可以用了，看来要加强lsp语言的学习才行，大学期间的忘记了，你的这个程序非常好用

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：画流速矢量图

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

浏览过的版块