[求助]：请教用vba做二次开发，应该怎样打包

saintlzh

请教用vba做二次开发，应该怎样打包

efan2000

这个比较复杂，要用专业的安装软件制作工具。
还有其它要注意的地方：首先要将安装后的目录加入到ACAD的支持路径中。其实要加载自己的菜单文件，最好能创建自己的配置文件，然后在该配置文件中操作。

gjliang

可以写一段lisp把你安装的目录自动加载cad的搜索路径，然后自动加载菜单文件，这样就能很好的解决vba的自动安装问题了。下面是我的例子，希望能对你起到一定的帮助。
;;;自动加载自定义的菜单方法
;;;以下代码可自动添加辅助工具所在的目录并自动加载辅助工具菜单：

;;;     MC-LOAD.LSP
;;    以下为加载设计工具

(defun add_path ( dir / a b c)
  (if (and dir
           (setq c (getenv "ACAD"))               
      );and
      (progn
       ;看看DIR目录是否在AutoCAD的支持目录中
       (setq a (strcase c)
             b (strcase dir)
       );setq
       (if (not (equal ";" (substr a 1 1)))
           (setq a (strcat ";" a))  ;在 a 前面加上一个";"   
       );if
       (if (not (equal ";" (substr a (strlen a) 1)))
           (setq a (strcat a ";")
                 c (strcat c ";")  ;在后面加上一个";"
           );setq
       );if
       (if (not (wcmatch a (strcat "*;" b ";*"))) ;查看“DIR”是否在支持路径中?
           (progn
            (setq c (strcat c dir));没有时则添加
            (setenv "ACAD" c)  ;设置到支持路径的环境变量中
           );progn
           (setq c nil)
       );if   
      );progn then
      (setq c nil)
  );if
  c
);defun add_path

(defun acc()
  (setvar "cmdecho" 0)
  (if (not(menugroup "test"))
    (if  (findfile "test.mnu")
      (progn
        (setvar "filedia" 0)
        (command "menuload" "test")
        (setvar "filedia" 1)
      )
      (progn
        (setq a (findfile "acad.exe"))                 ; 建立指向辅助工具的标准路径
        (setq          a (substr a 1 (- (strlen a) 8))
            bonus_path (strcat a "design")         
        );setq
        (findfile bonus_path)                          ; 查看辅助工具目录是否存在
        (add_path bonus_path)                          ; 将路径添加到支持路径中
        (if (findfile "test.mnu")
          (progn
            (setvar "filedia" 0)
            (command "menuload" "test")
            (setvar "filedia" 1)
          )
        )
      )
    )
  )
  (if  (findfile "jingtong.lsp")     ;如果有辅助工具配套程序，则同时加载
    (load "jingtong")
  )
  (setvar "cmdecho" 1)
  (princ)
)
(acc)
把以上代码拷贝到你的acad2000doc.lisp中，并把acad2000doc.lisp文件做为一个安装文件运行安装程序时把此文件覆盖你的support目录里文件。
以下是自动加载dvb文件的，写在你的菜单文件的mnl文件中的。
(vl-load-com)
;;自动加载VBA程序的函数
(defun AutoVBALoad (cmdname project macro)
  (eval
    (list 'defun
  (read (strcat "C:" cmdname))
  nil
  (list
    'vl-vbarun
    (strcat
      project
      "!"
      (if macro
macro
cmdname
      )
    )
  )
  (princ)
    )
  )
)

(AutoVBALoad "lh" "test.dvb" "lhjc")

(AutoVBALoad "lht" "test.dvb" "lhtz")

(AutoVBALoad "yh" "test.dvb" "yhjc")

(AutoVBALoad "yht" "test.dvb" "yhtz")

(AutoVBALoad "rh" "test.dvb" "rhtz")

(AutoVBALoad "sa" "test.dvb" "shtz")

(AutoVBALoad "si" "test.dvb" "sitz")

(AutoVBALoad "nt" "test.dvb" "niutui")

(AutoVBALoad "cm" "test.dvb" "clbm")

(AutoVBALoad "cs" "test.dvb" "clbs")

(AutoVBALoad "bg" "test.dvb" "biaog")

(AutoVBALoad "zx" "test.dvb" "zhoux")

(AutoVBALoad "gg" "test.dvb" "lg")

(AutoVBALoad "yg" "test.dvb" "yg")

(AutoVBALoad "zlk" "test.dvb" "zlk")

(AutoVBALoad "zb" "test.dvb" "zlky")

(AutoVBALoad "zg" "test.dvb" "zlgd")

(AutoVBALoad "mg" "test.dvb" "mg")

(AutoVBALoad "ul" "test.dvb" "ul")

(AutoVBALoad "ll" "test.dvb" "ll")

(AutoVBALoad "fd" "test.dvb" "fdq")

(AutoVBALoad "fq" "test.dvb" "fdq1")

(AutoVBALoad "xl" "test.dvb" "tzzz")

(AutoVBALoad "td" "test.dvb" "txdm")

(AutoVBALoad "tz" "test.dvb" "tz")

(AutoVBALoad "gd" "test.dvb" "ggjd")

(AutoVBALoad "yj" "test.dvb" "ygjd")

(AutoVBALoad "nj" "test.dvb" "xlzz")

(AutoVBALoad "wj" "test.dvb" "wmjd")

(AutoVBALoad "wg" "test.dvb" "wgmg")

(AutoVBALoad "lj" "test.dvb" "zljd")

(AutoVBALoad "n" "test.dvb" "edex")

(AutoVBALoad "js" "test.dvb" "js.exe")

(AutoVBALoad "k" "test.dvb" "k")
以下是自动加载菜单的部分
(defun placemenu (/ n)
  (if (menugroup "test")
    (progn
      (setq n 1)
      (while (< n 24)
        (if (menucmd (strcat "P" (itoa n) ".1=?"))
          (setq n (+ n 1))
          (progn
            (if        (> n 3)
              (setq n (- n 2))
              (setq n 3)
            )                                ;if
            (menucmd (strcat "p" (itoa n) "=+test.pop1"))
           ;; (menucmd (strcat "p" (itoa n) "=+XDSOFT.pop1"))
            (setq n 25)
          )                                ;progn
        )                                ;if
      )                                        ;while
    )                                        ;progn
  )                                        ;if
  (princ)
)                                        ;defun placemenu
(setvar "cmdecho" 0)
(placemenu)
也是在mnl文件里的。
当然这些文件我也是看到别人的，如果斑竹有什么好的方法，还望指教！