[必看]：如何entmake lwpolyline?

lxf-ysy · 发表于 2003-4-22 22:35:48

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

如何按给定的点表 entmake 一条 lwpolyline?
我现在是用vla 函数实现的不知道如何用entmake 实现

aeo · 发表于 2003-4-22 22:44:27

(defun make-pl(ptn / li)
(setq li (mapcar '(lambda ($u) (cons 10 $u) ) ptn))
(setq li(append(list '(0 . "LWPOLYLINE")'(100 . "AcDbEntity")'(100 . "AcDbPolyline")
(cons 90(length ptn)) ) li))
(entmake li)
)

都是直线!

lxf-ysy · 发表于 2003-4-22 23:04:47

多谢我可真是笨死了忘记了写90 组码

小菜 · 发表于 2006-6-15 18:35:48

如何让多义线封闭啊？我试了几次都不成功

飞马牌汽车 · 发表于 2006-6-15 20:04:40

封闭多义线

(setq ptlist '((0 0 0) (100 0 0)
(100 100 0)
(0 100 0)
)
)
(setq width 10)
(setq ed (list (cons 0 "LWPOLYLINE") (cons 100 "AcDbEntity") (cons 100 "AcDbPolyline")
(cons 90 (length ptlist)) (cons 70 (if closed
1
1
)
) (cons 43 width) (cons 67 0)
) ; list
)
;;; setq
(foreach elem ptlist
(setq ed (append
ed
(list (cons 10 elem))
)
)
)
;;; foreach
(entmake ed)

小菜 · 发表于 2006-6-16 08:39:23

谢谢，有时候70组码的在表中的位置似乎会影响到entmake是否成功

caddog · 发表于 2006-6-30 23:19:14

/www.theswamp.org/上Kerry Brown的代码

[FONT=courier new]
(SETQ point-list (LIST '(66.8823 62.975) '(123.03 109.175)
'(160.462 152.625) '(236.978 165.825)
'(263.951 212.025) '(334.962 221.925)
'(347.072 230.725) '(473.681 217.525)
'(475.883 187.825) '(452.763 124.025)
'(378.449 95.425) '(292.576 52.525)
)
)
(SETQ bulge-list
'(0.0 0.0 0.0 0.465609 -1.22874 0.0 0.0 0.0 0.0 0.0 0.0 0.0)
)
(ENTMAKE
(APPLY
(FUNCTION APPEND)
(CONS (LIST '(0 . "LWPOLYLINE")
'(100 . "AcDbEntity")
'(67 . 0)
'(410 . "Model")
'(8 . "0")
;; '(6 . "HIDDEN") ; Linetype
;; (cons 62 acyellow) ; Color
'(100 . "AcDbPolyline")
(CONS 90 (LENGTH point-list)) ; Vertices
'(70 . 0)
;;'(70 . 1) ; Closed
)
(MAPCAR (FUNCTION LIST)
(MAPCAR (FUNCTION (LAMBDA (a) (CONS 10 a))) point-list)
(MAPCAR (FUNCTION (LAMBDA (b) (CONS 42 b))) bulge-list)
)
)
)
)
[/FONT]

复制代码

xiao_longxin · 发表于 2006-6-30 23:38:10

可以生成带凸度的PLINE

;;生成一条pline
;;参数：
;;plist:坐标点表，如：((x1 y1 z1) (x2 y2 z2) (x2 y2 z2))或((x1 y1) (x2 y2) (x2 y2))
;;tudulist:各点之间的凸度表，与plist相对应，可为nil
;;bg：标高
;;clo:是否闭合，1:闭合，0：不闭合
;;(defun c:test ()
;;(setq a '((102.946 68.6354 3) (112.102 97.4851 3) (125.484 59.4879 3) (103.651 52.4513 3))
;; b '(-1.02092 -0.485629 0 -1.31201)
;;)
;;(makepline a b 211 1)
;;)
(defun xl:makepline (plist clo bg tudulist / dxf n i pt)
(setq bg (cons 38 bg)
i 0
n (length plist)
dxf nil
)
(if (= clo 1)
(entmake (list '(0 . "POLYLINE") '(66 . 1) '(70 . 1) bg))
(entmake (list '(0 . "POLYLINE") '(66 . 1) bg))
)
(repeat n
(setq pt (nth i plist)
pt (list (nth 0 pt) (nth 1 pt))
)
(if tudulist
(entmake (list (cons 0 "VERTEX")
(cons 10 pt)
(cons 42 (nth i tudulist))
)
)
(entmake (list (cons 0 "VERTEX")
(cons 10 pt)
)
)
)
(setq i (1+ i))
)
(entmake '((0 . "SEQEND")))
(princ)
)

;;生成一条pline 
;;参数： 
;;plist:坐标点表，如：((x1 y1 z1) (x2 y2 z2) (x2 y2 z2))或((x1 y1) (x2 y2) (x2 y2)) 
;;tudulist:各点之间的凸度表，与plist相对应，可为nil 
;;bg：标高 
;;clo:是否闭合，1:闭合，0：不闭合 
;;(defun c:test () 
;;(setq        a '((102.946 68.6354 3) (112.102 97.4851 3) (125.484 59.4879 3) (103.651 52.4513 3)) 
;;        b '(-1.02092 -0.485629 0 -1.31201) 
;;) 
;;(makepline a b 211 1) 
;;) 
 
(defun xl:makepline (plist clo bg tudulist / dxf n i pt) 
  (setq        bg  (cons 38 bg) 
        i   0 
        n   (length plist) 
        dxf nil 
  ) 
 
  (if (= clo 1) 
    (entmake (list '(0 . "POLYLINE") '(66 . 1) '(70 . 1) bg)) 
    (entmake (list '(0 . "POLYLINE") '(66 . 1) bg)) 
  ) 
  (repeat n 
    (setq pt (nth i plist) 
          pt (list (nth 0 pt) (nth 1 pt)) 
    ) 
    (if        tudulist 
      (entmake (list (cons 0 "VERTEX") 
                     (cons 10 pt) 
                     (cons 42 (nth i tudulist)) 
               ) 
      ) 
      (entmake (list (cons 0 "VERTEX") 
                     (cons 10 pt) 
               ) 
      ) 
    ) 
    (setq i (1+ i)) 
  ) 
  (entmake '((0 . "SEQEND"))) 
  (princ) 
)

账号		自动登录	找回密码
密码			立即注册

[必看]：如何entmake lwpolyline?

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子