[LISP函数]：程序加密问题?

ywqq · 发表于 2006-5-28 18:43:18

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

请问在LISP程序里能否读取机器码,或硬盘序号等,
然后通过一个算法产生一个序号,
再通过这个序号判断程序可否运行?
请指教..

zhang8755 · 发表于 2006-5-28 20:26:16

硬盘序号

[FONT=courier new]
;|
函数名: VxGetDriveInfos
功能: 返回选择磁盘信息
Copyright: ?001 MENZI ENGINEERING GmbH, Switzerland
参数[类型]:
Drv = 盘符, 如. "C" 或 "C:" [字串]
返回值[类型]:
磁盘信息 '(TotalSize FreeSpace DriveType FileSystem SerialNumber ShareName VolumeName) [表]
说明:
- TotalSize (kB) [实数] 磁盘空间或 network share.
- FreeSpace (kB) [REAL] 空闲空间 or network share.
- DriveType [INT]
0 = "Unknown"
1 = "Removable"
2 = "Fixed"
3 = "Network"
4 = "CD-ROM"
5 = "RAM Disk"
- FileSystem [STR] 磁盘系统格式, 如. "FAT", "NTFS", "CDFS".
- SerialNumber [INT] Returns the serial number used to uniquely identify a disk volume.
- ShareName [STR] Returns the network share name (UNC) for the specified drive. If it's
not a network drive, ShareName returns a zero-length string ("").
- VolumeName [STR] 卷标
0 The drive doesn't exist.
1 The drive is not ready. For removable-media drives and CD-ROM drives,
VxGetDriveInfos returns -1 when the appropriate media is not inserted
or not ready for access.
注意: 需要 ScrRun.dll.
|;
;(defun VxGetDriveInfos (Drv / DrvObj FilSys RetVal)
(defun V (Drv / DrvObj FilSys RetVal)
(setq FilSys (vlax-create-object "Scripting.FileSystemObject")
RetVal (cond
((= (vlax-invoke FilSys "DriveExists" Drv) 0) 0)
((setq DrvObj (vlax-invoke FilSys "GetDrive" Drv))
(cond
((= (vlax-get DrvObj "IsReady") 0) -1)
((list
(/ (vlax-get DrvObj "TotalSize") 1000.0)
(/ (vlax-get DrvObj "FreeSpace") 1000.0)
(vlax-get DrvObj "DriveType")
(vlax-get DrvObj "FileSystem")
(vlax-get DrvObj "SerialNumber")
(vlax-get DrvObj "ShareName")
(vlax-get DrvObj "VolumeName")
)
)
)
)
)
)
(if DrvObj
(vlax-release-object DrvObj)
)
(vlax-release-object FilSys)
RetVal
)
[/FONT]

[FONT=courier new] 
;| 
函数名: VxGetDriveInfos 
功  能: 返回选择磁盘信息 
Copyright:   ?001 MENZI ENGINEERING GmbH, Switzerland 
参数[类型]: 
   Drv = 盘符, 如. "C" 或 "C:" [字串] 
返回值[类型]: 
  磁盘信息 '(TotalSize FreeSpace DriveType FileSystem SerialNumber ShareName VolumeName) [表] 
说明: 
  - TotalSize (kB) [实数] 磁盘空间或 network share. 
  - FreeSpace (kB) [REAL] 空闲空间 or network share. 
  - DriveType [INT] 
     0 = "Unknown" 
     1 = "Removable" 
     2 = "Fixed" 
     3 = "Network" 
     4 = "CD-ROM" 
     5 = "RAM Disk" 
  - FileSystem [STR]  磁盘系统格式, 如. "FAT", "NTFS", "CDFS". 
  - SerialNumber [INT] Returns the serial number used to uniquely identify a disk volume. 
  - ShareName [STR]  Returns the network share name (UNC) for the specified drive. If it's 
                     not a network drive, ShareName returns a zero-length string (""). 
  - VolumeName [STR] 卷标 
     0 The drive doesn't exist. 
     1 The drive is not ready. For removable-media drives and CD-ROM drives, 
     VxGetDriveInfos returns -1 when the appropriate media is not inserted 
     or not ready for access. 
 注意: 需要 ScrRun.dll. 
|; 
 
;(defun VxGetDriveInfos (Drv / DrvObj FilSys RetVal) 
(defun V (Drv / DrvObj FilSys RetVal) 
  (setq    FilSys (vlax-create-object "Scripting.FileSystemObject") 
    RetVal (cond 
         ((= (vlax-invoke FilSys "DriveExists" Drv) 0) 0) 
         ((setq DrvObj (vlax-invoke FilSys "GetDrive" Drv)) 
          (cond 
            ((= (vlax-get DrvObj "IsReady") 0) -1) 
            ((list 
               (/ (vlax-get DrvObj "TotalSize") 1000.0) 
               (/ (vlax-get DrvObj "FreeSpace") 1000.0) 
               (vlax-get DrvObj "DriveType") 
               (vlax-get DrvObj "FileSystem") 
               (vlax-get DrvObj "SerialNumber") 
               (vlax-get DrvObj "ShareName") 
               (vlax-get DrvObj "VolumeName") 
             ) 
            ) 
          ) 
         ) 
           ) 
  ) 
  (if DrvObj 
    (vlax-release-object DrvObj) 
  ) 
  (vlax-release-object FilSys) 
  RetVal 
) 
 
  [/FONT]

建议用Boole，lsh，等函数做变换

bobby_yang · 发表于 2006-5-28 20:44:53

获取网卡号

;;Test OK with XP
;;Use WMI to Get Networkadapter MAC.
;;Author : eachy [eachy@xdcad.net]
;;Web : [url]http://www.xdcad.net[/url]
;;2005.11.22
(defun xdl-MACAddress (/ mac WMIobj serv lox sn)
(vl-load-com)
(setq mac '())
(if (SETQ WMIobj (VLAX-CREATE-OBJECT "wbemScripting.SwbemLocator"))
(progn
(SETQ serv (VLAX-INVOKE
WMIobj 'ConnectServer "."
"\\root\\cimv2" "" ""
"" "" 128 nil
)
)
(setq lox (vlax-invoke
serv
'ExecQuery
"Select * From Win32_NetworkAdapter "
)
)
(vlax-for item lox
(if (and (= (vlax-get item 'NetConnectionID) "本地连接") ;_中文系统
(not
(member (setq sn (vlax-get item 'MACAddress)) mac)
)
)
(setq mac (cons sn mac))
)
)
(mapcar 'vlax-release-object (list lox serv WMIobj))
)
)
(reverse mac)
)

;;Test OK with XP 
;;Use WMI to Get Networkadapter MAC. 
;;Author :  eachy [eachy@xdcad.net] 
;;Web    :  [url]http://www.xdcad.net[/url] 
;;2005.11.22 
(defun xdl-MACAddress (/ mac WMIobj serv lox sn) 
  (vl-load-com) 
  (setq mac '()) 
  (if (SETQ WMIobj (VLAX-CREATE-OBJECT "wbemScripting.SwbemLocator")) 
    (progn 
      (SETQ serv (VLAX-INVOKE 
                   WMIobj     'ConnectServer            "." 
                   "\\root\\cimv2"         ""            "" 
                   ""              ""         128            nil 
                  ) 
      ) 
      (setq lox        (vlax-invoke 
                  serv 
                  'ExecQuery 
                  "Select * From Win32_NetworkAdapter " 
                ) 
      ) 
      (vlax-for        item lox 
        (if (and (= (vlax-get item 'NetConnectionID) "本地连接") ;_中文系统 
                 (not 
                   (member (setq sn (vlax-get item 'MACAddress)) mac) 
                 ) 
            ) 
          (setq mac (cons sn mac)) 
        ) 
      ) 
      (mapcar 'vlax-release-object (list lox serv WMIobj)) 
    ) 
  ) 
  (reverse mac) 
)

ywqq · 发表于 2006-5-28 22:02:35

谢了,这函数我找了很久,
谢谢支持.

HuaiYu · 发表于 2006-5-29 20:02:17

请问大家是怎么学会这个 vlax-create-object 之类的函数的啊，
我怎么学都不知道啊 (汗，连门都不晓得在哪里)......
请大家指点指点一下，
谢谢,,,,,,,

senher · 发表于 2006-6-11 19:38:24

我都看不明白了。

账号		自动登录	找回密码
密码			立即注册

[LISP函数]：程序加密问题?

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子