[求助]：救命啊！！！怎么冻结当前层？？？

tchthong

在工作中，不能冻结当前层，我觉得很不方便

不想用转换到其他层在冻结的方法

哪位高人能帮忙解决一下。。最好是遍个LSP。。

谢谢了

A023-023

你直接把图层工具栏调出来，点击一下冻结图层的标志就可以了

jack8848001

你直接把图层工具栏调出来，点击一下冻结图层的标志就可以了
对了，就这么简单

zxq0220

当前图层不能冻结。只能将当前图层关闭并锁定。

baiyue

你把图层拉下来，要想要冻结的图层给冻结就行了

qiaqiadeng

楼上的兄弟门也太不负责任了，敷衍了事赚积分哪，楼主，看招：
(defun c:dg ()
  (vl-load-com)
  (setq acadObject (vlax-get-acad-object))
  (setq acadDocument (vlax-get-property acadObject 'ActiveDocument))
  (setq LayersObj (vla-get-layers acadDocument))
  (setq k T)
  (while k
    (setq layent (entsel "\n请选取要冻结层中的一个实体<退出>: "))
    (if        layent
      (progn
        (setq layent (car layent))
        (setq layentvla (vlax-ename->vla-object layent))
        (setq laystr (vla-get-layer layentvla))
        (setq
          actlaystr (vla-get-name (vla-get-activeLayer acadDocument))
        )
        (if (/= laystr actlaystr)
          (vla-put-freeze (vla-item LayersObj laystr) :vlax-True)
          (princ "\n不能冻结当前层!")
        )
      )
      (setq k nil)
    )
  )
  (princ)
)
;;;**************************************************************************
;;;5.解冻所有层
(defun c:gd ()
  (vl-load-com)
  (setq acadObject (vlax-get-acad-object))
  (setq acadDocument (vlax-get-property acadObject 'ActiveDocument))
  (setq LayersObj (vla-get-layers acadDocument))
  (setq actlaystr (vla-get-name (vla-get-activeLayer acadDocument)))
  (vlax-for lay        LayersObj
    (if        (/= (vla-get-name lay) actlaystr)
      (vla-put-freeze lay :vlax-false)
    )
  )
  (vla-regen acadDocument acAllViewPorts)
  (princ)
)
;;;**************************************************************************
;;;6.锁定或解锁选取实体所在层
(defun c:da ()
  (vl-load-com)
  (setq acadObject (vlax-get-acad-object))
  (setq acadDocument (vlax-get-property acadObject 'ActiveDocument))
  (setq LayersObj (vla-get-layers acadDocument))
  (setq k T)
  (while k
    (setq layent (entsel "\n请选取要锁定或解锁层中的一个实体<退出>: "))
    (if        layent
      (progn
        (setq layent (car layent))
        (setq layentvla (vlax-ename->vla-object layent))
        (setq laystr (vla-get-layer layentvla))
        (setq layvla (vla-item LayersObj laystr))
        (setq laylock (vla-get-lock layvla))
        (if (= laylock :vlax-false)
          (progn
            (vla-put-lock layvla :vlax-True)
            (princ (strcat "\n" laystr " 层已锁"))
          )
          (progn
            (vla-put-lock layvla :vlax-false)
            (princ (strcat "\n" laystr " 层已解锁"))
          )
        )
      )
      (setq k nil)
    )
  )
  (princ)
)

g174157601

还是楼上的厉害