[其他]：出道题目:根据字符格式化数字

aeo

出道题目
希望：

1. 
   
2. 命令: (f-str 1.14657 "2.000")
   
3. "1.14657"
   
4. 
   
5. 命令: (f-str 1.1465 "2.000")
   
6. "1.1465"
   
7. 
   
8. 命令: (f-str 1.1460 "2.000")
   
9. "1.146"
   
10. 
    
11. 命令: (f-str 1.1 "2.000")
    
12. "1.100"
    
13. 
    
14. 命令: (f-str 1.1 "2")
    
15. "1.1"
    
16. 
    
17. 命令: (f-str 1 "2.000")
    
18. "1.000"
    
19. 
    
20. 命令: (f-str 1 "2")
    
21. "1"
    
22. 
    
23. 命令: (f-str 1 "2.7")
    
24. "1.0"
    

复制代码

先保持精度（10位之内），尽量格式化成后面字符的格式

zml84

下面的代码是在网吧完成的，尚未经过测试。
[PHP]
;;;=======================
;;;尽量格式化数字to字符串
;;;日期：2007-03-04 zml84
;;;=======================
(defun f-str (num str / aa n 精度a 精度b)
    (if   (and  (numberp num)
          (= (type str)   "str")
        )
        (progn
            (setq   aa  (vl-princ-to-string num)
                    n   (strlen aa)
            )
            (if (setq   精度a   (vl-string-position  (ascii ".")
                                    aa 0 T
                        )
                )
                (progn  (while  (=  (substr a n 1)  "0")
                        (setq    n    (1- n))
                )
                    (setq  n  (-  n
                                  (vl-string-position (ascii ".") aa)
                                  -1
                              )
                    )
                )
                (setq  精度a  0
                       n      0
                )
            )
            (if (setq  精度b  (vl-string-position  (ascii ".")
                                                   str  0  T
                        )
                )
                ()
                (setq   精度b   0)
            )
            (if        (>      精度b   n)
                (rtos   num    2    精度b )
                (rtos   num    2    n     )
            )
        )
    )
)
[/PHP]

fools

[php]
(DEFUN f-str (num str / n num1)
  (IF (AND (SETQ n (VL-STRING-SEARCH "." str))
           (EQUAL (SETQ num1 (ATOF (RTOS num 2 (- (STRLEN str) 1 n))))
                    num
                    1E-10
             )
      )
    num1
    num
  )
)
[/php]

zml84

[PHP]
;;;---------------------------------------------------------------
;;;fools 于 2007年03月04日 12:19  写道：
(DEFUN f-str (num str)
  (IF (EQ num (FIX num))
    num
    (ATOF
      (RTOS num 2 (- (STRLEN str) 1 (VL-STRING-SEARCH "." str)))
    )
  )
)
;;;测试：(f-str 1 "2.000")===》》1
;;;结果与题目不符。

;;;---------------------------------------------------------------
;;;fools 于 2007年03月04日 12:26  写道：
(DEFUN f-str (num str / n)
  (IF (SETQ n (VL-STRING-SEARCH "." str))
    (ATOF (RTOS num 2 (- (STRLEN str) 1 n)))
    num     
  )
)
;;;测试返回值是数字，与题目不符。
[/PHP]

fools

刚才赶着要去吃饭,没细想,呵呵,这下可以了,
[php]
(DEFUN f-str (num str / n num1)
  (IF (AND (SETQ n (VL-STRING-SEARCH "." str))
           (EQUAL (ATOF (SETQ num1 (RTOS num 2 (- (STRLEN str) 1 n))))
                  num
                  1E-10
           )
      )
    num1
    (VL-PRINC-TO-STRING num)
  )
)
[/php]

zml84

[PHP];;;---------------------------------------------------------------
;;;fools 于 2007年03月04日 13:36  写道：
(DEFUN f-str (num str / n num1)
  (IF (AND (SETQ n (VL-STRING-SEARCH "." str))
           (EQUAL (ATOF (SETQ num1 (RTOS num
                                         2
                                         (- (STRLEN str) 1 n)
                                   )
                        )
                  )
                  num
                  1E-10
           )
      )
      num1
      (VL-PRINC-TO-STRING num)
  )
)
;;;请测试：(f-str 1.250 "2.2")
;;;返回结果应是1.25才对。
[/PHP]

fools

我这里返回的是1.25呀
[php]
_$ (f-str 1.250 "2.2")
"1.25"
_$ (f-str 1.25 "2.2")
"1.25"
[/php]

hehe ,我知道了,我用你写的程序测试结果为nil

zml84

不好意思，我这里没有Acad，所以没能测试。我也要吃饭去了，向你学习了！！

fools

相互学习,共同提高吧,呵呵.赶紧去吃饭吧.
我挺喜欢这种讨论气氛的,发现问题,思考问题,解决问题,乐在其中.
在这个帖子里你保留了我所有犯过的错误,现在回看一遍,挺有意思的.

aeo

命令: (f-str 1.0 "2")
"1.0"

我要整数

fools

给你整数
[php]
(DEFUN f-str (num str / n num1)
  (IF (EQUAL (FIX num) num 1E-10)
    (SETQ num (FIX num))
  )
  (IF (AND (SETQ n (VL-STRING-SEARCH "." str))
           (EQUAL (ATOF (SETQ num1 (RTOS num 2 (- (STRLEN str) 1 n))))
                  num
                  1E-10
           )
      )
    num1
    (VL-PRINC-TO-STRING num)
  )
)
[/php]

1. 
   
2. _$ (f-str 1.0 "2")
   
3. "1"
   
4. _$ (f-str 1.0 "2.2312")
   
5. "1.0000"
   
6. _$ (f-str 1.0 "2.3412312")
   
7. "1.0000000"
   

复制代码