为什么用command打开图形不成功？

Lispboy · 发表于 2013-4-23 16:34:41

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

命令: (command "_.open" "c:\\abc\\1.dwg" )
未知命令“C:\ABC\1.DWG”。按 F1 查看帮助。

不会进行，提示错误，请高手帮忙。

XDSoft · 发表于 2013-4-23 17:36:47

这是由于在SDI=0下，从VisualLisp执行open命令是不行的，原因是当执行OPEN命令时候，AutoCAD内部要创建一个新的文档并且激活它，在激活一个新的文档窗口后，AutoCAD继续执行LISP表达式，但它继续求值的表达式是在旧的文档下的，所以要出错了。

解决这个问题可以用ActiveX接口（在内部激活新窗口后，马上会回到旧的文档继续求值LISP表达式）

[pcode=lisp,true]
(vl-load-com)
(defun c:vlopen ()
(setq acadApp (vlax-get-acad-object)
acadDocs (vla-get-documents acadApp)
)

(vla-open acadDocs "c:/abc/1.dwg")
)
[/pcode]

hardthinking · 发表于 2013-8-26 22:26:57

XDSoft 发表于 2013-4-23 17:36
这是由于在SDI=0下，从VisualLisp执行open命令是不行的，原因是当执行OPEN命令时候，AutoCAD内部要创建一个 ...

老大，我试了下，写成相对路径就提示错误如下：
“错误: Automation 错误。未找到文件 .\结构专业\JIEGOU.DWG”
有没有支持相对路径的写法呢？

XDSoft · 发表于 2013-8-27 04:44:16

hardthinking 发表于 2013-8-26 22:26
老大，我试了下，写成相对路径就提示错误如下：
“错误: Automation 错误。未找到文件 .\结构专业\JIEG ...

路径用两个斜杠 \\ 分割试试。

ayl1004 · 发表于 2013-8-27 12:59:45

这要在打开新文档之前，用lisp写一段代码让新文档自动加载那段代码并自动执行，代码的作用是让新文档的控制权交返给旧文档，以便让旧文档继续执行剩下的表达式。

st788796 · 发表于 2013-8-27 13:19:24

ayl1004 发表于 18 分钟前

 登录/注册后可看大图

这要在打开新文档之前，用lisp写一段代码让新文档自动加载那段代码并自动执行，代码的作用是让新文档的控制权交返给旧文档，以便让旧文档继续执行剩下的表达式。

给个实例吧来自: Android客户端

ayl1004 · 发表于 2013-8-27 13:27:56

st788796 发表于 2013-8-27 13:19
给个实例吧

(defun getcommandname (file / acadapp documents
actdoc mnlfile tmpfile tmpf
value str1 abcDoc
)
(vl-load-com)
(setq acadapp (vlax-get-acad-object)
documents (vla-get-documents acadapp)
actdoc (vla-get-activedocument acadapp)
)
;;寻找自动加载的"acad.mnl"文件，并在同目录下创建"tmpfile.lsp"文件
(setq mnlfile (findfile "acad.mnl")
tmpfile (strcat (vl-filename-directory mnlfile) "\\tmpfile.lsp")
tmpf (open tmpfile "w")
)
;;在tmpfile.lsp"文件里写入 findfunc 函数定义
(princ (vl-prin1-to-string
'(defun
findfunc
(file / lst1 lst2 lst3)
(mapcar
'(lambda (x)
(if (or (wcmatch x "C:*")
(wcmatch x "c:*")
)
(setq lst1 (cons x lst1))
)
)
(atoms-family 1)
)
(load file (princ))
(mapcar
'(lambda (x)
(if (or (wcmatch x "C:*")
(wcmatch x "c:*")
)
(setq lst2 (cons x lst2))
)
)
(atoms-family 1)
)
(mapcar
'(lambda (x)
(if (not (member x lst1))
(setq lst3 (cons x lst3))
)
)
lst2
)
(vl-bb-set 'a lst3)
) ;_ 结束defun
) ;_ 结束 vl-princ1-to-string
tmpf
) ;_ 结束 princ
;;在文件的后面添加两行代码
;;(findfunc file) ;_ 执行自定义函数
;;(vl-load-com) ;_ 在第二个文档的名称空间里加载ActiveX支持
;;(vla-Activate actDoc) ;_ 激活前一个文档，把控制权交还给它
(princ (strcat "\n(findfunc " (vl-prin1-to-string file) " )")
tmpf
)
(princ "\n(vl-load-com)" tmpf)
(princ "\n(vla-Activate actdoc)" tmpf)
;;关闭"tmpfile.lsp"文件
(close tmpf)
;;从头到尾依次读取指定文件的每一行，
;;如果文件存在指定的字符串，就返回这
;;条字符串，并停止搜索，否则返回nil。
(defun readeveryline (fd string / str)
(if (setq str (read-line fd))
(if (/= string str)
(readeveryline fd string)
str
)
)
)
;;打开"acad.mnl"文件，依次读取每一行
;;寻找是不是存在(load tmpfile (princ))这一行代码
;;若不存在，就在文件里添加
(setq tmpf (open mnlfile "r")
str1 (strcat "(load " (vl-prin1-to-string tmpfile) " (princ))")
)
(if (readeveryline tmpf str1)
(close tmpf)
(progn (close tmpf)
(setq tmpf (open mnlfile "a"))
(princ (strcat "\n" str1) tmpf)
(close tmpf)
)
)
;;新建一个文档，同时，把控制权交给它
(setq abcDoc (vla-add documents ""))
;;第二个文档执行完所有的代码后，自动把控制权交还给第一个文档
;;第一个文档得到控制权后，就关闭第二个文档
(vla-close abcDoc)
;;从黑板读取变量值
(setq value (vl-bb-ref 'a))
;;删除黑板的变量
(vl-bb-set 'a nil)
;;删除文件
(vl-file-delete tmpfile)
value
)

(defun getcommandname (file   /     acadapp   documents 
           actdoc   mnlfile   tmpfile   tmpf 
           value   str1     abcDoc 
          ) 
  (vl-load-com) 
  (setq  acadapp    (vlax-get-acad-object) 
  documents (vla-get-documents acadapp) 
  actdoc    (vla-get-activedocument acadapp) 
  ) 
  ;;寻找自动加载的"acad.mnl"文件，并在同目录下创建"tmpfile.lsp"文件 
  (setq  mnlfile  (findfile "acad.mnl") 
  tmpfile  (strcat (vl-filename-directory mnlfile) "\\tmpfile.lsp") 
  tmpf  (open tmpfile "w") 
  ) 
  ;;在tmpfile.lsp"文件里写入 findfunc 函数定义 
  (princ (vl-prin1-to-string 
     '(defun 
       findfunc 
       (file / lst1 lst2 lst3) 
       (mapcar 
        '(lambda (x) 
     (if (or (wcmatch x "C:*") 
       (wcmatch x "c:*") 
         ) 
       (setq lst1 (cons x lst1)) 
     ) 
         ) 
        (atoms-family 1) 
       ) 
       (load file (princ)) 
       (mapcar 
        '(lambda (x) 
     (if (or (wcmatch x "C:*") 
       (wcmatch x "c:*") 
         ) 
       (setq lst2 (cons x lst2)) 
     ) 
         ) 
        (atoms-family 1) 
       ) 
       (mapcar 
        '(lambda (x) 
     (if (not (member x lst1)) 
       (setq lst3 (cons x lst3)) 
     ) 
         ) 
        lst2 
       ) 
       (vl-bb-set 'a lst3) 
      ) ;_ 结束defun 
   ) ;_ 结束 vl-princ1-to-string 
   tmpf 
  ) ;_ 结束 princ 
  ;;在文件的后面添加两行代码 
  ;;(findfunc file) ;_ 执行自定义函数 
  ;;(vl-load-com) ;_ 在第二个文档的名称空间里加载ActiveX支持 
  ;;(vla-Activate actDoc) ;_ 激活前一个文档，把控制权交还给它 
  (princ (strcat "\n(findfunc " (vl-prin1-to-string file) " )") 
   tmpf 
  ) 
  (princ "\n(vl-load-com)" tmpf) 
  (princ "\n(vla-Activate actdoc)" tmpf) 
  ;;关闭"tmpfile.lsp"文件 
  (close tmpf) 
  ;;从头到尾依次读取指定文件的每一行， 
  ;;如果文件存在指定的字符串，就返回这 
  ;;条字符串，并停止搜索，否则返回nil。 
  (defun readeveryline (fd string / str) 
    (if  (setq str (read-line fd)) 
      (if (/= string str) 
  (readeveryline fd string) 
  str 
      ) 
    ) 
  ) 
  ;;打开"acad.mnl"文件，依次读取每一行 
  ;;寻找是不是存在(load tmpfile (princ))这一行代码 
  ;;若不存在，就在文件里添加 
  (setq  tmpf (open mnlfile "r") 
  str1 (strcat "(load " (vl-prin1-to-string tmpfile) " (princ))") 
  ) 
  (if (readeveryline tmpf str1) 
    (close tmpf) 
    (progn (close tmpf) 
     (setq tmpf (open mnlfile "a")) 
     (princ (strcat "\n" str1) tmpf) 
     (close tmpf) 
    ) 
  ) 
  ;;新建一个文档，同时，把控制权交给它 
  (setq abcDoc (vla-add documents "")) 
  ;;第二个文档执行完所有的代码后，自动把控制权交还给第一个文档 
  ;;第一个文档得到控制权后，就关闭第二个文档 
  (vla-close abcDoc) 
  ;;从黑板读取变量值 
  (setq value (vl-bb-ref 'a)) 
  ;;删除黑板的变量 
  (vl-bb-set 'a nil) 
  ;;删除文件 
  (vl-file-delete tmpfile) 
  value 
)

/db_自贡黄明儒_ · 发表于 2013-8-27 14:35:15

;;打开文件时，不出现字体选择对话框自贡黄明儒 2013年2月5日
(defun C:MyOpen (/ *ACAD* DOCOBJ DWGNAME)
  (setq *ACAD* (vlax-get-acad-object))
  (setq DwgName (getfiled "打开文件" (getvar "dwgprefix") "dwg" 0))
  (setq DocObj (vla-open (vla-get-Documents *ACAD*) DwgName))
  (vla-Activate DocObj)
  (if *ACAD* (vlax-release-object *ACAD*))
  (princ)
)

q3_2006 · 发表于 2013-8-27 14:50:38

打开方式很好用，学习了！

newer · 发表于 2013-8-27 14:51:48

/db_自贡黄明儒_ 发表于 2013-8-27 14:35
;;打开文件时，不出现字体选择对话框自贡黄明儒 2013年2月5日
(defun C:MyOpen (/ *ACAD* DOCOBJ DWGNAME ...

不出现字体选择，是不是也不太好啊，有些图打开后可能字看不到了。

Free-Lancer · 发表于 2013-8-27 16:14:12

以前RAVE版主写过一个可以自定义字体静默替换ARX,可惜没有升级了，期望API能加入

/db_自贡黄明儒_ · 发表于 2013-8-27 16:58:14

Free-Lancer 发表于 2013-8-27 16:14
以前RAVE版主写过一个可以自定义字体静默替换ARX,可惜没有升级了，期望API能加入

vla-open 打开，也是用默认字体打开的吧？
acad.fmp

newer · 发表于 2013-8-27 17:00:05

Free-Lancer 发表于 2013-8-27 16:14
以前RAVE版主写过一个可以自定义字体静默替换ARX,可惜没有升级了，期望API能加入

用现有的API函数就可以写一个这样的LISP啊。

Free-Lancer · 发表于 2013-8-27 17:17:04

newer 发表于 2013-8-27 17:00
用现有的API函数就可以写一个这样的LISP啊。

网上看过一篇文章介绍这个自动替换字体，Open时监视是否出现替换字体对话框，如果有进行抑制不让其出现，后台自动替换，和事后替换是两个概念

newer · 发表于 2013-8-27 17:45:35

Free-Lancer 发表于 2013-8-27 17:17
网上看过一篇文章介绍这个自动替换字体，Open时监视是否出现替换字体对话框，如果有进行抑制不让其出现， ...

altfont 可以在系统变量里面设置，保存到注册表的应该，会自动替换，你试试看。

账号		自动登录	找回密码
密码			立即注册

[求助] 为什么用command打开图形不成功？

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

点评

点评

点评

点评

点评

点评

点评

点评

点评