[求助]：怎么把含有某字符串的字符串另外存到其他一个层？

长空无限

比如 900 xAUy 1272， 900 xAUy 1038，都含有xAUy，可是混在很多图形里面，有工具把它们找出来并存在另外一个层上吗？谢谢

highflybird

[php]
(defun C:ttt(/ *APP *DOC *BLK i str lay objname)
  (vl-load-com)
  (setq *APP (vlax-get-acad-object))
  (setq *DOC (vla-get-activeDocument *APP))
  (setq *BLK (vla-get-blocks *DOC))
  (setq i 0)
  (if (and (setq str (getstring "\n请输入你要查找的字符串:"))
           (setq lay (getstring "\n请输入你要指定的图层:"))
      )
    (vlax-for blocks *blk
      (vlax-for n blocks
        (setq objname (vla-get-objectname n))
        (if (or (= objname "AcDbMText")  (= objname "AcDbText"))
          (if (wcmatch (vla-get-TextString n) (strcat "*" str "*"))
            (progn
              (vla-put-layer n lay)
              (setq i (1+ i))
            )
          )
        )
      )
    )
  )
  (princ "\n你已经对")
  (princ i)
  (princ "个物体进行了操作!")
  (princ)
)
[/php]

这是全局的方法，对块内的文字及嵌套块均有效。
如果仅仅是图形空间的，用过滤器就可以了。

haibinpro

filter
设定
文字值条件为
WWW
没办法将WWW=CC
选中啊，
要将条件改为
WWW=CC
才可以。
怎么设定条件才能选中文字包含WWW的文字。

highflybird

在文字值中填写：

*www* -----------------www是你要替换的.

gisvv

强人