[求助]：如何实现固定数的不等比缩放

断点

http://p4.xdcad.net/forum/showth ... 2268965#post2268965
在这里14楼下了841594的不等比缩放，很好用，但我每次缩放都比较固定，X方向0.97560976
                Y方向0.98522168
用于克服绘图仪的误差。请大侠帮忙写个lisp，以解每次输入一长串数字之苦。谢谢

amu226

呵呵 没办法

断点

http://p4.xdcad.net/forum/showthread.php?s=&threadid=442079
在这里9楼lyc3029 的lisp，
;;;;本程序用于进行实体横纵向不等比例缩放!
(princ "\n start command with scc,本程序用于进行实体横纵向不等比例缩放!Writen by lyc in 2005.08.")
(setq i 0)
(defun c:scc(/ ss1 pt1 hxbl zxbl )
(setvar "cmdecho" 0)
(princ "请选择你要缩放的实体!")
(setq ss1 (ssget))
(setq pt1 (getpoint "\n请选择缩放点")
hxbl (getreal "\n输入横向放大比例:")
zxbl (getreal "\n输入纵向放大比例:")
)
(command "block" i pt1 ss1 "")
(command "insert" i pt1 hxbl zxbl "0")
(setq i (+ i 1))
(princ)
)

大侠，能不能把X方向0.97560976
Y方向0.98522168
加进去。谢谢

gysjy

;;;;本程序用于进行实体横纵向不等比例缩放!
(princ "\n start command with scc,本程序用于进行实体横纵向不等比例缩放!Writen by lyc in 2005.08.")
(setq i 0)
(defun c:scc(/ ss1 pt1 hxbl zxbl )
(setvar "cmdecho" 0)
(princ "请选择你要缩放的实体!")
(setq ss1 (ssget))
(setq pt1 (getpoint "\n请选择缩放点")
hxbl 0.97560976
zxbl 0.98522168
)
(command "block" i pt1 ss1 "")
(command "insert" i pt1 hxbl zxbl "0")
(setq i (+ i 1))
(princ)
)

断点

谢谢gysjy。运行成功！

但有个文件我先加载的3楼那个，能运行。接着又加载了4楼gysjy修改这个后，就不能运行了，提示： 错误: 函数被取消     以后这个文件都不能运行这个lisp了，重新启动电脑都不行，不知为什么？这个lisp都是每次是现加载的。

zml84

是由于块名的缘故，因为图形中已经存在同名块。

[php]
;;;本程序用于进行实体横纵向不等比例缩放!
;;;===============================
(defun C:SC1 (/ SS1 PT1 HXBL ZXBL)
    (if        (and (princ "\n请选择你要缩放的实体!")
             (setq SS1 (ssget))
             (setq PT1 (getpoint "\n请选择缩放点"))
             (setq HXBL (getreal "\n输入横向放大比例:"))
             (setq ZXBL (getreal "\n输入纵向放大比例:"))
        )
        (SC-K SS1 PT1 HXBL ZXBL)
    )
    (princ)
)
;;;===============================
(defun C:SC2 (/ SS1 PT1)
    (if        (and (princ "请选择你要缩放的实体!")
             (setq SS1 (ssget))
             (setq PT1 (getpoint "\n请选择缩放点"))
        )
        (SC-K SS1 PT1 0.97560976 0.98522168)
    )
    (princ)
)
;;;===============================
;;;通用函数
(defun SC-K (SS PT K_X K_Y / NAME)
    (setq NAME "2007-11-28")
    (setvar "cmdecho" 0)
    (command "-block" NAME PT SS "")
    (command "-insert" NAME PT K_X K_Y "0")
    (command "_.explode" (entlast) "")
    (command "_.purge" "b" NAME "y" "y")
)
[/php]

断点

谢zml84
太好用了！