[LISP程序]：转发一个圆和中心线关联的反应器

kmdz

想做图形关联的人可以看看。

2. 
   
3. ;;reac命令,修改反应器练习
   
4. (defun C:REAC (/)                        ; cp r1 r2 p1 p2 p3 p4 vc eh1 eh2 eh_l vc_l)
   
5.     (vl-load-com)                        ;该函数加载 Visual LISP 提供的扩展,实现对 ActiveX 和 AutoCAD 反应器的支持，
   
6.                                         ;同时还提供了 ActiveX 实用程序、数据转换函数、词典处理函数和曲线测量函数。
   
7.     (setvar "cmdecho" 0)                ;cmdecho-控制在 AutoLISP 的 command 函数运行时 AutoCAD 是否回显提示和输入。
   
8.     (setvar "osmode" 0)                        ;关闭对象捕捉
   
9.     (setq CP (getpoint "\n指定圆的中心点: ")) ;请求输入圆心坐标
   
10.     (setq R1 (getdist CP "\n输入圆的半径: ")) ;请求输入圆的半径
    
11.     (setq R2 (* 1.2 R1))                ;设定r2为圆半径的1.2倍
    
12.     (setq P1 (polar CP 0 R2)                ;利用极坐标法计算以圆心为起点,弧度为0,长度为r2的p1点坐标
    
13.           P2 (polar CP (* pi 0.5) R2)        ;利用极坐标法计算以圆心为起点,弧度为pi/2,长度为r2的p2点坐标
    
14.           P3 (polar CP pi R2)                ;利用极坐标法计算以圆心为起点,弧度为pi,长度为r2的p3点坐标
    
15.           P4 (polar CP (* pi 1.5) R2)        ;利用极坐标法计算以圆心为起点,弧度为3/2*pi,长度为r2的p4点坐标
    
16.     )
    
17.     (command "layer" "m" "cuxian" "")        ;新建cuxian图层
    
18.     (command "layer" "lw" 0.3 "cuxian" "") ;更改cuxian层线宽为0.3
    
19.     (command "circle" CP R1)                ;画出用户输入的圆
    
20.     (setq VC (VLAX-ENAME->VLA-OBJECT (entlast)))
    
21.                                         ;将AutoLISP类型的对象名转换为VLA对象,
    
22.                                         ;entlast 函数经常用于获得刚用 command 函数加入到图形中的新图元的图元名。
    
23.                                         ;该函数选择的图元不一定要显示在屏幕上，也不一定要处于解冻状态。本次主要获得用户输入的圆。
    
24.     (command "layer" "m" "xixian" "")        ;新建xixian图层
    
25.     (command "layer" "c" 1 "xixian" "l" "center" "xixian" "")
    
26.                                         ;更改xixian为红色点划线
    
27.     (command "line" P1 P3 "")                ;用直线连接p1,p3点
    
28.     (setq EH1 (cdr (assoc 5 (entget (entlast)))))
    
29.                                         ;assoc-从关联表中搜索一个元素，如果找到则返回该关联表条目,
    
30.                                         ;entget-获得对象（图元）的定义数据。
    
31.                                         ;cdr-返回去掉了第一个元素的表,当 list 参数是点对表时，cdr 返回点对表的第二个元素，而不是以表的形式返回它。
    
32.     (command "line" P2 P4 "")                ;用直线连接p2,p4点
    
33.     (setq EH2 (cdr (assoc 5 (entget (entlast)))))
    
34.     (setq EH_L (list EH1 EH2))                ;句柄表，它们将是反应器的关联数据
    
35.     (setq VC_L (list VC))                ;vla对象表，它们将是反应器的所有者
    
36.     (VLR-PERS
    
37.         (VLR-OBJECT-REACTOR VC_L EH_L '((:VLR-MODIFIED . CHANGE)))
    
38.     )
    
39.                                         ;反应器链接到圆c上，两直线为关联数据，当修改圆c时调用函数change
    
40.     (VLR-PERS
    
41.         (VLR-OBJECT-REACTOR VC_L NIL '((:VLR-MODIFIED . SHOW)))
    
42.     )
    
43.                                         ;反应器链接到圆c上，无关联数据，当修改圆c时调用函数show
    
44.     (setvar "cmdecho" 1)
    
45.     (setvar "osmode" 4133)
    
46.     (princ)
    
47. )
    
48. 
    
49. ;;;change函数
    
50. (defun CHANGE (NOTIFIER-OBJECT REACTOR-OBJECT PARAMETER-LIST /)
    
51.                                         ;ec ec_l r2 eh_l e1_l e2_l p1 p2 p3 p4 )
    
52.     (vl-load-com)
    
53.     (setq EC   (VLAX-VLA-OBJECT->ENAME NOTIFIER-OBJECT)
    
54.           EC_L (entget EC)
    
55.           CP   (cdr (assoc 10 EC_L))
    
56.           R2   (* 1.2 (cdr (assoc 40 EC_L)))
    
57.     )                                        ;新数据
    
58.     (setq EH_L (VLR-DATA REACTOR-OBJECT)) ;获取反应器的关联数据: 句柄表
    
59.     (setq E1_L (entget (handent (car EH_L))) ;读出直线一图元表
    
60.           E2_L (entget (handent (cadr EH_L))) ;直线二图元表
    
61.     )
    
62.     (setq P1 (polar CP 0 R2)
    
63.           P2 (polar CP (* pi 0.5) R2)
    
64.           P3 (polar CP pi R2)
    
65.           P4 (polar CP (* pi 1.5) R2)
    
66.     )                                        ;从新计算直线个端点
    
67.     (setq E1_L (subst (vl-list* 10 P1) (assoc 10 E1_L) E1_L))
    
68.                                         ;修改直线一的起点
    
69.     (setq E1_L (subst (vl-list* 11 P3) (assoc 11 E1_L) E1_L))
    
70.                                         ;修改直线一的端点
    
71.     (entmod E1_L)                        ;更新直线一的图元表
    
72.     (setq E2_L (subst (vl-list* 10 P2) (assoc 10 E2_L) E2_L))
    
73.     (setq E2_L (subst (vl-list* 11 P4) (assoc 11 E2_L) E2_L))
    
74.     (entmod E2_L)                        ;更新直线二的图元表
    
75. )
    
76. 
    
77. ;;;show函数
    
78. (defun SHOW (NOTIFIER-OBJECT REACTOR-OBJECT PARAMETER-LIST / R1)
    
79.     (vl-load-com)
    
80.     (setq R1 (VLA-GET-DIAMETER NOTIFIER-OBJECT)) ;获取直径
    
81.     (setq R1 (rtos R1 2 4))                ;转换为字符串
    
82.     (alert (strcat "圆的内径是: " R1))        ;报告操作结果
    
83. )
    

<br /> ;;reac命令,修改反应器练习<br /> (defun C:REAC (/)                        ; cp r1 r2 p1 p2 p3 p4 vc eh1 eh2 eh_l vc_l)<br />     (vl-load-com)                        ;该函数加载 Visual LISP 提供的扩展,实现对 ActiveX 和 AutoCAD 反应器的支持，<br />                                         ;同时还提供了 ActiveX 实用程序、数据转换函数、词典处理函数和曲线测量函数。<br />     (setvar "cmdecho" 0)                ;cmdecho-控制在 AutoLISP 的 command 函数运行时 AutoCAD 是否回显提示和输入。<br />     (setvar "osmode" 0)                        ;关闭对象捕捉<br />     (setq CP (getpoint "\n指定圆的中心点: ")) ;请求输入圆心坐标<br />     (setq R1 (getdist CP "\n输入圆的半径: ")) ;请求输入圆的半径<br />     (setq R2 (* 1.2 R1))                ;设定r2为圆半径的1.2倍<br />     (setq P1 (polar CP 0 R2)                ;利用极坐标法计算以圆心为起点,弧度为0,长度为r2的p1点坐标<br />           P2 (polar CP (* pi 0.5) R2)        ;利用极坐标法计算以圆心为起点,弧度为pi/2,长度为r2的p2点坐标<br />           P3 (polar CP pi R2)                ;利用极坐标法计算以圆心为起点,弧度为pi,长度为r2的p3点坐标<br />           P4 (polar CP (* pi 1.5) R2)        ;利用极坐标法计算以圆心为起点,弧度为3/2*pi,长度为r2的p4点坐标<br />     )<br />     (command "layer" "m" "cuxian" "")        ;新建cuxian图层<br />     (command "layer" "lw" 0.3 "cuxian" "") ;更改cuxian层线宽为0.3<br />     (command "circle" CP R1)                ;画出用户输入的圆<br />     (setq VC (VLAX-ENAME->VLA-OBJECT (entlast)))<br />                                         ;将AutoLISP类型的对象名转换为VLA对象,<br />                                         ;entlast 函数经常用于获得刚用 command 函数加入到图形中的新图元的图元名。<br />                                         ;该函数选择的图元不一定要显示在屏幕上，也不一定要处于解冻状态。本次主要获得用户输入的圆。<br />     (command "layer" "m" "xixian" "")        ;新建xixian图层<br />     (command "layer" "c" 1 "xixian" "l" "center" "xixian" "")<br />                                         ;更改xixian为红色点划线<br />     (command "line" P1 P3 "")                ;用直线连接p1,p3点<br />     (setq EH1 (cdr (assoc 5 (entget (entlast)))))<br />                                         ;assoc-从关联表中搜索一个元素，如果找到则返回该关联表条目,<br />                                         ;entget-获得对象（图元）的定义数据。<br />                                         ;cdr-返回去掉了第一个元素的表,当 list 参数是点对表时，cdr 返回点对表的第二个元素，而不是以表的形式返回它。<br />     (command "line" P2 P4 "")                ;用直线连接p2,p4点<br />     (setq EH2 (cdr (assoc 5 (entget (entlast)))))<br />     (setq EH_L (list EH1 EH2))                ;句柄表，它们将是反应器的关联数据<br />     (setq VC_L (list VC))                ;vla对象表，它们将是反应器的所有者<br />     (VLR-PERS<br />         (VLR-OBJECT-REACTOR VC_L EH_L '((:VLR-MODIFIED . CHANGE)))<br />     )<br />                                         ;反应器链接到圆c上，两直线为关联数据，当修改圆c时调用函数change<br />     (VLR-PERS<br />         (VLR-OBJECT-REACTOR VC_L NIL '((:VLR-MODIFIED . SHOW)))<br />     )<br />                                         ;反应器链接到圆c上，无关联数据，当修改圆c时调用函数show<br />     (setvar "cmdecho" 1)<br />     (setvar "osmode" 4133)<br />     (princ)<br /> )<br /> <br /> ;;;change函数<br /> (defun CHANGE (NOTIFIER-OBJECT REACTOR-OBJECT PARAMETER-LIST /)<br />                                         ;ec ec_l r2 eh_l e1_l e2_l p1 p2 p3 p4 )<br />     (vl-load-com)<br />     (setq EC   (VLAX-VLA-OBJECT->ENAME NOTIFIER-OBJECT)<br />           EC_L (entget EC)<br />           CP   (cdr (assoc 10 EC_L))<br />           R2   (* 1.2 (cdr (assoc 40 EC_L)))<br />     )                                        ;新数据<br />     (setq EH_L (VLR-DATA REACTOR-OBJECT)) ;获取反应器的关联数据: 句柄表<br />     (setq E1_L (entget (handent (car EH_L))) ;读出直线一图元表<br />           E2_L (entget (handent (cadr EH_L))) ;直线二图元表<br />     )<br />     (setq P1 (polar CP 0 R2)<br />           P2 (polar CP (* pi 0.5) R2)<br />           P3 (polar CP pi R2)<br />           P4 (polar CP (* pi 1.5) R2)<br />     )                                        ;从新计算直线个端点<br />     (setq E1_L (subst (vl-list* 10 P1) (assoc 10 E1_L) E1_L))<br />                                         ;修改直线一的起点<br />     (setq E1_L (subst (vl-list* 11 P3) (assoc 11 E1_L) E1_L))<br />                                         ;修改直线一的端点<br />     (entmod E1_L)                        ;更新直线一的图元表<br />     (setq E2_L (subst (vl-list* 10 P2) (assoc 10 E2_L) E2_L))<br />     (setq E2_L (subst (vl-list* 11 P4) (assoc 11 E2_L) E2_L))<br />     (entmod E2_L)                        ;更新直线二的图元表<br /> )<br /> <br /> ;;;show函数<br /> (defun SHOW (NOTIFIER-OBJECT REACTOR-OBJECT PARAMETER-LIST / R1)<br />     (vl-load-com)<br />     (setq R1 (VLA-GET-DIAMETER NOTIFIER-OBJECT)) ;获取直径<br />     (setq R1 (rtos R1 2 4))                ;转换为字符串<br />     (alert (strcat "圆的内径是: " R1))        ;报告操作结果<br /> )<br />

fill

试了一下，非常好，谢谢

carrot1983

(VLR-PERS
        (VLR-OBJECT-REACTOR VC_L EH_L '((:VLR-MODIFIED . CHANGE)))
    )
                                        ;反应器链接到圆c上，两直线为关联数据，当修改圆c时调用函数change
    (VLR-PERS
        (VLR-OBJECT-REACTOR VC_L NIL '((:VLR-MODIFIED . SHOW)))
    )
                                        ;反应器链接到圆c上，无关联数据，当修改圆c时调用函数show

这两个为何不合在一起？？？

kmdz

"转发一个圆和中心线关联的反应器"，才学的时候找了个别人的东西来学习的，可能是为了程序更清晰，这个例子中的两个回调函数比较简单，如果复杂了这样用比较好。
其实这个程序是原作者根据《visuallisp程序设计2006》中反应器例子改的。

newer

很好的例子。

结构小鑫

收藏，学习下

kswym88888

这个反应器的实例我太喜欢了。谢谢楼主的分享！

kswym88888

我太想做图形关联了。（KMDZ）老师你真好。你把这画好园后又及时的添加了红色中心线。我太喜欢了。虽然我是LISP菜鸟。但是能够读到你这样的清楚的详细的规范的明确的好懂的LSP.这是难能可贵啊。我幸运的搜索到了你大师的风采！我喜欢的爱不释手。不停的在我的电脑上实验，是非常成功的。就是最后的(defun SHOW 函数，好像没有打印出来。在我的电脑上。不知是我电脑原因？最后再次感谢KMDZ老师的无私奉献各我们菜鸟。

kswym88888

KMDZ老师你好。我有要给你写信了。刚才我去移动了一下。啊。真是精彩漂亮！我看到了移动后的通知。园的内径是：42  然后我点确定。我真高兴。觉得自己在反应器的方面有很多进步了。感谢楼主的奉献！