(XD::Polyline:AddFillet)指定顶点索引处F,C倒角

newer · 发表于 2013-10-30 11:11:25

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

本帖最后由 newer 于 2016-10-8 14:23 编辑

该函数应用程序，非模式对话框批量倒角插件，见：http://bbs.xdcad.net/thread-671374-1-1.html

;|
指定顶点索引处F,C倒角
参数：
e ---- LWPOLYLINE
index- 顶点索引
oper - "F" 圆角
"C" 倒角
dis1 - "F"下，半径，"C"下索引小段方向的C脚距离
dis2 - "F" 下无用，"C"下，索引大的方向的距离
返回值：
0 -- 成功
1 -- 倒角新顶点不在多段线上
2 -- 索引处有弧段
3 -- 不封闭曲线，索引在端点
4 -- 顶点索引超出合法范围
|;
(defun XD::Polyline:addFillet (e index oper dis1 dis2 / an anc bulge dis eL1
eL2 int inx next num p_1 p_2 ret v1 v2 x
xdata xdata2 xreclist xrecLst
)
(setq inx (XD::PolyLine:-Index+ e index)
num (xdrx_polyline_numVerts e)
oper (strcase oper)
)
(if (and
(> dis1 0)
(> dis2 0)
(setq ret 4) ; 顶点索引无效返回
(>= index 0)
(< index num)
(setq ret 3) ; 不封闭曲线，顶点索引在端点返回
(or
(xdrx_getpropertyvalue e "IsClosed")
(and
(/= (last inx) 0) ; 不封闭线判断是否是两端点，是退出
(/= (car inx) (1- num))
)
)
(setq ret 2) ; 顶点在弧线段返回
(= (xdrx_polyline_segtype e index) "kLine")
(= (xdrx_polyline_segtype e (car inx)) "kLine")
)
(progn
(setq eL1 (xdrx_polyline_getLineSegAt e (car inx))
eL2 (xdrx_polyline_getLineSegAt e index)
int (car (xdrx_curve_getinters eL1 eL2 3))
v1 (xdrx_vector_normalize (mapcar
'-
(car eL1)
(cadr eL1)
)
)
v2 (xdrx_vector_normalize (mapcar
'-
(last eL2)
(car eL2)
)
)
)
(setq p_1 (mapcar
'+
int
(xdrx_vector_product v1 dis1)
)
)
(cond
((= oper "C")
(setq p_2 (mapcar
'+
int
(xdrx_vector_product v2 dis2)
)
)
)
((= oper "F")
(setq p_2 (mapcar
'+
int
(xdrx_vector_product v2 dis1)
)
)
(setq an (xdrx_math_acos (xdrx_vector_dotproduct v2 v1)))
(if (< an 0.0)
(setq an (+ (* 2 PI) an))
)
(if (> an pi)
(setq an (- (* 2 PI) an))
)
(setq anc (- pi an)
dis (abs (* dis1 (xdrx_math_tan (/ anc 2.0))))
dis1 dis
dis2 dis
bulge (xdrx_math_tan (/ anc 4.0))
)
)
)
(if (minusp (xdrx_points_area p_1 int p_2))
(setq bulge (- bulge))
)
(setq ret 1) ; 算点不在曲线上
(if (and
(xdrx_point_ison p_1 e)
(xdrx_point_ison p_2 e)
)
(progn
(setq next (cadr inx))
(xdrx_polyline_addVertexAt e index p_1)
(if (= next 0)
(progn
(xdrx_polyline_setPointAt e (1+ index) p_2)
)
(progn
(xdrx_polyline_setPointAt e (1+ index) p_2)
)
)
(if (= oper "F")
(xdrx_polyline_setBulgeAt e index bulge)
)
(setq xrecLst (xdrx_xdata_get e "XD_FILLET"))
(if (not (member index xreclist))
(setq xrecLst (cons index xrecLst))
)
(setq xrecLst (vl-sort xrecLst '<)
xdata2 (member index xrecLst)
xdata (append
(reverse (member index (reverse xrecLst)))
(mapcar
'(lambda (x)
(1+ x)
)
(cdr xdata2)
)
)
)
(apply
'xdrx_xdata_set
(cons e (cons "XD_FILLET" xdata))
)
(setq ret 0) ; 成功
)
)
)
)
ret
)

;| 
指定顶点索引处F,C倒角 
参数： 
  e ---- LWPOLYLINE 
  index- 顶点索引 
  oper - "F" 圆角 
         "C" 倒角 
  dis1 - "F"下，半径，"C"下索引小段方向的C脚距离 
  dis2 - "F" 下无用，"C"下，索引大的方向的距离 
 
返回值： 
  0 -- 成功 
  1 -- 倒角新顶点不在多段线上 
  2 -- 索引处有弧段 
  3 -- 不封闭曲线，索引在端点 
  4 -- 顶点索引超出合法范围 
|; 
(defun XD::Polyline:addFillet (e index oper dis1 dis2 / an anc bulge dis eL1 
                                 eL2 int inx next num p_1 p_2 ret v1 v2 x 
                                 xdata xdata2 xreclist xrecLst 
                              ) 
  (setq inx (XD::PolyLine:-Index+ e index) 
        num (xdrx_polyline_numVerts e) 
        oper (strcase oper) 
  ) 
  (if (and 
        (> dis1 0) 
        (> dis2 0) 
        (setq ret 4)                       ; 顶点索引无效返回 
        (>= index 0) 
        (< index num) 
        (setq ret 3)                       ; 不封闭曲线，顶点索引在端点返回 
        (or 
          (xdrx_getpropertyvalue e "IsClosed") 
          (and 
            (/= (last inx) 0)               ; 不封闭线判断是否是两端点，是退出 
            (/= (car inx) (1- num)) 
          ) 
        ) 
        (setq ret 2)                       ; 顶点在弧线段返回 
        (= (xdrx_polyline_segtype e index) "kLine") 
        (= (xdrx_polyline_segtype e (car inx)) "kLine") 
      ) 
    (progn 
      (setq eL1 (xdrx_polyline_getLineSegAt e (car inx)) 
            eL2 (xdrx_polyline_getLineSegAt e index) 
            int (car (xdrx_curve_getinters eL1 eL2 3)) 
            v1 (xdrx_vector_normalize (mapcar 
                                        '- 
                                        (car eL1) 
                                        (cadr eL1) 
                                      ) 
               ) 
            v2 (xdrx_vector_normalize (mapcar 
                                        '- 
                                        (last eL2) 
                                        (car eL2) 
                                      ) 
               ) 
      ) 
      (setq p_1 (mapcar 
                  '+ 
                  int 
                  (xdrx_vector_product v1 dis1) 
                ) 
      ) 
      (cond 
        ((= oper "C") 
          (setq p_2 (mapcar 
                      '+ 
                      int 
                      (xdrx_vector_product v2 dis2) 
                    ) 
          ) 
        ) 
        ((= oper "F") 
          (setq p_2 (mapcar 
                      '+ 
                      int 
                      (xdrx_vector_product v2 dis1) 
                    ) 
          ) 
          (setq an (xdrx_math_acos (xdrx_vector_dotproduct v2 v1))) 
          (if (< an 0.0) 
            (setq an (+ (* 2 PI) an)) 
          ) 
          (if (> an pi) 
            (setq an (- (* 2 PI) an)) 
          ) 
          (setq anc (- pi an) 
                dis (abs (* dis1 (xdrx_math_tan (/ anc 2.0)))) 
                dis1 dis 
                dis2 dis 
                bulge (xdrx_math_tan (/ anc 4.0)) 
          ) 
        ) 
      ) 
      (if (minusp (xdrx_points_area p_1 int p_2)) 
        (setq bulge (- bulge)) 
      ) 
      (setq ret 1)                       ; 算点不在曲线上 
      (if (and 
            (xdrx_point_ison p_1 e) 
            (xdrx_point_ison p_2 e) 
          ) 
        (progn 
          (setq next (cadr inx)) 
          (xdrx_polyline_addVertexAt e index p_1) 
          (if (= next 0) 
            (progn 
              (xdrx_polyline_setPointAt e (1+ index) p_2) 
            ) 
            (progn 
              (xdrx_polyline_setPointAt e (1+ index) p_2) 
            ) 
          ) 
          (if (= oper "F") 
            (xdrx_polyline_setBulgeAt e index bulge) 
          ) 
          (setq xrecLst (xdrx_xdata_get e "XD_FILLET")) 
          (if (not (member index xreclist)) 
            (setq xrecLst (cons index xrecLst)) 
          ) 
          (setq xrecLst (vl-sort xrecLst '<) 
                xdata2 (member index xrecLst) 
                xdata (append 
                        (reverse (member index (reverse xrecLst))) 
                        (mapcar 
                          '(lambda (x) 
                             (1+ x) 
                           ) 
                          (cdr xdata2) 
                        ) 
                      ) 
          ) 
          (apply 
            'xdrx_xdata_set 
            (cons e (cons "XD_FILLET" xdata)) 
          ) 
          (setq ret 0)                       ; 成功 
        ) 
      ) 
    ) 
  ) 
  ret 
)

/db_自贡黄明儒_ · 发表于 2018-1-12 15:52:56

N版，为什么两条多段线(vl-cmdf "_.fillet" (entsel) (entsel))倒不了角，手工却可以？

sachindkini · 发表于 2013-10-30 13:09:08

DEAR SIR,

NICE

/db_自贡黄明儒_ · 发表于 2013-11-2 16:09:47

这个还真复杂

st788796 · 发表于 2013-11-2 16:13:45

写了扩展数据才知道哪个是倒角线哪个是直线

章鱼366 · 发表于 2017-2-22 16:43:34

sachindkini 发表于 2013-10-30 13:09

用不来这个函数，怎么用啊

章鱼366 · 发表于 2017-2-22 16:47:48

请问加载这个应用程序以后是输入什么命令啊？

xiaolong100 · 发表于 2017-10-26 15:23:58

还是有好多的子函数没有开源，没加载函数库就用不了!

land100 · 发表于 2017-10-29 08:25:09

不错奥！打发vsvsdv

lixiaolin1974 · 发表于 2017-10-29 10:16:20

下载试试

账号		自动登录	找回密码
密码			立即注册

[多段线] (XD::Polyline:AddFillet)指定顶点索引处F,C倒角

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。