画圆及中心线

lucas3 · 发表于 2014-9-7 01:40:53

本帖最后由 lucas3 于 2014-9-9 17:38 编辑

1. 首先，拾取放置中心点
2. 输入大圆直径：30 （也可拾取，也可输入）
3. 输入小圆直径： 10
4. 输入均布个数： 6
5. 输入偏移角度： 30
绘制出6个圆，并绘制出中心线，那个直经为30的圆也属于中心线，中心线图层为中心线层，圆为当前图层，
中心线每端超出圆的长度=圆直径*0.2倍（图中所示，每端超出为2，）
注：图中的一条过圆中心的水平直线不用绘出，只是标偏移角参照用

st788796 · 发表于 2014-9-7 23:46:16

再体会体会 ODCL 用法（ODCL 8.0 以上）,参数获取用非模态对话框，点击绘图自动关闭对话框，同时分开写还可以增加命令行版本，无需界面

;;初始值设置
(mapcar '(lambda (x y)
(if (not (eval x))
(set x y)
)
)
'($globle_dRadius
$globle_sRadius
$globle_Angle
$globle_number
)
'(30.0 10.0 30.0 6)
)
;;角度按钮
(defun c:test/form1/aPick#OnClicked (/ an)
(if (setq an (getangle (strcat "\n偏转角度<"
(vl-princ-to-string $globle_angle)
">: "
)
)
)
(progn
(setq $globle_angle (* (/ an pi) 180.))
(dcl-control-settext
test/form1/Angle
(vl-princ-to-string $globle_angle)
)
)
)
(princ)
)
;;大圆直径按钮
(defun c:test/form1/dPick#OnClicked (/ d)
(if (setq d (getdist (strcat "\n大圆直径<"
(vl-princ-to-string $globle_dradius)
">: "
)
)
)
(progn
(setq $globle_dradius d)
(dcl-control-settext
test/form1/dradius
(vl-princ-to-string $globle_dradius)
)
)
)
(princ)
)
;;小圆直径按钮
(defun c:test/form1/sPick#OnClicked (/ d)
(if (setq d (getdist (strcat "\n小圆直径<"
(vl-princ-to-string $globle_sradius)
">: "
)
)
)
(progn
(setq $globle_sradius d)
(dcl-control-settext
test/form1/sradius
(vl-princ-to-string $globle_sradius)
)
)
)
(princ)
)
;;绘制按钮
(defun c:test/form1/Draw#OnClicked (/)
(mapcar
'(lambda (x y)
(setq x (distof (dcl-control-gettext (eval y))))
)
'($globle_dRadius $globle_sRadius $globle_Angle)
'(test/form1/dRadius test/form1/sRadius test/form1/Angle)
)
(setq $globle_Number
(atoi (dcl-control-gettext test/form1/Number))
)
(dcl-form-close test/form1)
(DoDrawCircle t)
(princ)
)
;;命令行版本
(defun CmdGetInput (/ d d1 an i)
(if (setq d (getdist (strcat "\n大圆直径<"
(vl-princ-to-string $globle_dradius)
">: "
)
)
)
(setq $globle_dradius d )
)
(if (setq d1 (getdist (strcat "\n小圆直径<"
(vl-princ-to-string $globle_sradius)
">: "
)
)
)
(setq $globle_sradius d1)
)
(if (setq an (getangle (strcat "\n偏转角度<"
(vl-princ-to-string $globle_angle)
">: "
)
)
)
(setq $globle_angle (* (/ an pi) 180.))
)
(if (setq i (getint (strcat "\n数量<"
(vl-princ-to-string $globle_number)
">: "
)
)
)
(setq $globle_number i)
)
(DoDrawCircle t)
)
;;绘制主程序
;;可以单独写命令行版本
(defun DoDrawCircle (tf / p drawscircle)
(defun drawscircle (p r an num / pc circle d ln mat)
(setq pc (polar p (setq an (* pi (/ an 180.))) (/ $globle_dradius 2))
circle (xdrx_circle_make pc r)
d (* 1.2 r)
ln (xdrx_line_make (polar pc an d) (polar pc (+ pi an) d))
)
(ssadd circle ln)
(setq mat (xdrx_matrix_setrotation
mat0
(/ (+ pi pi) num)
'(0 0 1)
p
)
)
(repeat (fix num)
(setq ln (xdrx_entity_transformedcopy
ln
mat
)
)
)
)
(while (setq p (getpoint "\nCenter: "))
(xdrx_circle_make p (/ $globle_dradius 2.))
(drawscircle
p
(/ $globle_sradius 2.)
$globle_angle
$globle_number
)
)
)
;;主界面启动
(defun c:tt (/ str lst)
(defun c:test/form1#OnInitialize (/)
(mapcar
'(lambda (x y)
(dcl-control-settext (eval x) y)
)
'(test/form1/dRadius
test/form1/sRadius
test/form1/Angle
test/form1/Number
)
(mapcar
'vl-princ-to-string
(list $globle_dRadius
$globle_sRadius
$globle_Angle
$globle_Number
)
)
)
)
(setq str '("YWt6AwYvAAC9hE4ABuKT57URZStquEFZyA0rMiFudDRpO1M0OzadqDc2Jl4/3XQWYFhvdDZrtvfj"
"yJqv1jdhCj9IUvQkd8+fX24cu/TZuj0c/y4lLidrCy/PnnE+/Hx1PvY5vEe5bbGiTTfSL9Ky+rI6"
"HbGZDZmwA+Khx5kwyFCyUb5H7c1WH3jNNn6GyH+mumkaps3hcnsKrRlppJfUa4Uv2pUvxBTZIQ3a"
"JZeJMFevNBlvXQoINIdikFkL/hKM3nvQz/1SRxq3pDCJmJbgEFS7WammMwvzN0N7zPO3Ed0q0D6L"
"Ci4zAiPckWJIXV3z2n2md+0+Y+L9YO1E+m1G9zdUENAchdy7Vxx47/qZTg2sDUcA3nSzfKzwMg61"
"s0fboSqEIdsxVQN3V5UHpaOZw7OEBSuA8tuRZLt9JuLcSMYjpfN/Mp8vRPHtm0bzrHoD4N3s2EAf"
"iY5NiffcQS+ELdtBKITcFJ/VNIHTiifbrXclgZ2wfkG2ksjY0UBDgqON4/241sXAzzS/kgslN3D+"
"cvGM41zlyjnaca/eaxamNLWGOmMy29B/ySAQ/jclK1tRczPpwMZOSxlI1yCWB+DMkLWKH3bFlkI4"
"8+bewSOW37HdTrEolO+Z5G00MSik7Yb9gw0ip1nqiIapFdJlQ526GaBNxQobYCmIBSKzY06D0AD1"
"ix+bY8M0iVeD5qw2pp3Ymcsn89UZ4IHaTb3bZTuQjbMN0Xp1YJ6I1I3SxzHUh42Gv3CGgx7EOv9S"
"BZMb7SwA5C+ggd/0SWFXg/9UgcCskVeD0Kwvi72xo4/Ft5tDAMfrk1PU4/O04MmZoyIug4iGkyvI"
"scWx6Q+GJ8uZGBtitImB1oKQackBLIBZSiYE8cShvbcNzkcXOHNGd747aHBpyfUi9/UiU8eW/OH1"
"/4K6NakhApmXqw5fg/XHVskNYw2PWhJQYD82IqJYDFtQcKrs9UKCIhJH7GCAk4p1sbqVOw5QRtOF"
"QQ9fD629u0/6urvTXCmc3ATAYv71F4bHFgBUmLzMER5Q2kFgULBdelCmxL3v9PUa8ZJdsXofnCng"
"TXF9wmpXeJQawcXMgUlTiWDec/XzVMFvRlaRfzhPMBv1D+h7+eTqpVCnqxX0IC+Dji6KWxL0WvWv"
"asMgj4wMweUis9HXwup3618sCHRIG1MmJbQGi7WOlutvBK7JhIotbVkbg0cn68pIi+LSrGBsgSzV"
"7aZL5+S8FNWwmP6CKp0b5dWbkzUqhpcsg9C4MfVkmY0UYjjqYCikvaG9zoeF5IsDtIEk66gC6OrA"
"KYuZzKwRUsE0iM2D9syh04IB4Rmr4/VekR3Ug9WbwSXzIf4GDmgwQqZYrGlxLHGvzAjqosJqWmT2"
"sFRjXmSabtMWLvFGZI4PbghKhnSfOP1A0tEWjnqSFg5mb/J4EsM92lF5MWvuCWyiKxqfPMm0vJk5"
"EHIrt7wJUOH7xbN05Pn1oP4HxppJFeb59fAuYMBa9xXj+Vnj/yb0yuck7kj6JO1Ibe345spe2gu+"
"WBNiX+/IO9rhyhxTNuU70zdVuNpfpNo7k6NsgX2kNaQ7+j5k8SA42hFRp079PzSr9Jq42bafqQ5B"
"V5UewuHyogDMeUj/KW6QAMxplRVBx5qkZMuDWsmYaO+A9i5yVVy2BMN/XLyRDzqmLm8ft2JeHG//"
"8YF+3uk/Cg=="
)
lst (list $globle_dRadius
$globle_sRadius
$globle_Angle
$globle_Number
)
)
(dcl-project-import str)
(dcl-form-show test/form1)
(princ)
)
;;命令行版本
(defun c:tt1 (/) (CmdGetInput) (princ))

;;初始值设置 
(mapcar        '(lambda (x y) 
           (if (not (eval x)) 
             (set x y) 
           ) 
         ) 
        '($globle_dRadius 
          $globle_sRadius 
          $globle_Angle 
          $globle_number 
         ) 
        '(30.0 10.0 30.0 6) 
) 
 
;;角度按钮 
(defun c:test/form1/aPick#OnClicked (/ an) 
  (if (setq an (getangle (strcat "\n偏转角度<" 
                                 (vl-princ-to-string $globle_angle) 
                                 ">: " 
                         ) 
               ) 
      ) 
    (progn 
      (setq $globle_angle (* (/ an pi) 180.)) 
      (dcl-control-settext 
        test/form1/Angle 
        (vl-princ-to-string $globle_angle) 
      ) 
    ) 
  ) 
  (princ) 
) 
;;大圆直径按钮 
(defun c:test/form1/dPick#OnClicked (/ d) 
  (if (setq d (getdist (strcat "\n大圆直径<" 
                               (vl-princ-to-string $globle_dradius) 
                               ">: " 
                       ) 
              ) 
      ) 
    (progn 
      (setq $globle_dradius d) 
      (dcl-control-settext 
        test/form1/dradius 
        (vl-princ-to-string $globle_dradius) 
      ) 
    ) 
  ) 
  (princ) 
) 
;;小圆直径按钮 
(defun c:test/form1/sPick#OnClicked (/ d) 
  (if (setq d (getdist (strcat "\n小圆直径<" 
                               (vl-princ-to-string $globle_sradius) 
                               ">: " 
                       ) 
              ) 
      ) 
    (progn 
      (setq $globle_sradius d) 
      (dcl-control-settext 
        test/form1/sradius 
        (vl-princ-to-string $globle_sradius) 
      ) 
    ) 
  ) 
  (princ) 
) 
;;绘制按钮 
(defun c:test/form1/Draw#OnClicked (/) 
  (mapcar 
    '(lambda (x y) 
       (setq x (distof (dcl-control-gettext (eval y)))) 
     ) 
    '($globle_dRadius $globle_sRadius $globle_Angle) 
    '(test/form1/dRadius test/form1/sRadius test/form1/Angle) 
  ) 
  (setq        $globle_Number 
         (atoi (dcl-control-gettext test/form1/Number)) 
  ) 
  (dcl-form-close test/form1) 
  (DoDrawCircle t) 
  (princ) 
) 
;;命令行版本 
(defun CmdGetInput (/ d d1 an i) 
  (if (setq d (getdist (strcat "\n大圆直径<" 
                               (vl-princ-to-string $globle_dradius) 
                               ">: " 
                       ) 
              ) 
      ) 
    (setq $globle_dradius d   ) 
  ) 
  (if (setq d1 (getdist        (strcat        "\n小圆直径<" 
                                (vl-princ-to-string $globle_sradius) 
                                ">: " 
                        ) 
               ) 
      ) 
    (setq $globle_sradius d1) 
  ) 
  (if (setq an (getangle (strcat "\n偏转角度<" 
                                 (vl-princ-to-string $globle_angle) 
                                 ">: " 
                         ) 
               ) 
      ) 
    (setq $globle_angle (* (/ an pi) 180.)) 
  ) 
  (if (setq i (getint (strcat "\n数量<" 
                              (vl-princ-to-string $globle_number) 
                              ">: " 
                      ) 
              ) 
      ) 
    (setq $globle_number i) 
  ) 
  (DoDrawCircle t) 
) 
;;绘制主程序 
;;可以单独写命令行版本 
(defun DoDrawCircle (tf / p drawscircle) 
  (defun drawscircle (p r an num / pc circle d ln mat) 
    (setq pc         (polar p (setq an (* pi (/ an 180.))) (/ $globle_dradius 2)) 
          circle (xdrx_circle_make pc r) 
          d         (* 1.2 r) 
          ln         (xdrx_line_make (polar pc an d) (polar pc (+ pi an) d)) 
    ) 
    (ssadd circle ln) 
    (setq mat (xdrx_matrix_setrotation 
                mat0 
                (/ (+ pi pi) num) 
                '(0 0 1) 
                p 
              ) 
    ) 
    (repeat (fix num) 
      (setq ln (xdrx_entity_transformedcopy 
                 ln 
                 mat 
               ) 
      ) 
    ) 
  ) 
  (while (setq p (getpoint "\nCenter: ")) 
    (xdrx_circle_make p (/ $globle_dradius 2.)) 
    (drawscircle 
      p 
      (/ $globle_sradius 2.) 
      $globle_angle 
      $globle_number 
    ) 
  ) 
) 
;;主界面启动 
(defun c:tt (/ str lst) 
  (defun c:test/form1#OnInitialize (/) 
    (mapcar 
      '(lambda (x y) 
         (dcl-control-settext (eval x) y) 
       ) 
      '(test/form1/dRadius 
        test/form1/sRadius 
        test/form1/Angle 
        test/form1/Number 
       ) 
      (mapcar 
        'vl-princ-to-string 
        (list $globle_dRadius 
              $globle_sRadius 
              $globle_Angle 
              $globle_Number 
        ) 
      ) 
    ) 
  ) 
  (setq        str '("YWt6AwYvAAC9hE4ABuKT57URZStquEFZyA0rMiFudDRpO1M0OzadqDc2Jl4/3XQWYFhvdDZrtvfj" 
              "yJqv1jdhCj9IUvQkd8+fX24cu/TZuj0c/y4lLidrCy/PnnE+/Hx1PvY5vEe5bbGiTTfSL9Ky+rI6" 
              "HbGZDZmwA+Khx5kwyFCyUb5H7c1WH3jNNn6GyH+mumkaps3hcnsKrRlppJfUa4Uv2pUvxBTZIQ3a" 
              "JZeJMFevNBlvXQoINIdikFkL/hKM3nvQz/1SRxq3pDCJmJbgEFS7WammMwvzN0N7zPO3Ed0q0D6L" 
              "Ci4zAiPckWJIXV3z2n2md+0+Y+L9YO1E+m1G9zdUENAchdy7Vxx47/qZTg2sDUcA3nSzfKzwMg61" 
              "s0fboSqEIdsxVQN3V5UHpaOZw7OEBSuA8tuRZLt9JuLcSMYjpfN/Mp8vRPHtm0bzrHoD4N3s2EAf" 
              "iY5NiffcQS+ELdtBKITcFJ/VNIHTiifbrXclgZ2wfkG2ksjY0UBDgqON4/241sXAzzS/kgslN3D+" 
              "cvGM41zlyjnaca/eaxamNLWGOmMy29B/ySAQ/jclK1tRczPpwMZOSxlI1yCWB+DMkLWKH3bFlkI4" 
              "8+bewSOW37HdTrEolO+Z5G00MSik7Yb9gw0ip1nqiIapFdJlQ526GaBNxQobYCmIBSKzY06D0AD1" 
              "ix+bY8M0iVeD5qw2pp3Ymcsn89UZ4IHaTb3bZTuQjbMN0Xp1YJ6I1I3SxzHUh42Gv3CGgx7EOv9S" 
              "BZMb7SwA5C+ggd/0SWFXg/9UgcCskVeD0Kwvi72xo4/Ft5tDAMfrk1PU4/O04MmZoyIug4iGkyvI" 
              "scWx6Q+GJ8uZGBtitImB1oKQackBLIBZSiYE8cShvbcNzkcXOHNGd747aHBpyfUi9/UiU8eW/OH1" 
              "/4K6NakhApmXqw5fg/XHVskNYw2PWhJQYD82IqJYDFtQcKrs9UKCIhJH7GCAk4p1sbqVOw5QRtOF" 
              "QQ9fD629u0/6urvTXCmc3ATAYv71F4bHFgBUmLzMER5Q2kFgULBdelCmxL3v9PUa8ZJdsXofnCng" 
              "TXF9wmpXeJQawcXMgUlTiWDec/XzVMFvRlaRfzhPMBv1D+h7+eTqpVCnqxX0IC+Dji6KWxL0WvWv" 
              "asMgj4wMweUis9HXwup3618sCHRIG1MmJbQGi7WOlutvBK7JhIotbVkbg0cn68pIi+LSrGBsgSzV" 
              "7aZL5+S8FNWwmP6CKp0b5dWbkzUqhpcsg9C4MfVkmY0UYjjqYCikvaG9zoeF5IsDtIEk66gC6OrA" 
              "KYuZzKwRUsE0iM2D9syh04IB4Rmr4/VekR3Ug9WbwSXzIf4GDmgwQqZYrGlxLHGvzAjqosJqWmT2" 
              "sFRjXmSabtMWLvFGZI4PbghKhnSfOP1A0tEWjnqSFg5mb/J4EsM92lF5MWvuCWyiKxqfPMm0vJk5" 
              "EHIrt7wJUOH7xbN05Pn1oP4HxppJFeb59fAuYMBa9xXj+Vnj/yb0yuck7kj6JO1Ibe345spe2gu+" 
              "WBNiX+/IO9rhyhxTNuU70zdVuNpfpNo7k6NsgX2kNaQ7+j5k8SA42hFRp079PzSr9Jq42bafqQ5B" 
              "V5UewuHyogDMeUj/KW6QAMxplRVBx5qkZMuDWsmYaO+A9i5yVVy2BMN/XLyRDzqmLm8ft2JeHG//" 
              "8YF+3uk/Cg==" 
             ) 
        lst (list $globle_dRadius 
                  $globle_sRadius 
                  $globle_Angle 
                  $globle_Number 
            ) 
  ) 
  (dcl-project-import str) 
  (dcl-form-show test/form1) 
  (princ) 
) 
;;命令行版本 
(defun c:tt1 (/) (CmdGetInput) (princ))

st788796 · 发表于 2014-9-8 07:15:25

本帖最后由 st788796 于 2014-9-8 08:22 编辑

newer 发表于 2014-9-8 02:19
必须用ODCL 8.0以上版本吗？ 8.0以上有什么新的东西？

因为用的电脑只有AutoCAD 2015 ，8.X版本ODCL才支持15，上班后再改成低版本的
说到8.X的好处, 这个程序是第一次用8.07写, 确实有方便之处
1 最高支持2015
2  函数名连接由下划线改成横线，而且两者均显示为内置函数，好处就是输入不必按shift再按下划线，方便输入同时也保持对低版的兼容
3 控件名由  /  代替下划线，好处同2

我在想这种获取输入参数的方式怎样更高效一些，界面上既可以输入也可以拾取，在 Modal 方式下点界面上任何一个拾取按钮就直接拾取该对应参数，其它都用界面内的默认值，不再返回界面，或者在 Modaless 模式下，界面一直显示，输入和点取改变界面输入框的值，只有点界面内的绘制才是获取界面内参数进入绘制主程序

第一种方法可能对已经养成的习惯需要再适应

2015 API  用8.30 号那个 x64 版本绘制 circle 提示 Lockxxx , 新版本没有试

Free-Lancer · 发表于 2014-9-7 01:40:54

lucas3 发表于 2014-9-7 19:17
谢谢Free-Lancer 大师，感谢您的再次帮助，
能不能脱离API呢？用您的app.fas函数，主要是 ...

就替换几句话而已

(mapcar '(lambda (x y)
(if (not (eval x))
(set x y)
)
)
'($globle_dradius $globle_sradius $globle_num $globle_angle)
'(30. 10. 6 30.)
)
(defun c:tt (/ actionkey dopick doaccept drawscircle
getinput strl $keyinput fn id
p lst
)
;;手动输入
(defun actionkey (kl)
(mapcar
'(lambda (x)
(action_tile
x
"(set (read (strcat \"$globle_\" $key ))(distof $value))"
)
)
kl
)
)
;;点击拾取
(defun dopick (key)
(if (= key "apick")
(setq $keyinput 1)
(setq $keyinput 0)
)
(done_dialog)
)
;;点击确定
(defun doaccept ()
(setq lst (dcl:gettile '("dradius" "sradius" "angle" "num")))
(done_dialog)
)
;;绘制小圆
(defun drawscircle (p r an num / pc circle d ln mat an1 an0 lst)
(setq pc (polar p an (/ $globle_dradius 2))
circle (vlax-invoke (fy:acspace) 'AddCircle pc r)
;;(xdrx_circle_make pc r)
d (* 1.2 r)
ln (vlax-invoke
(fy:Acspace)
'Addline
(polar pc an d)
(polar pc (+ pi an) d)
)
;;(xdrx_line_make (polar pc an d) (polar pc (+ pi an) d))
)
(vla-put-layer ln "中心线")
;;(ssadd circle ln)
;|
(setq an1 (/ (+ pi pi) num)
mat (xdrx_matrix_setrotation
mat0
an1
'(0 0 1)
p
)
)
(repeat (fix num)
(setq ln (xdrx_entity_transformedcopy
ln
mat
)
)
)|;
(mapcar '(lambda (x)
(vla-arraypolar
x
(fix num)
(+ pi pi)
(vlax-3d-point p)
)
)
(list circle ln)
)
)
(defun getinput (/ dc an)
(if (and (zerop $keyinput)
(setq
dc (getdist (strcat "\n大圆半径<"
(vl-princ-to-string $globle_dradius)
">: "
)
)
)
)
(setq $globle_dradius dc)
)
(if (and (= $keyinput 1)
(setq
an (getangle (strcat "\n偏转角度<"
(vl-princ-to-string $globle_angle)
">: "
)
)
)
)
(setq $globle_angle (math:rtd an))
)
)
(setq strl
'("temp:dialog {"
" label = \"圆绘制\" ;"
" :boxed_column {"
" label =\"参数\" ;"
" :row {"
" :edit_box { key = \"dradius\" ; label = \"大圆直径\" ; }"
" :button { key = \"dpick\" ; label = \"拾取\" ; width = 8 ; }"
" }"
" :row {"
" :edit_box { key = \"angle\" ; label = \"偏转角度\" ; }"
" :button { key = \"apick\" ; label = \"拾取\" ; width = 8 ;}"
" }"
" :row {"
" :edit_box { key = \"sradius\" ; label = \"小圆直径\" ;}"
" :edit_box { key = \"num\" ; label = \"数量\" ; }"
" }"
" }"
" ok_cancel;"
" errtile;"
"}"
)
)
;;Main program
(setq fn (dcl:make strl) ;_写出DCL
id (dcl:load fn "temp") ;_加载DCL
)
(dcl:settile
'("dradius" "sradius" "angle" "num")
(mapcar 'vl-princ-to-string
(list $globle_dradius
$globle_sradius
$globle_angle
$globle_num
)
)
) ;_设置默认值
(dcl:chknumin '("dradius" "sradius" "angle" "num")) ;_检查输入格式
(actionkey '("dradius" "sradius" "angle" "num")) ;_手动输入时记录变量
(mapcar '(lambda (x) (action_tile x "(dopick $key)"))
'("dpick" "apick")
) ;_点取拾取按钮后进入命令行模式
(action_tile "accept" "(doaccept)") ;_点击确定直接进入绘图
;;主程序
(dcl:start id fn) ;_start dialog
(if (or $keyinput lst) ;_点击确定或者点拾取后继续
(progn
(if lst
(mapcar
'set
'($globle_dradius $globle_sradius $globle_angle $globle_num)
(mapcar 'read lst)
)
(getinput)
)
(while (setq p (getpoint "\n中心点: "))
(vlax-invoke
(fy:acspace)
'AddCircle
p
(/ $globle_dradius 2.)
)
;;(xdrx_circle_make p (/ $globle_dradius 2.))
(drawscircle
p
(/ $globle_sradius 2.)
(math:dtr $globle_angle)
$globle_num
)
)
)
)
(princ)
)
;;============================================
(defun math:rtd (n) (* (/ n pi) 180.))
(defun math:dtr (n) (* (/ n 180.) pi))
;;清空 errtile 控件显示
(defun DCL:RsError () (set_tile "error" ""))
;;设置 errtile 控件文字
;;var ----- string
(defun DCL:SetError (val)
(dcl:RsError)
(set_tile "error" val)
)
;;检查输入格式(数字)
;;input ---- $value
;;format ---- string
;;kk ---- key
(defun DCL:CheckIn (input format kk /)
(if (and (distof input 2) (> (atof input) 0))
(progn (dcl:RsError) input)
(progn
(dcl:SetError (strcat "无效的" format "输入"))
(mode_tile kk 2)
nil
)
)
)
(defun DCL:ChkNumIn (kl /)
(mapcar '(lambda (x)
(action_tile x (strcat "(dcl:checkin $value \"数字\" " x))
)
kl
)
)
;;将DCL表写出文件
(defun DCL:Make (lst / flname ofile)
(setq FlName (vl-filename-mktemp (strcat "FYDCL" ".dcl"))
oFile (open FlName "w")
)
(foreach fStream lst (write-line fStream oFile)) ;写入文件
(close oFile) ;_关闭文档
flname
)
;;加载 DCL 文件
(defun DCL:Load (flname na / id)
(setq id (load_dialog FlName))
(if (not (new_dialog na id ""))
(progn (alert "对话框加载失败!") (exit))
)
id
)
;;显示对话框
(defun dcl:start (id flname / dg)
(setq dg (start_dialog))
(unload_dialog id) ;_卸载对话框
(vl-file-delete FlName) ;_删除DCL文件
)
;;获取控件值
;;lst ---- key list
(defun DCL:Gettile (lst)
(mapcar '(lambda (x)
(get_tile x)
)
lst
)
)
;;批量设置控件值
;;kl ------ key list
;;pl ------ list
(defun DCL:Settile (kl pl)
(mapcar '(lambda (x y)
(set_tile x y)
)
kl
pl
)
)

(mapcar        '(lambda (x y) 
           (if (not (eval x)) 
             (set x y) 
           ) 
         ) 
        '($globle_dradius $globle_sradius $globle_num $globle_angle) 
        '(30. 10. 6 30.) 
) 
(defun c:tt (/               actionkey dopick           doaccept  drawscircle 
             getinput  strl         $keyinput fn             id 
             p               lst 
            ) 
  ;;手动输入 
  (defun actionkey (kl) 
    (mapcar 
      '(lambda (x) 
         (action_tile 
           x 
           "(set (read (strcat \"$globle_\" $key ))(distof $value))" 
         ) 
       ) 
      kl 
    ) 
  ) 
  ;;点击拾取 
  (defun dopick        (key) 
    (if        (= key "apick") 
      (setq $keyinput 1) 
      (setq $keyinput 0) 
    ) 
    (done_dialog) 
  ) 
  ;;点击确定 
  (defun doaccept () 
    (setq lst (dcl:gettile '("dradius" "sradius" "angle" "num"))) 
    (done_dialog) 
  ) 
  ;;绘制小圆 
  (defun drawscircle (p r an num / pc circle d ln mat an1 an0 lst) 
    (setq pc         (polar p an (/ $globle_dradius 2)) 
          circle (vlax-invoke (fy:acspace) 'AddCircle pc r) 
          ;;(xdrx_circle_make pc r) 
          d         (* 1.2 r) 
          ln         (vlax-invoke 
                   (fy:Acspace) 
                   'Addline 
                   (polar pc an d) 
                   (polar pc (+ pi an) d) 
                 ) 
                 ;;(xdrx_line_make (polar pc an d) (polar pc (+ pi an) d)) 
    ) 
    (vla-put-layer ln "中心线") 
    ;;(ssadd circle ln) 
    ;| 
    (setq an1 (/ (+ pi pi) num) 
          mat (xdrx_matrix_setrotation 
                mat0 
                an1 
                '(0 0 1) 
                p 
              ) 
    ) 
    (repeat (fix num) 
      (setq ln (xdrx_entity_transformedcopy 
                 ln 
                 mat 
               ) 
      ) 
    )|; 
    (mapcar '(lambda (x) 
               (vla-arraypolar 
                 x 
                 (fix num) 
                 (+ pi pi) 
                 (vlax-3d-point p) 
               ) 
             ) 
            (list circle ln) 
    )    
  ) 
  (defun getinput (/ dc an) 
    (if        (and (zerop $keyinput) 
             (setq 
               dc (getdist (strcat "\n大圆半径<" 
                                   (vl-princ-to-string $globle_dradius) 
                                   ">: " 
                           ) 
                  ) 
             ) 
        ) 
      (setq $globle_dradius dc) 
    ) 
    (if        (and (= $keyinput 1) 
             (setq 
               an (getangle (strcat "\n偏转角度<" 
                                    (vl-princ-to-string $globle_angle) 
                                    ">: " 
                            ) 
                  ) 
             ) 
        ) 
      (setq $globle_angle (math:rtd an)) 
    ) 
  ) 
  (setq        strl 
         '("temp:dialog {" 
           "    label = \"圆绘制\" ;" 
           "    :boxed_column {" 
           "     label =\"参数\" ;" 
           "        :row {" 
           "            :edit_box {   key = \"dradius\" ;  label = \"大圆直径\" ; }" 
           "           :button { key = \"dpick\" ; label = \"拾取\" ;  width = 8 ; }" 
           "       }" 
           "      :row {" 
           "          :edit_box { key = \"angle\" ; label = \"偏转角度\" ; }" 
           "           :button { key = \"apick\" ; label = \"拾取\" ; width = 8 ;}" 
           "      }" 
           "     :row {" 
           "          :edit_box { key = \"sradius\" ; label = \"小圆直径\" ;}" 
           "          :edit_box { key = \"num\" ;  label = \"数量\" ; }" 
           "      }" 
           "  }" 
           "   ok_cancel;" 
           "   errtile;" 
           "}" 
          ) 
  ) 
  ;;Main program 
  (setq        fn (dcl:make strl) ;_写出DCL 
        id (dcl:load fn "temp") ;_加载DCL 
  ) 
  (dcl:settile 
    '("dradius" "sradius" "angle" "num") 
    (mapcar 'vl-princ-to-string 
            (list $globle_dradius 
                  $globle_sradius 
                  $globle_angle 
                  $globle_num 
            ) 
    ) 
  ) ;_设置默认值 
  (dcl:chknumin '("dradius" "sradius" "angle" "num")) ;_检查输入格式 
  (actionkey '("dradius" "sradius" "angle" "num")) ;_手动输入时记录变量 
  (mapcar '(lambda (x) (action_tile x "(dopick $key)")) 
          '("dpick" "apick") 
  ) ;_点取拾取按钮后进入命令行模式 
  (action_tile "accept" "(doaccept)") ;_点击确定直接进入绘图 
  ;;主程序 
  (dcl:start id fn) ;_start dialog 
  (if (or $keyinput lst) ;_点击确定或者点拾取后继续 
    (progn 
      (if lst 
        (mapcar 
          'set 
          '($globle_dradius $globle_sradius $globle_angle $globle_num) 
          (mapcar 'read lst) 
        ) 
        (getinput) 
      ) 
      (while (setq p (getpoint "\n中心点: ")) 
        (vlax-invoke 
          (fy:acspace) 
          'AddCircle 
          p 
          (/ $globle_dradius 2.) 
        ) 
        ;;(xdrx_circle_make p (/ $globle_dradius 2.)) 
        (drawscircle 
          p 
          (/ $globle_sradius 2.) 
          (math:dtr $globle_angle) 
          $globle_num 
        ) 
      ) 
    ) 
  ) 
  (princ) 
) 
 
;;============================================ 
(defun math:rtd (n) (* (/ n pi) 180.)) 
(defun math:dtr (n) (* (/ n 180.) pi)) 
;;清空 errtile 控件显示 
(defun DCL:RsError () (set_tile "error" "")) 
;;设置 errtile 控件 文字 
;;var ----- string 
(defun DCL:SetError (val) 
  (dcl:RsError) 
  (set_tile "error" val) 
) 
;;检查输入格式(数字) 
;;input  ---- $value 
;;format ---- string 
;;kk     ---- key 
(defun DCL:CheckIn (input format kk /) 
  (if (and (distof input 2) (> (atof input) 0)) 
    (progn (dcl:RsError) input) 
    (progn 
      (dcl:SetError (strcat "无效的" format "输入")) 
      (mode_tile kk 2) 
      nil 
    ) 
  ) 
) 
(defun DCL:ChkNumIn (kl /) 
  (mapcar '(lambda (x) 
             (action_tile x (strcat "(dcl:checkin $value \"数字\" " x)) 
           ) 
          kl 
  ) 
) 
;;将DCL表写出文件 
(defun DCL:Make        (lst / flname ofile) 
  (setq        FlName (vl-filename-mktemp (strcat "FYDCL" ".dcl")) 
        oFile  (open FlName "w") 
  ) 
  (foreach fStream lst (write-line fStream oFile)) ;写入文件 
  (close oFile) ;_关闭文档 
  flname 
) 
;;加载 DCL 文件 
(defun DCL:Load        (flname na / id) 
  (setq id (load_dialog FlName)) 
  (if (not (new_dialog na id "")) 
    (progn (alert "对话框加载失败!") (exit)) 
  ) 
  id 
) 
;;显示对话框 
(defun dcl:start (id flname / dg) 
  (setq dg (start_dialog)) 
  (unload_dialog id) ;_卸载对话框 
  (vl-file-delete FlName) ;_删除DCL文件   
) 
;;获取 控件 值 
;;lst ---- key list 
(defun DCL:Gettile (lst) 
  (mapcar '(lambda (x) 
             (get_tile x) 
           ) 
          lst 
  ) 
) 
;;批量设置控件值 
;;kl  ------ key list 
;;pl  ------ list 
(defun DCL:Settile (kl pl) 
  (mapcar '(lambda (x y) 
             (set_tile x y) 
           ) 
          kl 
          pl 
  ) 
)

Free-Lancer · 发表于 2014-9-7 11:52:30

本帖最后由 Free-Lancer 于 2014-9-7 12:06 编辑

试试i这个，绘制实体和旋转拷贝用了 xdrxapi

(mapcar '(lambda (x y)
(if (not x)
(setq x y)
)
)
'($globle_dradius $globle_sradius $globle_num $globle_angle)
'(30. 10. 6 30.)
)
(setq mat0 (xdrx_matrix_identity))
(defun c:tt (/ actionkey dopick doaccept drawscircle
getinput strl $keyinput fn id
p lst
)
;;手动输入
(defun actionkey (kl)
(mapcar
'(lambda (x)
(action_tile
x
"(set (read (strcat \"$globle_\" $key ))(distof $value))"
)
)
kl
)
)
;;点击拾取
(defun dopick (key)
(if (= key "apick")
(setq $keyinput 1)
(setq $keyinput 0)
)
(done_dialog)
)
;;点击确定
(defun doaccept ()
(setq lst (dcl:gettile '("dradius" "sradius" "angle" "num")))
(done_dialog)
)
;;绘制小圆
(defun drawscircle (p r an num / pc circle d ln mat an1 an0)
(setq pc (polar p an (/ $globle_dradius 2))
circle (xdrx_circle_make pc r)
d (* 1.2 r)
ln (xdrx_line_make (polar pc an d) (polar pc (+ pi an) d))
)
(ssadd circle ln)
(setq an1 (/ (+ pi pi) num)
mat (xdrx_matrix_setrotation
mat0
an1
'(0 0 1)
p
)
)
(repeat (fix num)
(setq ln (xdrx_entity_transformedcopy
ln
mat
)
)
)
)
(defun getinput (/ dc an)
(if (and (zerop $keyinput)
(setq
dc (getdist (strcat "\n大圆半径<"
(vl-princ-to-string $globle_dradius)
">: "
)
)
)
)
(setq $globle_dradius dc)
)
(if (and (= $keyinput 1)
(setq
an (getangle (strcat "\n偏转角度<"
(vl-princ-to-string $globle_angle)
">: "
)
)
)
)
(setq $globle_angle (math:rtd an))
)
)
(setq strl
'("temp:dialog {"
" label = \"圆绘制\" ;"
" :boxed_column {"
" label =\"参数\" ;"
" :row {"
" :edit_box { key = \"dradius\" ; label = \"大圆直径\" ; }"
" :button { key = \"dpick\" ; label = \"拾取\" ; width = 8 ; }"
" }"
" :row {"
" :edit_box { key = \"angle\" ; label = \"偏转角度\" ; }"
" :button { key = \"apick\" ; label = \"拾取\" ; width = 8 ;}"
" }"
" :row {"
" :edit_box { key = \"sradius\" ; label = \"小圆直径\" ;}"
" :edit_box { key = \"num\" ; label = \"数量\" ; }"
" }"
" }"
" ok_cancel;"
" errtile;"
"}"
)
)
;;Main program
(setq fn (dcl:make strl) ;_写出DCL
id (dcl:load fn "temp") ;_加载DCL
)
(dcl:settile
'("dradius" "sradius" "angle" "num")
(mapcar 'vl-princ-to-string
(list $globle_dradius
$globle_sradius
$globle_angle
$globle_num
)
)
) ;_设置默认值
(dcl:chknumin '("dradius" "sradius" "angle" "num")) ;_检查输入格式
(actionkey '("dradius" "sradius" "angle" "num")) ;_手动输入时记录变量
(mapcar '(lambda (x) (action_tile x "(dopick $key)"))
'("dpick" "apick")
) ;_点取拾取按钮后进入命令行模式
(action_tile "accept" "(doaccept)") ;_点击确定直接进入绘图
;;主程序
(dcl:start id fn) ;_start dialog
(if (or $keyinput lst) ;_点击确定或者点拾取后继续
(progn
(if lst
(mapcar
'set
'($globle_dradius $globle_sradius $globle_angle $globle_num)
(mapcar 'read lst)
)
(getinput)
)
(while (setq p (getpoint "\n中心点: "))
(xdrx_circle_make p (/ $globle_dradius 2.))
(drawscircle
p
(/ $globle_sradius 2.)
(math:dtr $globle_angle)
$globle_num
)
)
)
)
(princ)
)
;;============================================
(defun math:rtd (n)
(* (/ n pi) 180.)
)
(defun math:dtr (n)
(* (/ n 180.) pi)
)
;;清空 errtile 控件显示
(defun DCL:RsError ()
(set_tile "error" "")
)
;;设置 errtile 控件文字
;;var ----- string
(defun DCL:SetError (val)
(dcl:RsError)
(set_tile "error" val)
)
;;检查输入格式(数字)
;;input ---- $value
;;format ---- string
;;kk ---- key
(defun DCL:CheckIn (input format kk /)
(if (and (distof input 2) (> (atof input) 0))
(progn (dcl:RsError) input)
(progn
(dcl:SetError (strcat "无效的" format "输入"))
(mode_tile kk 2)
nil
)
)
)
(defun DCL:ChkNumIn (kl /)
(mapcar '(lambda (x)
(action_tile x (strcat "(dcl:checkin $value \"数字\" " x))
)
kl
)
)
;;将DCL表写出文件
(defun DCL:Make (lst / flname ofile)
(setq FlName (vl-filename-mktemp (strcat "FYDCL" ".dcl"))
oFile (open FlName "w")
)
(foreach fStream lst (write-line fStream oFile)) ;写入文件
(close oFile) ;_关闭文档
flname
)
;;加载 DCL 文件
(defun DCL:Load (flname na / id)
(setq id (load_dialog FlName))
(if (not (new_dialog na id ""))
(progn (alert "对话框加载失败!") (exit))
)
id
)
;;显示对话框
(defun dcl:start (id flname / dg)
(setq dg (start_dialog))
(unload_dialog id) ;_卸载对话框
(vl-file-delete FlName) ;_删除DCL文件
)
;;获取控件值
;;lst ---- key list
(defun DCL:Gettile (lst)
(mapcar '(lambda (x)
(get_tile x)
)
lst
)
)
;;批量设置控件值
;;kl ------ key list
;;pl ------ list
(defun DCL:Settile (kl pl)
(mapcar '(lambda (x y)
(set_tile x y)
)
kl
pl
)
)

(mapcar        '(lambda (x y) 
           (if (not x) 
             (setq x y) 
           ) 
         ) 
        '($globle_dradius $globle_sradius $globle_num $globle_angle) 
        '(30. 10. 6 30.) 
) 
(setq mat0 (xdrx_matrix_identity)) 
(defun c:tt (/               actionkey dopick           doaccept  drawscircle 
             getinput  strl         $keyinput fn             id 
             p               lst 
            ) 
  ;;手动输入 
  (defun actionkey (kl) 
    (mapcar 
      '(lambda (x) 
         (action_tile 
           x 
           "(set (read (strcat \"$globle_\" $key ))(distof $value))" 
         ) 
       ) 
      kl 
    ) 
  ) 
  ;;点击拾取 
  (defun dopick        (key) 
    (if        (= key "apick") 
      (setq $keyinput 1) 
      (setq $keyinput 0) 
    ) 
    (done_dialog) 
  ) 
  ;;点击确定 
  (defun doaccept () 
    (setq lst (dcl:gettile '("dradius" "sradius" "angle" "num"))) 
    (done_dialog) 
  ) 
  ;;绘制小圆 
  (defun drawscircle (p r an num / pc circle d ln mat an1 an0) 
    (setq pc         (polar p an (/ $globle_dradius 2)) 
          circle (xdrx_circle_make pc r) 
          d         (* 1.2 r) 
          ln         (xdrx_line_make (polar pc an d) (polar pc (+ pi an) d)) 
    ) 
    (ssadd circle ln) 
    (setq an1 (/ (+ pi pi) num) 
          mat (xdrx_matrix_setrotation 
                mat0 
                an1 
                '(0 0 1) 
                p 
              ) 
    ) 
    (repeat (fix num) 
      (setq ln (xdrx_entity_transformedcopy 
                 ln 
                 mat 
               ) 
      ) 
    ) 
  ) 
  (defun getinput (/ dc an) 
    (if        (and (zerop $keyinput) 
             (setq 
               dc (getdist (strcat "\n大圆半径<" 
                                   (vl-princ-to-string $globle_dradius) 
                                   ">: " 
                           ) 
                  ) 
             ) 
        ) 
      (setq $globle_dradius dc) 
    ) 
    (if        (and (= $keyinput 1) 
             (setq 
               an (getangle (strcat "\n偏转角度<" 
                                    (vl-princ-to-string $globle_angle) 
                                    ">: " 
                            ) 
                  ) 
             ) 
        ) 
      (setq $globle_angle (math:rtd an)) 
    ) 
  ) 
  (setq        strl 
         '("temp:dialog {" 
           "    label = \"圆绘制\" ;" 
           "    :boxed_column {" 
           "     label =\"参数\" ;" 
           "        :row {" 
           "            :edit_box {   key = \"dradius\" ;  label = \"大圆直径\" ; }" 
           "           :button { key = \"dpick\" ; label = \"拾取\" ;  width = 8 ; }" 
           "       }" 
           "      :row {" 
           "          :edit_box { key = \"angle\" ; label = \"偏转角度\" ; }" 
           "           :button { key = \"apick\" ; label = \"拾取\" ; width = 8 ;}" 
           "      }" 
           "     :row {" 
           "          :edit_box { key = \"sradius\" ; label = \"小圆直径\" ;}" 
           "          :edit_box { key = \"num\" ;  label = \"数量\" ; }" 
           "      }" 
           "  }" 
           "   ok_cancel;" 
           "   errtile;" 
           "}" 
          ) 
  ) 
  ;;Main program 
  (setq        fn (dcl:make strl) ;_写出DCL 
        id (dcl:load fn "temp") ;_加载DCL 
  ) 
  (dcl:settile 
    '("dradius" "sradius" "angle" "num") 
    (mapcar 'vl-princ-to-string 
            (list $globle_dradius 
                  $globle_sradius 
                  $globle_angle 
                  $globle_num 
            ) 
    ) 
  ) ;_设置默认值 
  (dcl:chknumin '("dradius" "sradius" "angle" "num")) ;_检查输入格式 
  (actionkey '("dradius" "sradius" "angle" "num")) ;_手动输入时记录变量 
  (mapcar '(lambda (x) (action_tile x "(dopick $key)")) 
          '("dpick" "apick") 
  ) ;_点取拾取按钮后进入命令行模式 
  (action_tile "accept" "(doaccept)") ;_点击确定直接进入绘图 
  ;;主程序 
  (dcl:start id fn) ;_start dialog 
  (if (or $keyinput lst) ;_点击确定或者点拾取后继续 
    (progn 
      (if lst 
        (mapcar 
          'set 
          '($globle_dradius $globle_sradius $globle_angle $globle_num) 
          (mapcar 'read lst) 
        ) 
        (getinput) 
      ) 
      (while (setq p (getpoint "\n中心点: ")) 
        (xdrx_circle_make p (/ $globle_dradius 2.)) 
        (drawscircle 
          p 
          (/ $globle_sradius 2.) 
          (math:dtr $globle_angle) 
          $globle_num 
        ) 
      ) 
    ) 
  ) 
  (princ) 
) 
;;============================================ 
(defun math:rtd        (n) 
  (* (/ n pi) 180.) 
) 
(defun math:dtr        (n) 
  (* (/ n 180.) pi) 
) 
;;清空 errtile 控件显示 
(defun DCL:RsError () 
  (set_tile "error" "") 
) 
;;设置 errtile 控件 文字 
;;var ----- string 
(defun DCL:SetError (val) 
  (dcl:RsError) 
  (set_tile "error" val) 
) 
;;检查输入格式(数字) 
;;input  ---- $value 
;;format ---- string 
;;kk     ---- key 
(defun DCL:CheckIn (input format kk /) 
  (if (and (distof input 2) (> (atof input) 0)) 
    (progn (dcl:RsError) input) 
    (progn 
      (dcl:SetError (strcat "无效的" format "输入")) 
      (mode_tile kk 2) 
      nil 
    ) 
  ) 
) 
(defun DCL:ChkNumIn (kl /) 
  (mapcar '(lambda (x) 
             (action_tile x (strcat "(dcl:checkin $value \"数字\" " x)) 
           ) 
          kl 
  ) 
) 
;;将DCL表写出文件 
(defun DCL:Make (lst / flname ofile) 
  (setq        FlName (vl-filename-mktemp (strcat "FYDCL" ".dcl")) 
        oFile  (open FlName "w") 
  ) 
  (foreach fStream lst (write-line fStream oFile)) ;写入文件 
  (close oFile) ;_关闭文档 
  flname 
) 
;;加载 DCL 文件 
(defun DCL:Load (flname na / id) 
  (setq id (load_dialog FlName)) 
  (if (not (new_dialog na id "")) 
    (progn (alert "对话框加载失败!") (exit)) 
  ) 
  id 
) 
;;显示对话框 
(defun dcl:start (id flname / dg) 
  (setq dg (start_dialog)) 
  (unload_dialog id) ;_卸载对话框 
  (vl-file-delete FlName) ;_删除DCL文件   
) 
;;获取 控件 值 
;;lst ---- key list 
(defun DCL:Gettile (lst) 
  (mapcar '(lambda (x) 
             (get_tile x) 
           ) 
          lst 
  ) 
) 
;;批量设置控件值 
;;kl  ------ key list 
;;pl  ------ list 
(defun DCL:Settile (kl pl) 
  (mapcar '(lambda (x y) 
             (set_tile x y) 
           ) 
          kl 
          pl 
  ) 
)

newer · 发表于 2014-9-7 14:06:53

你不用API，我就不写了。

帮别的朋友问你下：

有均布数后，还用偏移角度吗？你的工作不是都从0度角开始均布？

csharp · 发表于 2014-9-7 14:12:49

本帖最后由 csharp 于 2014-9-7 14:14 编辑

从0度使用偏移夹角后整体不一定对称，只有偶数才对称
2/3篇幅是处理输入数据

newer · 发表于 2014-9-7 16:38:51

csharp 发表于 2014-9-7 14:12
从0度使用偏移夹角后整体不一定对称，只有偶数才对称
2/3篇幅是处理输入数据

所以得问问他

如果有起始偏角后，均布后，那么第一个起始偏角的小圆，在都画完后，不一定是起始角后的第一个圆。这样就容易照成模糊了。

不知道他做什么工作的，是否工作中的都是均布对称的。

csharp · 发表于 2014-9-7 17:01:24

应该简化简化对话框输入和控制，大量的是简单界面，没有关联

lucas3 · 发表于 2014-9-7 19:17:11

Free-Lancer 发表于 2014-9-7 11:52
试试i这个，绘制实体和旋转拷贝用了 xdrxapi

谢谢Free-Lancer 大师，感谢您的再次帮助，{:soso_e160:}
能不能脱离API呢？用您的app.fas函数，主要是API更新公司的电脑拷贝文件进出比较麻烦，请您理解！
另外，中心线用'中心线'图层，关于此图层是否存在，这一点不用担心。
对话框初次绘制时有个默认值，而不是nil

以上，谢谢！！！

lucas3 · 发表于 2014-9-7 22:14:46

Free-Lancer 发表于 2014-9-7 22:01
就替换几句话而已

Free-Lancer大师，非常感谢！
还差一点点，绘制的大圆也属于“中心线”图层，要怎样改呢？

Free-Lancer · 发表于 2014-9-7 22:21:35

lucas3 发表于 2014-9-7 22:14
Free-Lancer大师，非常感谢！
还差一点点，绘制的大圆也属于“中心线”图层，要怎样改呢？

(while (setq p (getpoint "\n中心点: "))
(vla-put-layer
(vlax-invoke
(fy:acspace)
'AddCircle
p
(/ $globle_dradius 2.)
)
"中心线"
)
(drawscircle
p
(/ $globle_sradius 2.)
(math:dtr $globle_angle)
$globle_num
)
)

lucas3 · 发表于 2014-9-7 22:46:35

再次感谢Free-Lancer大师！晓东有您更精彩！{:soso_e178:}

newer · 发表于 2014-9-8 02:19:46

st788796 发表于 2014-9-7 23:46
再体会体会 ODCL 用法（ODCL 8.0 以上）,参数获取用非模态对话框，点击绘图自动关闭对话框，同时分开写还 ...

必须用ODCL 8.0以上版本吗？ 8.0以上有什么新的东西？

账号		自动登录	找回密码
密码			立即注册

[已解决] 画圆及中心线

最佳答案

相关帖子

点评

评分

点评

点评

评分

评分

点评

评分

点评

浏览过的版块