请教通过点表绘制z非零的多段线

434939575 · 发表于 2016-11-20 21:05:25

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

(defun c:ttt ( / p1 p2 p3 p4)
(command "ucs" "w""")
;(setvar "osmode" 3)
(vl-cmdf "ucs" "3p"
(setq p1 '( 0 0 100 ) )
(setq p2 ' ( 100 0 100) )
(setq p3 ' (100 0 200) )
(setq p4 ' (0 0 200) )
)
(vl-cmdf "pline" (trans p1 0 1) (trans p2 0 1) (trans p3 0 1)(trans p4 0 1)"c""")
(command "ucs" "w""")
(princ)
)
我这里是每个点这样设置的，哪位朋友帮忙修改下， p1 p2 p3 p4 由任意长度点表代替！谢谢！

newer · 发表于 2016-11-20 22:32:56

用 entmake 搜索论坛，找关于生成多段线的，帖子不少。

Lisphk · 发表于 2016-11-20 22:40:28

看你的数据，Z值是不同的，这样不能生成二维多段线，只能生成3DPOLYLINE。
二维多段线是平面实体，Z值必须相同。
所以你不能用PLINE命令，要用3DPOLY命令。

434939575 · 发表于 2016-11-20 22:49:38

newer 发表于 2016-11-20 22:32

谢谢大师的关照，我有entmake的函数，那个Z值.都为0，我想Z非零的，。

434939575 · 发表于 2016-11-20 22:54:44

Lisphk 发表于 2016-11-20 22:40

多谢指点，我是用的，三维多段线，不好编揖，想改成多段线，用上面这种ucs能绘出非零的z值，但必须这样写，想用个点表代替下，

newer · 发表于 2016-11-20 23:01:59

本帖最后由 newer 于 2016-11-20 23:03 编辑

434939575 发表于 2016-11-20 22:54

LWPOLYLINE和2DPOLYLINE是平面实体，就是说所有的点必须在一个平面上，所以你构造的点表，不管Z值是什么，这些点必须在一个平面上，从这些点算出平面的法向向量组码210的值，而点坐标仍然是二维点，不要Z。用你收集的ENTMAKE创建多段线就行了，别忘了加上210组码。

你给的例子是特例，你这些点是根据什么来的呢？你怎么保证他们在一个平面上的，这个平面怎么来的？

newer · 发表于 2016-11-20 23:41:56

本帖最后由 newer 于 2016-11-20 23:43 编辑

;;;-----------------------------------------------------------;;
;;; 向量乘标量(系数)                                              ;;
;;; Vector x Scalar - Lee Mac                                      ;;
;;; Args: v - vector in R^n, s - real scalar                      ;;
;;;-----------------------------------------------------------;;
(defun MAT:vxs ( v s )
  (mapcar (function (lambda ( n ) (* n s))) v)
)
;;;-----------------------------------------------------------;;
;;; 单位向量                                                      ;;
;;; Unit Vector - Lee Mac                                     ;;
;;; Args: v - vector in R^n                                      ;;
;;;-----------------------------------------------------------;;
(defun MAT:Unitization (v)
  ( (lambda (n)
      (if (equal 0.0 n 1e-14)
        nil
        (MAT:vxs v (/ 1.0 n))
      )
    )
    (MAT:norm v)
  )
)
;;;-----------------------------------------------------------;;
;;; 向量的模(长度)                                              ;;
;;; Vector Norm - Lee Mac                                             ;;
;;; Args: v - vector in R^n                                      ;;
;;;-----------------------------------------------------------;;
(defun MAT:norm ( v )
  (sqrt (apply '+ (mapcar '* v v)))
)
;;;-----------------------------------------------------------;;
;;; 两向量的叉积                                              ;;
;;; Vector Cross Product                                       ;;
;;; Args: u,v - vectors in R^3                                      ;;
;;;-----------------------------------------------------------;;
(defun MAT:vxv ( u v )
  (list
    (- (* (cadr u) (caddr v)) (* (cadr v) (caddr u)))
    (- (* (car  v) (caddr u)) (* (car  u) (caddr v)))
    (- (* (car  u) (cadr  v)) (* (car  v) (cadr  u)))
  )
)
(defun c:tt ()
  (setq p1 '(0 0 100))
  (setq p2 '(100 0 100))
  (setq p3 '(100 0 200))
  (setq p4 '(0 0 200))
  (setq vec1 (mapcar '- p2 p1)
        vec2 (mapcar '- p3 p1)
        z210 (MAT:vxv vec1 vec2)
        z210 (MAT:Unitization z210)
  )
  (setq pts (mapcar '(lambda(x)(list (car x)(cadr x))) (list p1 p2 p3 p4)))
  (entmake (append
             (list (cons 0 "LWPOLYLINE")
                   (cons 100 "AcDbEntity")
                   (cons 100 "AcDbPolyline")
                   (cons 90 (length pts))
                   (cons 210 z210)
             )
             (mapcar
               '(lambda        (x)
                  (cons 10 x)
                )
               pts
             )
           )
  )  (princ)
)

执行TT，看生成的多段线是你想要的不。

cable2004 · 发表于 2016-11-21 00:14:14

我只是路过打酱油的

守仁格竹GM · 发表于 2016-11-21 08:23:58

我只是路过打酱油的

forb0217 · 发表于 2016-11-21 08:45:46

程序编制得太好了。

434939575 · 发表于 2016-11-21 21:14:52

newer 发表于 2016-11-20 23:41

谢谢老大，很好，这么晚还在帮助别人，一定要注意身体，我得了电脑病，l希望大家多多锻炼身体！我还个想法先不管Z作为零，画了再三维旋转。

newer · 发表于 2016-11-21 21:25:02

434939575 发表于 2016-11-21 21:14

好啊，想法实现了，代码贴上来和大家分享。

434939575 · 发表于 2016-11-22 15:13:28

(defun c:tt ()
(setq p1 '(0 0 100))
(setq p2 '(100 0 100))
(setq p3 '(100 0 200))
(setq p4 '(0 0 200))
(setq ls (list (list (car p1) (caddr p1))
(list (car p2) (caddr p2))
(list (car p3) (caddr p3))
(list (car p4) (caddr p4))
)
)
(EntmakePline ls)
(command "rotate3d" (entlast) ""(list(car p1)(cadr p1)) (list(car p2)(cadr p2)) 90 "")
)
(defun EntmakePline (lst / pt)
(entmake (append (list '(0 . "LWPOLYLINE")
'(100 . "AcDbEntity")
'(100 . "AcDbPolyline")
(cons 90 (length lst))
'(70 . 1)
)
(mapcar '(lambda (pt) (cons 10 pt)) lst)
)
)
)

434939575 · 发表于 2016-11-22 15:15:17

这样的图形。

账号		自动登录	找回密码
密码			立即注册

[求助] 请教通过点表绘制z非零的多段线

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

评分

浏览过的版块