lisp 填充渐变色应该怎么做？

spp_wall

填充渐变色应该怎么写？

newer

填充普通的索引颜色 你是怎么写的？ 代码贴上来，帮你改改。

spp_wall

newer 发表于 2016-11-25 09:44

(defun C:kx-TC-zylh (/ ss1 zhbl s1)
  (setvar "cmdecho" 0)  ;不回现操作过程
  (setvar "measurement" 1)     ;设置公制单位
  (setvar "hpassoc" 1)     ;设置填充图案关联

        ;;;这部分:确定是否建立新图层
  (if (tblsearch "layer" "KX-TC-中央绿化") ""
                (command "-layer" "new" "KX-TC-中央绿化" "color" "71" "KX-TC-中央绿化" "")
        );if




        ;;;这部分填充对象或拾取内部点填充
  (princ "\n请选择填充对象：(***跳过则为拾取内部点填充）")
  (if (setq s1 (ssget))
                (progn
                        (command "-bhatch" "s" s1 "" "p" "SOLID"  "")
                );progn
                (progn
                        (princ "\n请拾取填充内部点：")
                        (command "bhatch" pause pause)
                );progn
        );if
  (command "change" (entlast) "" "P" "la" "KX-TC-中央绿化" "");确定图层
   (setvar "hpassoc" 0)
  (princ)
) ;over defun

newer

spp_wall 发表于 2016-11-25 10:40

既然你用了CHPROP命令修改，那就按照命令的要求给参数就行了，下面是命令修改颜色（真彩色）的过程

CHPROP
选择对象: l
找到 1 个
选择对象:
输入要更改的特性 [颜色(C)/图层(LA)/线型(LT)/线型比例(S)/线宽(LW)/厚度(T)/透明度(TR)/材质(M)/注释性(A)]: c
新颜色 [真彩色(T)/配色系统(CO)] <BYLAYER>: t
红,绿,蓝: 220,22,1
输入要更改的特性 [颜色(C)/图层(LA)/线型(LT)/线型比例(S)/线宽(LW)/厚度(T)/透明度(TR)/材质(M)/注释性(A)]:

(defun c:tt ()
  (if (setq ss (ssget))
    (command ".chprop" ss "" "c" "t" "220,22,1" "")
  )
  (princ)
)

kqqt6236

N版好热心啊，赞一个。

marting

kqqt6236 发表于 2016-11-25 17:15

回答别人问题是最好的学习和巩固的方法。

spp_wall

newer 发表于 2016-11-25 12:21

这个是真彩色 我知道  但是渐变色好像没有得选吧！

newer

spp_wall 发表于 2016-11-25 17:22

不好意思，看花眼了，渐变色，命令就无能为力了，但可以用VLISP，试下下面代码,修改选择的HATCH变渐变色。

(defun c:tt ()
  (if (setq e (ssget  '((0 . "hatch"))))
    (progn
      (setq e         (ssname e 0)
            hatchobj         (vlax-ename->vla-object e)
            acad (vlax-get-acad-object)
      )
      (setq name (strcat "autocad.accmcolor."
                      (itoa (atoi
                              (getvar 'acadver)
                            )
                      )
              ))
      (setq col1 (vlax-create-object name))
      (setq col2 (vlax-create-object name))
      (if (/= "SOLID" (vlax-get-property hatchobj 'patternname))
        (vla-setpattern hatchobj achatchpatterntypepredefined "solid")
      )
      (vla-setrgb col1 255 0 0)
      (vla-setrgb col2 0 255 0)

      (vla-put-gradientcolor1 hatchobj col1)
      (vla-put-gradientcolor2 hatchobj col2)
      (vla-put-gradientname hatchobj "spherical")
      (entmod (subst (cons 450 1)(cons 450 0)(entget e)))
      (vlax-release-object col1)
      (vlax-release-object col2)
    )
  )
  (princ)
)

spp_wall

newer 发表于 2016-11-25 19:06

现在是改填充，能否直接填充渐变色呢？
  还有那个代码是改这个选项 现在的选项是第二排第一个

newer

spp_wall 发表于 2016-11-25 20:12

给你的是个例子代码，你想要什么，修改里面的参数。 其实你完全可以创建一个填充，然后用上面的代码改改修改成渐变色，都是相通的。

直接创建渐变色填充，可以去看看ACTIVEX 帮助手册里面的例子代码，帮助文件是很好的学习材料，下面摘自帮助文件。

颜色修改里面 setrgb后面的值，类型修改patternName，下面代码是运行在R19版本的CAD，你可以参照上面的我给你的例子，做成适合任意不版本的。

(vl-load-com)
(defun c:Example_GradientColor2()
    ;; This example changes the value of the GradientColor2 property.
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))    
    
    ;; Define the hatch
    (setq patternName "CYLINDER")
    (setq patternType acPreDefinedGradient)
    (setq bAssociativity :vlax-true)
    
    ;; Create the associative Hatch object in model space
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq hatchObj (vla-AddHatch modelSpace patternType patternName bAssociativity acGradientObject))

    (setq col1 (vlax-create-object "AutoCAD.AcCmColor.19"))
    (setq col2 (vlax-create-object "AutoCAD.AcCmColor.19"))
    (setq newColor (vlax-create-object "AutoCAD.AcCmColor.19"))

    (vla-SetRGB col1 255 0 0)
    (vla-SetRGB col2 0 255 0)
    (vla-SetRGB newColor 0 100 0)

    (vla-put-GradientColor1 hatchObj col1)
    (vla-put-GradientColor2 hatchObj col2)
    
    ;; Create the outer boundary for the hatch (a circle)
    (setq center (vlax-3d-point 3 3 0)
          radius 1)
    (setq circle (vla-AddCircle modelSpace center radius))

    (setq outerLoop (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (vlax-safearray-put-element outerLoop 0 circle)
    
    ;; Append the outerboundary to the hatch object, and display the hatch
    (vla-AppendOuterLoop hatchObj outerLoop)
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    (alert (strcat "Initial value of GradientColor2 is :"
                   "\nred = " (itoa (vla-get-Red (vla-get-GradientColor2 hatchObj)))
                   "\ngreen = " (itoa (vla-get-Green (vla-get-GradientColor2 hatchObj)))
                   "\nblue = " (itoa (vla-get-Blue (vla-get-GradientColor2 hatchObj)))))

    (vla-put-GradientColor2 hatchObj newColor)
    (alert (strcat "New value of GradientColor2 is :"
                   "\nred = " (itoa (vla-get-Red (vla-get-GradientColor2 hatchObj)))
                   "\ngreen = " (itoa (vla-get-Green (vla-get-GradientColor2 hatchObj)))
                   "\nblue = " (itoa (vla-get-Blue (vla-get-GradientColor2 hatchObj)))))

    (vlax-release-object col1)
    (vlax-release-object col2)
    (vlax-release-object newColor)
)

aeo

vla-Evaluate 什么意思？

我来小顶一下