MPolygon转换成LWPOLYLINE的代码

newer

(defun c:mp2pL (/ L LL LST P V)
  ;; by ElpanovEvgeniy
  ;; convert MPolygon to Lwpolyline
  ;; version 0.2
  ;; 2012.07.11
  ;; mailto: [email]elpanov@gmail.com[/email]
  ;; web: elpanov.com
  (if (setq v (ssget "_x" '((0 . "MPOLYGON"))))
    (foreach e (mapcar (function cadr) (ssnamex v))
      ;;(setq e(car(entsel)))
      (setq e        (entget e)
            v        (cons
                  0
                  (mapcar (function -) (cdr (assoc 11 e)) (cdr (assoc 10 e)))
                )
            l        (vl-remove nil
                           (list '(0 . "LWPOLYLINE")
                                 '(100 . "AcDbEntity")
                                 (assoc 67 e)
                                 (assoc 410 e)
                                 (assoc 8 e)
                                 (if (assoc 63 e)
                                   (cons 62 (cdr (assoc 63 e)))
                                 )
                                 (if (assoc 421 e)
                                   (cons 420 (cdr (assoc 421 e)))
                                 )
                                 '(100 . "AcDbPolyline")
                           )
                )
            lst        e
            ll        nil
      )
      (defun f (l i)
        (if (> i 0)
          (cons (mapcar (function +) (car l) v) (f (cdr l) (1- i)))
        )
      )
      (while (setq lst (member (assoc 93 (cdr lst)) (cdr lst)))
        (setq p         (f (cdr lst) (cdar lst))
              ll (append ll
                         (list '(92 . 7) '(72 . 0) '(73 . 1) (car lst))
                         p
                         '((97 . 0))
                 )
        )
        (entmakex
          (vl-remove nil
                     (append l
                             (list (cons 90 (cdar lst)) '(70 . 1))
                             p
                             (list (assoc 210 e))
                     )
          )
        )
      )
      (entmakex        (vl-remove nil
                           (append (list '(0 . "HATCH")
                                         '(100 . "AcDbEntity")
                                         (assoc 410 l)
                                         (assoc 8 l)
                                         (assoc 62 l)
                                         (assoc 420 l)
                                         '(100 . "AcDbHatch")
                                         (assoc 10 e)
                                         (assoc 210 e)
                                         '(2 . "SOLID")
                                         (assoc 70 e)
                                         (assoc 71 e)
                                         (assoc 91 e)
                                   )
                                   ll
                                   (list '(75 . 0) '(76 . 1) '(47 . 1.)
                                         '(98 . 2) '(10 0. 0. 0.0) '(10 0. 0. 0.0)
                                         '(450 . 0) '(451 . 0) '(460 . 0.0)
                                         '(461 . 0.0) '(452 . 0) '(462 . 0.0)
                                         '(453 . 2) '(463 . 0.0) '(63 . 256)
                                         '(463 . 1.0) '(63 . 256) '(470 . "LINEAR"))
                           )
                )
      )
    )
  )
  (princ)
)

qqqincccken

谢谢提供,试用一下!!

newer

下面是用XDRX API写的

(defun c:XDTB_MP2PL ( / bulges e el i loop numloops pl ss verts x)
  (defun _makeloop (el / i)
    (setq verts (car el)
          bulges (last el)
    )
    (setq pl (xdrx_polyline_make verts t))
    (setq i -1)
    (mapcar
      '(lambda (x)
         (xdrx_setpropertyvalue pl "BulgeAt" (list (setq i (1+ i))
                                                   x
                                             )
         )
       )
      bulges
    )
    pl
  )
  (defun _convert (e)
    (setq numloops (xdrx_getpropertyvalue e "NumMPolygonLoops"))
    (setq i 0)
    (repeat numloops
      (setq loop (xdrx_getpropertyvalue e "MPolygonLoopAt" i)
            i (1+ i)
      )
      (_makeloop loop)
      (xdrx_entity_matchprop e (entlast))
    )
    (xdrx_entity_delete e)
  )
  (xdrx_initssget "\n选取要转化的MPolygon实体<全选>:")
  (if (or
        (setq ss (xdrx_ssget '((0 . "MPOLYGON"))))
        (setq ss (ssget "x" '((0 . "MPOLYGON"))))
      )
    (progn
      (xdrx_begin)
      (mapcar
        '(lambda (x)
           (_convert x)
         )
        (xdrx_pickset->ents ss)
      )
      (xdrx_prompt "\n成功转换了" (sslength ss)
                   "个MPolygon实体到Lwpolyline."
      )
      (xdrx_end)
    )
  )
  (princ)
)

小冬冬2016

学习，膜拜

sicky111

啥也不说了，感谢楼主分享哇！

WhoCanSay

基本上没有用过三维图，MPOLYGON是什么命令生成的呀？

newer

WhoCanSay 发表于 2017-2-6 09:07

MPOLYGON不是三维实体，是AUTOCAD MAP里面的对象，构建形状拓扑的。

看看下面几个帖子的介绍

http://bbs.xdcad.net/thread-707028-1-1.html

http://bbs.xdcad.net/thread-707034-1-1.html

在AUTOCAD里面没有命令能生成MPOLYGON实体。你可以用API生成MPOLYGON后，ENTGET下实体信息，试试看能用ENTMAKE创建不。

iLisp

这些实体一般用 Explode 就可以了，Explode 后不保留Hatch

iLisp

Polygon 多边形，是一种面的描述，Google 地图、Gis 软件上常用， M 可能代表 Autodesk Map 中的 Map 吧

小冬冬2016

学习了！！！！！