如何用entmake创建注释性文本样式？

qindong668

在用entmake函数创建文本样式时，如何创建注释性文本样式？
;用法：(EntMakeTextStyle 样式名 样式高度 宽度因子 字体名 大字体名)
;系统TrueType字体如：黑体.ttf
;示例：(EntMakeTextStyle "样式测试" 6 1 "黑体.ttf" "hzjs-1.shx")
(defun EntMakeTextStyle (tStyleName tStyleHeight tStyleWeight tFontName tBigFontName)
  (entmakeX
    (list
      '(0 . "STYLE")
      '(100 . "AcDbSymbolTableRecord")
      '(100 . "AcDbTextStyleTableRecord")
      (cons 2 tStyleName)
      '(70 . 0)
      (cons 40 tStyleHeight)
      (cons 41 tStyleWeight)
      (cons 3  tFontName)
      (cons 4  tBigFontName)
    )
  )
)

以上函数创建的文本样式是这样的：


如何创建“注释性”选中的文本样式？

marting

你可以对比下啊，创建好注释样式后，entget下，和没有注释样式的entget数据对比下，你看看差别是什么，把没有的那个放到你的entmake里面就行了。

qindong668

早试过了，用entget提取不出来参数！创建样式后，用style将“注释性”选中，再用entget提取，读出来的与之前的一模一样，也就是这个“注释性”无法用entget读出来！

marting

qindong668 发表于 2017-5-8 20:47

误导了，不是entget数据的组码的，应该用 entmake 不出来。

用  (command "style" ....) 设置注释性吧

qindong668

(command "style" ....) 当然可以，我的问题是用entmake!

marting

qindong668 发表于 2017-5-8 21:07

研究了下数据格式，添加注释性后，数据保存在样式对象的扩展实体数据里面

命令: (entget a '("*"))
((-1 . <图元名: -24c378>) (0 . "STYLE") (330 . <图元名: -24c3e8>) (5 . "11") (100 .
"AcDbSymbolTableRecord") (100 . "AcDbTextStyleTableRecord") (2 . "Standard")
(70 . 0) (40 . 0.0) (41 . 1.0) (50 . 0.0) (71 . 0) (42 . 2.5) (3 . "txt.shx")
(4 . "gbcbig.shx") (-3 ("AcadAnnotative" (1000 . "AnnotativeData") (1002 . "{")
(1070 . 1) (1070 . 1) (1002 . "}")) ("AcadAnnoPO" (1070 . 1))))



你试试按照这个格式entmake 下。

qindong668

marting 发表于 2017-5-8 21:50

正解，高手，谢谢！