咨询个关于属性的问题

lisp_beginner · 发表于 2017-8-30 13:21:04

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

如果一个块有多个属性，那怎么能把INSERT的属性实体和块定义里面的属性定义联系起来呢？就是怎么对应上，我发现属性定义和属性实体entget数据里面都有TAG标签，我试着用这个对应，如果TAG不同还可以，但我发现这个TAG是可以重复的，一个块定义里面属性定义TAG可以都相同，那这种情况怎么去对应呢？

WhoCanSay · 发表于 2017-8-30 13:42:48

可能考虑相互位置关系，或者出现的顺序来考虑。

xinxirong · 发表于 2017-8-30 17:28:35

按顺序吧，既然原作者用相同的TAG就不是给电脑识别的。所以就算是按位置、按顺序都有人为改过的可能，当然最好是AI识别，人脑怎样识别，电脑就怎样识别。

marting · 发表于 2017-8-30 18:17:22

确实如上面朋友说的，可以用生成的顺序来配对他们。属性定义时候属性的生成的顺序，也是图块插入时候属性实体的生成顺序。
下面代码，可以把他们配对起来。

(defun c:tt ()
(defun _getattlistpair (e / el al lst _getblkattlist _getattlist) ;获得属性实体和属性定义对
(defun _getblkattlist (e / blkname blk al)
(setq blkname (cdr (assoc 2 (entget e))))
(setq blk (tblsearch "block" blkname))
(setq e (cdr (assoc -2 blk)))
(while (setq e (entnext e))
(if (= (cdr (assoc 0 (entget e))) "ATTDEF")
(setq al (cons e al))
)
)
(setq al (reverse al))
) ;
(defun _getattlist (e1 / el)
(while (and (setq e1 (entnext e1))
(/= (cdr (assoc 0 (entget e1))) "SEQEND")
)
(setq el (cons e1 el))
)
(setq el (reverse el))
)
(setq el (_getattlist e))
(setq al (_getblkattlist e))
(setq lst (mapcar 'list el al))
)
;main
(if (setq e (car (entsel)))
(progn (setq lst (_getattlistpair e)))
)
)

(defun c:tt () 
  (defun _getattlistpair (e / el al lst _getblkattlist _getattlist)        ;获得属性实体和属性定义对 
    (defun _getblkattlist (e / blkname blk al) 
      (setq blkname (cdr (assoc 2 (entget e)))) 
      (setq blk (tblsearch "block" blkname)) 
      (setq e (cdr (assoc -2 blk))) 
      (while (setq e (entnext e)) 
        (if (= (cdr (assoc 0 (entget e))) "ATTDEF") 
          (setq al (cons e al)) 
        ) 
      ) 
      (setq al (reverse al)) 
    )                                        ; 
    (defun _getattlist (e1 / el) 
      (while (and (setq e1 (entnext e1)) 
                  (/= (cdr (assoc 0 (entget e1))) "SEQEND") 
             ) 
        (setq el (cons e1 el)) 
      ) 
      (setq el (reverse el)) 
    ) 
    (setq el (_getattlist e)) 
    (setq al (_getblkattlist e)) 
    (setq lst (mapcar 'list el al)) 
  ) 
  ;main 
  (if (setq e (car (entsel))) 
    (progn (setq lst (_getattlistpair e))) 
  ) 
)

命令: tt
选择对象: ((<图元名: -225b88> <图元名: -225ba8>) (<图元名: -225b80> <图元名: -225ba0>))

marting · 发表于 2017-8-30 19:56:28

VLA代码

(defun c:tt ()
(if (setq e (car (entsel)))
(progn
(setq obj (vlax-ename->vla-object e))
(setq cdoc (vla-get-activedocument (vlax-get-acad-object)))
(setq atts (vla-GetAttributes obj)
atts (vlax-safearray->list (vlax-variant-value atts))
blk (tblobjname "block" (vla-get-name obj))
blk (vlax-ename->vla-object blk)
owner (vla-get-ownerid blk)
blk (vla-objectidtoobject cdoc owner)
)
(setq ol nil)
(vlax-for item blk
(if (= (vla-get-objectname item) "AcDbAttributeDefinition")
(setq ol (cons item ol))
)
)
(mapcar
'(lambda (x y)
(list (vlax-vla-object->ename x) (vlax-vla-object->ename y))
)
atts
ol
)
)
)
)

(defun c:tt () 
  (if (setq e (car (entsel))) 
    (progn 
      (setq obj (vlax-ename->vla-object e)) 
      (setq cdoc (vla-get-activedocument (vlax-get-acad-object))) 
      (setq atts  (vla-GetAttributes obj) 
            atts  (vlax-safearray->list (vlax-variant-value atts)) 
            blk          (tblobjname "block" (vla-get-name obj)) 
            blk          (vlax-ename->vla-object blk) 
            owner (vla-get-ownerid blk) 
            blk          (vla-objectidtoobject cdoc owner) 
      ) 
      (setq ol nil) 
      (vlax-for        item blk 
        (if (= (vla-get-objectname item) "AcDbAttributeDefinition") 
          (setq ol (cons item ol)) 
        ) 
      ) 
      (mapcar 
        '(lambda (x y) 
           (list (vlax-vla-object->ename x) (vlax-vla-object->ename y)) 
         ) 
        atts 
        ol 
      ) 
    ) 
  ) 
)

ll_j · 发表于 2017-8-30 20:23:45

是不是用组码5更保险一点？

marting · 发表于 2017-8-30 20:52:09

ll_j 发表于 2017-8-30 20:23

看在什么地方用了，如果就在本图里面操作，实体名就够了，如果要关闭图，以后打开还用，那么就用组码5，然后保存的扩展记录或者扩展词典里面。

eachy · 发表于 2017-8-30 21:07:55

不如先修改 TagString ，起个有意义的标签，然后什么时候处理都方便了

账号		自动登录	找回密码
密码			立即注册

[求助] 咨询个关于属性的问题

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。