关于捕捉选项经常自动关闭的问题，到底是什么原因？

再见熊猫衣服 · 发表于 2018-12-15 17:31:03

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

关于捕捉选项经常自动关闭的问题，到底是什么原因？
我使用CAD的时候，经常出现一个问题：
在捕捉选项，勾选了要捕捉的内容。
但是，过一会儿这些勾选的选项就取消勾选了。
QQ截图20181215172259.png

一开始是这样的，

但是，经常过了一会儿就变成这样了。
——————
我自己初步猜测，可能和加载的插件有关系。因为我没有安装插件之前，一直都正常的，
安装和运行一些插件后，就会开始出现这样的问题了。但是具体是哪些插件，我也不知道。
这个问题已经困扰我两年了，
1，以前我用Acad的时候，就会出现，现在用浩辰CAD，也会出现这样的问题。
2，这个问题是偶发的，发生概率约为30%，不是必然发生。
————
请问，这可能是什么原因引起的？
如何解决？

marting · 发表于 2018-12-15 19:04:48

肯定是某个插件设置了捕捉，而退出时候没有恢复

解决，就要写反应器，监视，没恢复，强制恢复

marting · 发表于 2018-12-15 19:32:20

本帖最后由 marting 于 2018-12-15 20:36 编辑

执行下TT
以后除了调用OSNAP命令外，其他所有命令结束后，强制恢复你用OSNAP设置的捕捉值

(defun c:tt () ((lambda ()
(vl-load-com)
(foreach rtr (cdar (vlr-reactors :VLR-Command-Reactor))
(if (= "#xd-command-monitor-reactor" (vlr-data rtr))
(vlr-remove rtr)
)
)
(vlr-set-notification
(vlr-command-reactor
"#xd-command-monitor-reactor"
'((:VLR-commandEnded . #xd-command-end-callback)
)
)
'active-document-only
)
(foreach rtr (cdar (vlr-reactors :vlr-lisp-reactor))
(if (= "#xd-lisp-monitor-reactor" (vlr-data rtr))
(vlr-remove rtr)
)
)
(vlr-set-notification
(vlr-lisp-reactor
"#xd-lisp-monitor-reactor"
'((:VLR-lispEnded . #xd-lisp-end-callback)
(:VLR-lispWillStart . #xd-lisp-start-callback)
)
)
'active-document-only
)
(setq #xd-var-global-osmode (getvar "osmode"))
(princ)
)
)
)
(defun #xd-command-end-callback (obj arglst)
(setq name (car arglst))
(cond ((= name "OSNAP")
(setq #xd-var-global-osmode (getvar "osmode"))
)
(t
(setvar "osmode" #xd-var-global-osmode)
)
)
(princ)
)
(defun #xd-lisp-end-callback (obj arglst)
(if #xd-var-global-lispcmdname
(progn (setvar "osmode" #xd-var-global-osmode)
(setq #xd-var-global-lispcmdname nil)
)
)
(princ)
)
(defun #xd-lisp-start-callback (obj arglst)
(setq name (car arglst))
(if (= (substr name 2 2) "C:")
(progn (setq #xd-var-global-lispcmdname name))
)
(princ)
)

(defun c:tt ()  ((lambda () 
     (vl-load-com) 
     (foreach rtr (cdar (vlr-reactors :VLR-Command-Reactor)) 
       (if (= "#xd-command-monitor-reactor" (vlr-data rtr)) 
         (vlr-remove rtr) 
       ) 
     ) 
     (vlr-set-notification 
       (vlr-command-reactor 
         "#xd-command-monitor-reactor" 
         '((:VLR-commandEnded . #xd-command-end-callback) 
          ) 
       ) 
       'active-document-only 
     ) 
     (foreach rtr (cdar (vlr-reactors :vlr-lisp-reactor)) 
       (if (= "#xd-lisp-monitor-reactor" (vlr-data rtr)) 
         (vlr-remove rtr) 
       ) 
     ) 
     (vlr-set-notification 
       (vlr-lisp-reactor 
         "#xd-lisp-monitor-reactor" 
         '((:VLR-lispEnded . #xd-lisp-end-callback) 
           (:VLR-lispWillStart . #xd-lisp-start-callback) 
          ) 
       ) 
       'active-document-only 
     ) 
     (setq #xd-var-global-osmode (getvar "osmode")) 
     (princ) 
   ) 
  ) 
) 
(defun #xd-command-end-callback        (obj arglst) 
  (setq name (car arglst)) 
  (cond        ((= name "OSNAP") 
         (setq #xd-var-global-osmode (getvar "osmode")) 
        ) 
        (t 
         (setvar "osmode" #xd-var-global-osmode) 
        ) 
  ) 
  (princ) 
) 
(defun #xd-lisp-end-callback (obj arglst) 
  (if #xd-var-global-lispcmdname 
    (progn (setvar "osmode" #xd-var-global-osmode) 
           (setq #xd-var-global-lispcmdname nil) 
    ) 
  ) 
  (princ) 
) 
(defun #xd-lisp-start-callback (obj arglst) 
  (setq name (car arglst)) 
  (if (= (substr name 2 2) "C:") 
    (progn (setq #xd-var-global-lispcmdname name)) 
  ) 
  (princ) 
)

wzg356 · 发表于 2018-12-15 22:41:46

使用的查件改变了捕捉最后没恢复，或是查件运行中途退出没恢复等等

2767836360 · 发表于 2018-12-16 06:35:04

谢谢分享谢谢分享

konglong604 · 发表于 2018-12-16 10:27:11

有的外挂程序你执行到一半，按ESC退出，还没来得及恢复对象捕捉的设置。

再见熊猫衣服 · 发表于 2018-12-16 10:33:30

marting 发表于 2018-12-15 19:32
执行下TT
以后除了调用OSNAP命令外，其他所有命令结束后，强制恢复你用OSNAP设置的捕捉值

很高级的样子，我马上测试一下，先谢谢了

再见熊猫衣服 · 发表于 2018-12-16 10:35:16

konglong604 发表于 2018-12-16 10:27
有的外挂程序你执行到一半，按ESC退出，还没来得及恢复对象捕捉的设置。

谢谢你提供的思路，应该是你说的这样。

再见熊猫衣服 · 发表于 2018-12-16 11:14:37

本帖最后由再见熊猫衣服于 2018-12-16 11:20 编辑

marting 发表于 2018-12-15 19:32
执行下TT
以后除了调用OSNAP命令外，其他所有命令结束后，强制恢复你用OSNAP设置的捕捉值

老师，这个好用是好用，但是有一个BUG。就是手动重新设置的捕捉选项，它也无法记住。（其实是相当于锁定了，手动也无法修改。）
这一点，能否再调整一下呢？还有一个小问题，能否让它加载后就自动生效，而不需要手动输入命令TT？

marting · 发表于 2018-12-16 11:31:15

再见熊猫衣服发表于 2018-12-16 11:14
老师，这个好用是好用，但是有一个BUG。就是手动重新设置的捕捉选项，它也无法记住。（其实是相当于锁定 ...

每次执行 OSNAP 命令，都会给你记住设置值
除非你执行的不是OSNAP命令

marting · 发表于 2018-12-16 11:33:53

本帖最后由 marting 于 2018-12-16 11:37 编辑

再见熊猫衣服发表于 2018-12-16 11:14
老师，这个好用是好用，但是有一个BUG。就是手动重新设置的捕捉选项，它也无法记住。（其实是相当于锁定 ...

你再把按F3时候执行的 DSETTINGS 命令名加进去

((= name "OSNAP") 改成 ( (or (= name "OSNAP")(= name "DSETTINGS"))

你通过什么命令修改捕捉，就把什么命令加到上面

再见熊猫衣服 · 发表于 2018-12-16 11:59:12

marting 发表于 2018-12-16 11:33
你再把按F3时候执行的 DSETTINGS 命令名加进去

((= name "OSNAP") 改成 ( (or (= name "OSNAP")(= na ...

请点击此处下载

请先注册会员后在进行下载

已注册会员，请先登录后下载

文件名称:自动锁定捕捉工具.zip
下载次数:4 文件大小:698 Bytes 售价:10D豆 [记录]
下载权限: 不限以上 [免费赚D豆]

我已经在本论坛，找到了可以自动加载，并保持状态的工具了。
万分感谢你，感谢晓东论坛，解除了困扰我多年的问题。。

Lisphk · 发表于 2018-12-16 12:29:48

再见熊猫衣服发表于 2018-12-16 11:59
我已经在本论坛，找到了可以自动加载，并保持状态的工具了。
万分感谢你，感谢晓东论坛，解除了困 ...

你这个还要打开LSP，修改想要的，不方便
上面那个代码，你自己执行设置捕捉命令时候，随时可以根据你的需要监视，更好

账号		自动登录	找回密码
密码			立即注册

关于捕捉选项经常自动关闭的问题，到底是什么原因？

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

点评

点评

点评

点评

点评