弓形质心

st788796 · 发表于 2022-7-9 18:49:35

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

本帖最后由 st788796 于 2022-7-9 18:51 编辑

参考：Calculate circular segment, calculator and formulas (redcrab-software.com)

弓形质心-1.gif

Autolisp 实现

(defun c:tt (/ ss e san ean r an sp ep mp pm pc a s dx p)
(princ "\n拾取 ARC ...")
(if (setq ss (ssget ":S" '((0 . "arc"))))
(progn (setq e (ssname ss 0)
el (entget e)
san (cdr (assoc 50 el))
ean (cdr (assoc 51 el))
r (cdr (assoc 40 el))
an (if (> san ean)
(+ ean (- (+ pi pi) san))
(- ean san)
)
sp (vlax-curve-getstartpoint e)
ep (vlax-curve-getendpoint e)
mp (mapcar '(lambda (a b) (/ (+ a b) 2)) sp ep)
pm (vlax-curve-getpointatparam
e
(/ (+ (vlax-curve-getstartparam e) (vlax-curve-getendparam e)) 2)
)
pc (cdr (assoc 10 el))
;;a (vlax-curve-getarea e)
a (* (/ (* r r) 2) (- an (sin an)))
s (distance sp ep)
dx (- (/ (expt s 3) (* 12 a)) (* r (cos (/ an 2))))
p (polar mp (angle mp pm) dx)
)
(vl-cmdf ".point" "_none" p)
)
)
(princ)
)

(defun c:tt (/ ss e san ean r an sp ep mp pm pc a s dx p) 
  (princ "\n拾取 ARC ...") 
  (if (setq ss (ssget ":S" '((0 . "arc")))) 
    (progn (setq e   (ssname ss 0) 
                 el  (entget e) 
                 san (cdr (assoc 50 el)) 
                 ean (cdr (assoc 51 el)) 
                 r   (cdr (assoc 40 el)) 
                 an  (if (> san ean) 
                       (+ ean (- (+ pi pi) san)) 
                       (- ean san) 
                     ) 
                 sp  (vlax-curve-getstartpoint e) 
                 ep  (vlax-curve-getendpoint e) 
                 mp  (mapcar '(lambda (a b) (/ (+ a b) 2)) sp ep) 
                 pm  (vlax-curve-getpointatparam 
                       e 
                       (/ (+ (vlax-curve-getstartparam e) (vlax-curve-getendparam e)) 2) 
                     ) 
                 pc  (cdr (assoc 10 el)) 
                 ;;a   (vlax-curve-getarea e) 
                 a   (* (/ (* r r) 2) (- an (sin an))) 
                 s   (distance sp ep) 
                 dx  (- (/ (expt s 3) (* 12 a)) (* r (cos (/ an 2)))) 
                 p   (polar mp (angle mp pm) dx) 
           ) 
           (vl-cmdf ".point" "_none" p) 
    ) 
  ) 
  (princ) 
)

用 Region 验证，完全重合！

Highflybird · 发表于 2022-7-9 19:40:14

在我以前的帖子里面，有纯公式求弓形的质心和面积：

;;;-------------------------------------------------------------
;;;Circular segment
;;;弓的质心求以及弓形的面积
;;;输入: C---圆心;Center
;;; R---半径;Radius
;;; A1--起始角;0 <= A1 <= 2*Pi Start Angle(Radian)
;;; A2--终止角;0 <= A2 <= 2*Pi End Angle(Radian)
;;; IsCW--是否顺时针
;;;输出: 列表: 第一项为质心，第二项为面积，第三项为弧长
;;;-------------------------------------------------------------
(defun CIR:Circular_Segment (C R A1 A2 IsCW / A k d S e)
(and isCW (setq A A2 A2 A1 A1 A))
(if (> A1 A2)
(setq A (- (+ pi pi A2) A1 ))
(setq A (- A2 A1))
)
(setq k (sin (* 0.5 A)))
(setq k (* 1.333333333333333333333 R k k k))
(setq e (- A (sin A)))
(setq S (* 0.5 R R e))
(and IsCW (setq S (- S))) ;如果顺时针，面积为负
(setq d (/ k e))
(if (> A1 A2) (setq d (- d))) ;这种情况下要反向
(list (polar C (* 0.5 (+ A1 A2)) d) S (* A R))
)

;;;------------------------------------------------------------- 
;;;Circular segment                                        
;;;弓的质心求以及弓形的面积                               
;;;输入: C---圆心;Center                                  
;;;      R---半径;Radius                                  
;;;      A1--起始角;0 <= A1 <= 2*Pi Start Angle(Radian)    
;;;      A2--终止角;0 <= A2 <= 2*Pi End Angle(Radian)      
;;;      IsCW--是否顺时针                                  
;;;输出: 列表: 第一项为质心，第二项为面积，第三项为弧长    
;;;------------------------------------------------------------- 
(defun CIR:Circular_Segment (C R A1 A2 IsCW / A k d S e) 
  (and isCW (setq A A2 A2 A1 A1 A)) 
  (if (> A1 A2) 
    (setq A (- (+ pi pi A2) A1 )) 
    (setq A (- A2 A1)) 
  ) 
  (setq k (sin (* 0.5 A))) 
  (setq k (* 1.333333333333333333333 R k k k)) 
  (setq e (- A (sin A))) 
  (setq S (* 0.5 R R e)) 
  (and IsCW (setq S (- S)))                               ;如果顺时针，面积为负 
  (setq d (/ k e)) 
  (if (> A1 A2) (setq d (- d)))                           ;这种情况下要反向 
  (list (polar C (* 0.5 (+ A1 A2)) d) S (* A R)) 
)

还有扇形的质心，面积等。

;;;-------------------------------------------------------------
;;;Circular sector
;;;扇形的质心，面积和周长
;;;输入: C---圆心;Center
;;; R---半径;Radius
;;; A1--起始角;0 <= A1 <= 2*Pi Start Angle(Radian)
;;; A2--终止角;0 <= A2 <= 2*Pi End Angle(Radian)
;;; IsCW--是否顺时针
;;;输出: 列表: 第一项为质心，第二项为面积，第三项为周长
;;;-------------------------------------------------------------
(defun CIR:Circular_Sector (C R A1 A2 IsCW / A d S L)
(and IsCW (setq A A2 A2 A1 A1 A))
(if (> A1 A2)
(setq A (- (+ pi pi A2) A1))
(setq A (- A2 A1))
)
(setq d (/ (* 4 R (sin (* 0.5 A))) 3 A))
(setq S (* 0.5 A R R))
(and IsCW (setq S (- S))) ;如果顺时针，面积为负
(setq L (* R (+ A 2))) ;周长
(if (> A1 A2) (setq d (- d))) ;这种情况下要反向
(list (polar C (* 0.5 (+ A1 A2)) d) S L)
)

;;;------------------------------------------------------------- 
;;;Circular sector                                        
;;;扇形的质心，面积和周长                                  
;;;输入: C---圆心;Center                                  
;;;      R---半径;Radius                                  
;;;      A1--起始角;0 <= A1 <= 2*Pi Start Angle(Radian)    
;;;      A2--终止角;0 <= A2 <= 2*Pi End Angle(Radian)      
;;;      IsCW--是否顺时针                                  
;;;输出: 列表: 第一项为质心，第二项为面积，第三项为周长    
;;;------------------------------------------------------------- 
(defun CIR:Circular_Sector (C R A1 A2 IsCW / A d S L) 
  (and IsCW (setq A A2 A2 A1 A1 A)) 
  (if (> A1 A2) 
    (setq A (- (+ pi pi A2) A1)) 
    (setq A (- A2 A1)) 
  ) 
  (setq d (/ (* 4 R (sin (* 0.5 A))) 3 A)) 
  (setq S (* 0.5 A R R))                                 
  (and IsCW (setq S (- S)))                               ;如果顺时针，面积为负 
  (setq L (* R (+ A 2)))                                  ;周长 
  (if (> A1 A2) (setq d (- d)))                           ;这种情况下要反向 
  (list (polar C (* 0.5 (+ A1 A2)) d) S L) 
)

st788796 · 发表于 2022-7-9 19:46:28

本帖最后由 st788796 于 2022-7-9 19:48 编辑

Highflybird 发表于 2022-7-9 19:40
在我以前的帖子里面，有纯公式求弓形的质心和面积：

扇形是三角形和弓形组合

三角形质心

(defun triangle-centroid (p1 p2 p3) (mapcar '(lambda (a b c) (/ (+ a b c) 3)) p1 p2 p3))

扇形质心，用弓形和三角形质心组合：两个质心连线，按面积分隔。
推广：LWPOLYLINE在质心算法

LXH刚开始 · 发表于 2022-7-9 20:02:57

不错，但论坛为什么总是无法进入。

hh_lj007 · 发表于 2022-7-11 09:07:53

感谢大神分享源码

qxlonmsn · 发表于 2022-7-12 08:04:50

Highflybird 发表于 2022-7-9 19:40
在我以前的帖子里面，有纯公式求弓形的质心和面积：

厉害感谢大佬的代码

账号		自动登录	找回密码
密码			立即注册

[原创] 弓形质心

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

点评