[求助]：得到更详细的DIMSTYLE列表

心梦相随 · 发表于 2003-8-26 20:33:39

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

tblsearch dimstyle只能得到一个简短的列表，有什么办法得到某个指定标注样式的列表，包含<entities...>,谢谢

eachy · 发表于 2003-8-26 21:20:17

你想在列表中得到什么？

心梦相随 · 发表于 2003-8-26 21:26:10

包含<实体名称Entities name>的列表,谢谢.

e2002 · 发表于 2003-8-26 22:11:55

你是不是想获得某个DimStyle的详细数据啊?

eachy · 发表于 2003-8-26 22:22:56

命令: (tblsearch "dimstyle" "iso-25")
((0 . "DIMSTYLE") (2 . "ISO-25") (70 . 0) (3 . "") (4 . "") (5 . "") (6 . "")
(7 . "") (40 . 1.0) (41 . 2.5) (42 . 0.625) (43 . 3.75) (44 . 1.25) (45 . 0.0)
(46 . 0.0) (47 . 0.0) (48 . 0.0) (140 . 2.5) (141 . 2.5) (142 . 0.0) (143 .
0.0393701) (144 . 1.0) (145 . 0.0) (146 . 1.0) (147 . 0.625) (71 . 0) (72 . 0)
(73 . 0) (74 . 0) (75 . 0) (76 . 0) (77 . 1) (78 . 8) (170 . 0) (171 . 3) (172
. 1) (173 . 0) (174 . 0) (175 . 0) (176 . 0) (177 . 0) (178 . 0) (270 . 2) (271
. 2) (272 . 2) (273 . 2) (274 . 3) (340 . <图元名: 40090c88>) (275 . 0) (280 .
0) (281 . 0) (282 . 0) (283 . 0) (284 . 8) (285 . 0) (286 . 0) (287 . 3) (288 .
0))

2s6j8 · 发表于 2003-8-26 23:21:58

最初由 eachy 发布
[B]命令: (tblsearch "dimstyle" "iso-25")
((0 . "DIMSTYLE") (2 . "ISO-25") (70 . 0) (3 . "") (4 . "") (5 . "") (6 . "")
(7 . "") (40 . 1.0) (41 . 2.5) (42 . 0.625) (43 . 3.75) (44 . 1.25) (45 . 0.0)
... [/B]

要是能再注释一下就更好。

eachy · 发表于 2003-8-26 23:29:43

最初由 2s6j8 发布
[B][QUOTE]最初由 eachy 发布
[B]命令: (tblsearch "dimstyle" "iso-25")
((0 . "DIMSTYLE") (2 . "ISO-25") (70 . 0) (3 . "") (4 . "") (5 . "") (6 . "")
(7 . "") (40 . 1.0) (41 . 2.5) (42 . 0.625) (... [/B]

你不看CAD联机帮助中的DXF组码部分？

2s6j8 · 发表于 2003-8-27 23:16:27

老记不住，要对着看。

橄榄滋味 · 发表于 2006-1-9 11:50:02

请问斑竹，如何用LISP修改尺寸样式的参数呢？用TBLOBJNAME可以得到尺寸样式的实体名，却没有我要修改的参数。我的目的就是修改当前图纸现有任何一个尺寸样式名（如STANDARD）的箭头大小，全局比例，文字样式等等

狂刀 · 发表于 2006-1-9 12:07:44

for example:
(entget(tblobjname "dimstyle" "dimn"))

Dallas_whu · 发表于 2006-1-9 15:58:12

以前写的,贡献给大家吧!
[PHP]

;;建立标准样式,分号后为对应系统变量及注释
(DEFUN C:DSTY (/    DIMSTY    DIMNAMESTR  BLTEXT
         DIMNAME    BLNUM    CHK_DIMSTYLE
         DIMSET    BLOCK    DIMPROMPT
      )
  (PRINC "\n按建筑&结构要求设置标准样式!标注样式的前缀为\"BL_1-\":")
  (IF (NOT (TBLSEARCH "STYLE" "DIM_STYLE")) ;建立标准的文字样式
(ENTMAKE
   (LIST
'(0 . "STYLE") ;对象名称
'(100 . "AcDbSymbolTableRecord")
'(100
   .
   "AcDbTextStyleTableRecord"
   ) ;子类标记
'(2 . "DIM_STYLE") ;字体样式名
'(70 . 0) ;标注位码
'(40 . 0.0) ;文字高度
'(41 . 0.8) ;宽度系数
'(50 . 0.0) ;字斜角
'(71 . 0) ;文字生成标注位码2＝反向，4＝颠倒
'(3 . "TSSDENG.shx") ;西文字体名
'(4 . "HZTXT.shx") ;中文字体名
   ) ;_ 结束LIST
) ;_ 结束ENTMAKE
  )
  (SETQ DIMNAMESTR "BL_1-")
  (SETQ BLTEXT (GETSTRING "\n请输入你要建立的标注比例 1: "))
  (IF (/= BLTEXT "")
(PROGN ;
   (SETQ DIMNAME (STRCAT DIMNAMESTR BLTEXT))
   (SETQ BLNUM (ATOI BLTEXT))
   (SETQ CHK_DIMSTYLE (TBLSEARCH "DIMSTYLE" DIMNAME))
   (IF (= CHK_DIMSTYLE NIL)
(PROGN
   (SETQ DIMSET
   (LIST
   '(0 . "DIMSTYLE")
   '(100
      .
      "AcDbSymbolTableRecord"
      )
   '(100
      .
      "AcDbDimStyleTableRecord"
      )
   (CONS 2 DIMNAME) ;标注样式名
   '(3 . "") ;"DIMPOST" 指定标注测量值的文字前缀或后缀（或者两者都指定）
   '(4 . "") ;"DIMAPOST" 为所有标注类型（角度标注除外）的换算标注测量值指定文字前缀或后缀（或两者都指定）。
   '(40 . 1) ;"DIMSCALE" 为标注变量（指定尺寸、距离或偏移量）设置全局比例因子。
   '(41 . 1.0) ;"DIMASZ" 控制尺寸线、引线箭头的大小
   '(42 . 3.0) ;"DIMEXO" 指定尺寸界线偏移原点的距离。
;'(43 . 3.0);"DIMDLI" 控制基线标注中尺寸线的间距。
   '(44 . 1.0) ;"DIMEXE"指定尺寸界线超出尺寸线的距离
   '(45 . 0.0) ;"DIMRND" 将所有标注距离舍入到指定值
   '(46 . 0.0) ;"DIMDLE" 当使用小斜线代替箭头进行标注时，设置尺寸线超出尺寸界线的距离
;'(47 . 0.0);"DIMTP" 在 DIMTOL 或 DIMLIM 系统变量设置为开的情况下，为标注文字设置最大（上）偏差。
;'(48 . 0.0);"DIMTM" 为标注文字设置最小（下）偏差
   '(70 . 32) ;"DIMTOL" 将公差附在标注文字之后
   '(71 . 0) ;"DIMLIM" 将极限尺寸生成为默认文字。将 DIMLIM 设置为“开”将关闭 DIMTOL 系统变量。
   '(73 . 0) ;"DIMTIH" 控制所有标注类型（坐标标注除外）的标注文字在尺寸界线内的位置
   '(74 . 0) ;"DIMTOH" 控制标注文字在尺寸界线外的位置
   '(75 . 0) ;"DIMSE1" 控制是否禁止显示第一条尺寸界线
   '(76 . 0) ;"DIMSE2" 控制是否禁止显示第二条尺寸界线
   '(77 . 1) ;"DIMTAD" 控制文字相对尺寸线的垂直位置
   '(78 . 0) ;"DIMZIN" 控制是否对主单位值作消零处理
   '(79 . 0) ;"DIMAZIN" 对角度标注作消零处理
   '(140 . 3.0) ;"DIMTXT" 指定标注文字的高度，除非当前文字样式具有固定的高度
   '(141 . 0.1) ;"DIMCEN" 圆或圆弧的圆心标记和中心线图形
   '(142 . 0.0) ;"DIMTSZ" 指定线性标注、半径标注以及直径标注中替代箭头的小斜线尺寸
   '(143 . 25.4) ;"DIMALTF" 控制换算单位乘数
   (CONS 144 BLNUM) ;"DIMLFAC" 设置线性标注测量值的比例因子
   '(145 . 0.0) ;"DIMTVP" 控制尺寸线上方或下方标注文字的垂直位置
   '(146 . 1.0) ;"DIMTFAC" 按照 DIMTXT 系统变量的设置，相对于标注文字高度给分数值和公差值的文字高度指定比例因子
   '(147 . 1.0) ;"DIMGAP" 当尺寸线分成段以在两段之间放置标注文字时，设置标注文字周围的距离
   '(148 . 0.0) ;"DIMALTRND" 舍入换算标注单位
   '(170 . 0) ;"DIMALT" 控制标注中换算单位的显示
   '(171 . 2) ;"DIMALTD" 控制换算单位中小数位的位数
   '(172 . 1) ;"DIMTOFL" 控制是否将尺寸线绘制在尺寸界线之间（即使文字放置在尺寸界线之外）。
   '(173 . 0) ;"DIMSAH" 控制尺寸线箭头块的显示
   '(174 . 1) ;"DIMTIX" 在尺寸界线之间绘制文字
   '(175 . 0) ;"DIMSOXD" 控制是否允许尺寸线绘制到尺寸界线之外
   '(176 . 2) ;"DIMCLRD" 为尺寸线、箭头和标注引线指定颜色
   '(177 . 2) ;"DIMCLRE" 为尺寸界线指定颜色
   '(178 . 0) ;"DIMCLRT" 为标注文字指定颜色
   '(179 . 0) ;"DIMADEC" 控制角度标注的显示精确位数。
   '(271 . 0)
;;;<<<"DIMDEC" 设置标注主单位显示的小数位位数
   '
      (272 . 0) ;"DIMTDEC" 为标注主单位的公差值设置显示的小数位位数
   '(273 . 2) ;"DIMALTU" 为所有标注样式族（角度标注除外）换算单位设置单位格式
   '(274 . 2) ;"DIMALTTD" 设置标注换算单位公差值小数位的位数
   '(275 . 0) ;"DIMAUNIT" 设置角度标注的单位格式
   '(276 . 0) ;"DIMFRAC" 在 DIMLUNIT 系统变量设置为 4（建筑）或 5（分数）时设置分数格式
   '(277 . 2) ;"DIMLUNIT" 为所有标注类型（除角度标注外）设置单位制
   '(279 . 2) ;"DIMTMOVE" 设置标注文字的移动规则
   '(280 . 0) ;"DIMJUST" 控制标注文字的水平位置
   '(281 . 0) ;"DIMSD1" 控制是否禁止显示第一条尺寸线
   '(282 . 0) ;"DIMSD2" 控制是否禁止显示第二条尺寸线
   '(283 . 1) ;"DIMTOLJ" 设置公差值相对名词性标注文字的垂直对正方式
   '(284 . 0) ;"DIMTZIN" 控制是否对公差值作消零处理
   '(285 . 0) ;"DIMALTZ" 控制是否对换算单位标注值作消零处理
   '(286 . 0) ;"DIMALTTZ" 控制是否对公差值作消零处理
   '(288 . 0) ;"DIMUPT" 控制用户定位文字的选项
   '(289 . 3) ;"DIMATFIT" 当尺寸界线的空间不足以同时放下标注文字和箭头时，本系统变量将确定这两者的排列方式
   '(371 . -2) ;"DIMLWD"（线宽枚举值）指定尺寸线的线宽。其值是标准线宽。-3 BYLAYER -2 BYBLOCK
   '(372 . -2) ;"DIMLWE"（线宽枚举值）指定尺寸界线的线宽。其值是标准线宽。-3 BYLAYER -2 BYBLOCK
   ) ;
   )
   (SetQ DIMSTY (TblObjName "STYLE" "DIM_STYLE"))
   (SETVAR "DIMBLK" "_ARCHTICK") ;加载_ARCHTICK块
   (SetQ BLOCK
   (Cdr (Assoc 330 (EntGet (TblObjName "BLOCK" "_ARCHTICK"))))
   )
   (SetQ DIMSET
   (Append DIMSET (List (Cons 340 DIMSTY) (Cons 342 BLOCK)))
   )
   (EntMakeX DIMSET)
)
(PROGN
   (SETQ BLNUM (CDR (ASSOC 144 (ENTGET (TBLOBJNAME "DIMSTYLE" DIMNAME)))))
   (SETQ BLTEXT (RTOS BLNUM 2 1))
   (SETQ DIMPROMPT (STRCAT "标注样式\""
   DIMNAME
   "\"已经存在，"
   "全局比例为1:"
   BLTEXT
   "，"
   "请重新输入比例建立样式！"
   )
   )
   (ALERT DIMPROMPT)
)
   )
)
  )
  (COMMAND ".-DIMSTYLE" "R" DIMNAME)
  (PRINC)
)
[/PHP]

yshf · 发表于 2006-1-9 16:28:48

Dallas_whu :
请问在2000版中为何出以下问题:
Command: dsty
按建筑&结构要求设置标准样式!标注样式的前缀为"BL_1-":
请输入你要建立的标注比例 1: 50
; error: bad DXF group: (179 . 0)
Command: dsty
按建筑&结构要求设置标准样式!标注样式的前缀为"BL_1-":
请输入你要建立的标注比例 1: 50
; error: bad DXF group: (277 . 2)
Command: dsty
按建筑&结构要求设置标准样式!标注样式的前缀为"BL_1-":
请输入你要建立的标注比例 1: 50
; error: bad DXF group: (279 . 2)
而将

'(179 . 0) ;"DIMADEC" 控制角度标注的显示精确位数。
'(271 . 0) ;;;<<<"DIMDEC" 设置标注主单位显示的小数位位数
'(272 . 0) ;"DIMTDEC" 为标注主单位的公差值设置显示的小数位位数
'(273 . 2) ;"DIMALTU" 为所有标注样式族（角度标注除外）换算单位设置单位格式
'(274 . 2) ;"DIMALTTD" 设置标注换算单位公差值小数位的位数
'(275 . 0) ;"DIMAUNIT" 设置角度标注的单位格式
'(276 . 0) ;"DIMFRAC" 在 DIMLUNIT 系统变量设置为 4（建筑）或 5（分数）时设置分数格式
'(277 . 2) ;"DIMLUNIT" 为所有标注类型（除角度标注外）设置单位制
'(279 . 2) ;"DIMTMOVE" 设置标注文字的移动规则
'(280 . 0) ;"DIMJUST" 控制标注文字的水平位置

复制代码

改为

;'(179 . 0) ;"DIMADEC" 控制角度标注的显示精确位数。
'(271 . 0) ;;;<<<"DIMDEC" 设置标注主单位显示的小数位位数
'(272 . 0) ;"DIMTDEC" 为标注主单位的公差值设置显示的小数位位数
'(273 . 2) ;"DIMALTU" 为所有标注样式族（角度标注除外）换算单位设置单位格式
'(274 . 2) ;"DIMALTTD" 设置标注换算单位公差值小数位的位数
'(275 . 0) ;"DIMAUNIT" 设置角度标注的单位格式
'(276 . 0) ;"DIMFRAC" 在 DIMLUNIT 系统变量设置为 4（建筑）或 5（分数）时设置分数格式
;'(277 . 2) ;"DIMLUNIT" 为所有标注类型（除角度标注外）设置单位制
;'(279 . 2) ;"DIMTMOVE" 设置标注文字的移动规则
'(280 . 0) ;"DIMJUST" 控制标注文字的水平位置

复制代码

后不出问题?

Dallas_whu · 发表于 2006-1-9 17:40:21

不好意思,我现在用的是2004,没有在2000里面测试,可能是2000里面没对应特性设置吧.格式方面应该没有问题.

yshf · 发表于 2006-1-9 17:50:10

应该是的。

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：得到更详细的DIMSTYLE列表

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子