测测你们的包围盒函数代码...

XDSoft

很多朋友都有自己的“包围盒”代码，但很多只是能获得WCS下的，如果用户的UCS下画图并出图，那么这样的“包围盒”代码就是不能用的，大家贴贴代码，要你的包围盒函数能支持UCS。当然WCS下也要正常。

测试图见附件。

夜来风语声

[pcode=lisp,true](entmake
  (append
    (list '(0 . "LWPOLYLINE") '(100 . "AcDbEntity") '(100 . "AcDbPolyline")
          '(90 . 4) '(70 . 1) '(43 . 0.0) '(38 . 0.0) '(39 . 0.0) '(62 . 1))
    (
     (lambda (SS / XDIR ORG CP ANG N OBJ LL UR pl UL LR)
       (setq xdir (getvar 'ucsxdir)
             org  (getvar 'ucsorg)
             cp          (vlax-3d-point '(0.0 0.0 0.0))
             ang  (atan (cadr xdir) (car xdir))
       )
       (repeat (setq n (sslength ss))
         (setq
           obj (vlax-ename->vla-object (ssname ss (setq n (1- n))))
         )
         (vla-rotate obj cp (- ang))
         (vla-update obj)
         (vla-GetBoundingBox obj 'll 'ur) ;_ 计算包围盒
         (setq ll (vlax-safearray->list ll) ;_ 坐下角点
               ur (vlax-safearray->list ur) ;_ 右上角点
         )
         ;;_ 还原对象位置
         (vla-rotate obj cp ang)
         (setq pl (cons ll pl)
               pl (cons ur pl)
         )
       )
       (setq ll        (apply 'mapcar (cons 'min pl)) ;_ 坐下角点
             ur        (apply 'mapcar (cons 'max pl)) ;_ 右上角点
             ul        (list (car ll) (cadr ur) (caddr ll)) ;_ 左上角点
             lr        (list (car ur) (cadr ll) (caddr ll)) ;_ 右下角点
       )
       ;;返回UCS方向的WCS坐标
       (mapcar '(lambda (x) (cons 10 (mapcar '- (trans x 1 0) org)))
               (list ll ul ur lr)
       )
     )
      (ssget)
    )
  )
)[/pcode]

XDSoft

夜来风语声 发表于 2013-4-27 21:47

                               
登录/注册后可看大图

(entmake
  (append
    (list '(0 . "LWPOLYLINE") '(100 . "AcDbEntity") '(100 . "AcDbPolyline")

这大段，给整理出个函数吧，要返回四个脚点的，也通用。

梦断江南

ucs下求实体包围盒，可先用vla-GetUCSMatrix求ucs转换矩阵,进行transfrom变换后求box,
        用x#-1求逆矩阵,transfrom方法将box转换回ucs.参程序: x#ucsbox 函数.

XDSoft

梦断江南 发表于 2013-4-28 02:02

                               
登录/注册后可看大图

ucs下求实体包围盒，可先用vla-GetUCSMatrix求ucs转换矩阵,进行transfrom变换后求box,
        用x#-1求逆 ...

贴代码上来吧。

夜来风语声

XDSoft 发表于 2013-4-27 22:33

                               
登录/注册后可看大图

这大段，给整理出个函数吧，要返回四个脚点的，也通用。

[pcode=lisp,true](defun ucsbox (SS / XDIR ORG CP ANG N OBJ LL UR pl UL LR)
    (setq xdir (getvar 'ucsxdir)
          org  (getvar 'ucsorg)
          cp   (vlax-3d-point '(0.0 0.0 0.0))
          ang  (atan (cadr xdir) (car xdir))
          )
    (repeat (setq n (sslength ss))
      (setq
        obj (vlax-ename->vla-object (ssname ss (setq n (1- n))))
        )
      (vla-rotate obj cp (- ang))
      (vla-update obj)
      (vla-GetBoundingBox obj 'll 'ur) ;_ 计算包围盒
      (setq ll (vlax-safearray->list ll) ;_ 坐下角点
            ur (vlax-safearray->list ur) ;_ 右上角点
            )
      ;;_ 还原对象位置
      (vla-rotate obj cp ang)
      (setq pl (cons ll pl)
            pl (cons ur pl)
            )
      )
    (setq ll (apply 'mapcar (cons 'min pl)) ;_ 左下角点
          ur (apply 'mapcar (cons 'max pl)) ;_ 右上角点
          ul (list (car ll) (cadr ur) (caddr ll)) ;_ 左上角点
          lr (list (car ur) (cadr ll) (caddr ll)) ;_ 右下角点
          )
    ;;返回UCS方向的WCS坐标
    (mapcar '(lambda (x) (mapcar '- (trans x 1 0) org))
            (list ll ul ur lr)
            )
    )[/pcode]

userzhl

试试附件的文件，出错。。。

XDSoft

userzhl 发表于 2013-4-28 09:51

                               
登录/注册后可看大图

试试附件的文件，出错。。。

是什么意思？ 说上面哪个朋友的代码测试有错？

userzhl

附件是测试的DWG文件,用了“夜来风语声”求出的包围盒有误。

XDSoft

userzhl 发表于 2013-4-28 10:43

                               
登录/注册后可看大图

附件是测试的DWG文件,用了“夜来风语声”求出的包围盒有误。

在你机器上测试的包围盒，截取个图片贴论坛吧。

夜来风语声

userzhl 发表于 2013-4-28 10:43

                               
登录/注册后可看大图

附件是测试的DWG文件,用了“夜来风语声”求出的包围盒有误。

实体SPline用vla-GetBoundingBox计算的包围盒并不是其真正的包围盒！这个是CAD本身的问题！计算spline的真正包围盒可用拟合逼近法近似计算其包围盒！

Highflybird

下面是我的代码：
其实在UCS下最主要的是如何得到ucs的变换矩阵。
当然，对spline是有些问题的。不过如果要真正得到spline的，需要采用迭代或者其他方法。我已经发过这个情况的帖子。

请点击此处下载

查看状态：需购买或无权限

您的用户组是：游客

文件名称:UCSBOX20130428.LSP 
下载次数:79  文件大小:4.15 KB 
下载权限: 不限 以上  [免费赚D豆]

[pcode=lisp,true];;;-----------------------------------------------------------;;
;;;Highflybird  2008.03.22 海南    2013.04.28 修订于深圳      ;;
;;;-----------------------------------------------------------;;
;;;程序功能：画出选择集的包围盒，可适用于UCS下                ;;
;;;免责申明：本着开源的精神，此代码可以免费拷贝复制，但使用此 ;;
;;;          程序带来的一切责任由使用者这承担。               ;;
;;;程序用法：命令为Test,选择一个或多个，自动创建物体包围盒    ;;
;;;-----------------------------------------------------------;;
(defun C:Test (/ B DOC ENT I ISUCS LL LR UL UR MATRIX REVMAT OBJ  SEL pl)
  ;;先判断UCS是否与WCS相同。
  ;;如是UCS，得到UCS变换矩阵和到WCS的逆变换矩阵
  (if (zerop (getvar "WORLDUCS"))                                    ;UCS是否与WCS相同
    (setq IsUCS T                                                     ;设置标志位为true
          matrix (vlax-tmatrix (MAT:Trans 1 0))                 ;UCS的变换矩阵
          revMat (vlax-tmatrix (MAT:Trans 0 1))                 ;UCS的逆变换矩阵
    )
    (setq IsUCS nil)                                                  ;否则不予变换
  )
  (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)))
  ;;在UCS下先变换物体到WCS下，取得每个物体的包围框，
  ;;求出包围框集合的最小XY，最大XY，并用矩形框画出来
  ;;然后把物体变换回到UCS，并把矩形也变换回去
  (if (setq sel (ssget))                                        ;选择物体
    (progn
      (setq i 0)
      (vla-StartUndoMark doc)
      (repeat (sslength sel)
        (setq ent (ssname sel i))                               ;图元
        (setq obj (vlax-ename->vla-object ent))                 ;obj对象
        (and IsUCS (vla-TransformBy obj revMat))                      ;反变换到WCS
        (vla-GetBoundingBox obj 'll 'ur)                          ;得到包围框
        (setq ll (vlax-safearray->list ll))
        (setq ur (vlax-safearray->list ur))
        (setq pl (cons ll pl))                                       ;得到左下角点表
        (setq pl (cons ur pl))                                       ;得到右上角点表
        (and IsUCS (vla-TransformBy obj matrix))                      ;变换回到UCS
        (setq i (1+ i))                                         
      )
      (setq ll (apply 'mapcar (cons 'min pl)))                        ;左下角
      (setq ur (apply 'mapcar (cons 'max pl)))                  ;右上角
      (setq lr (list (car ll) (cadr ur) (caddr ll)))            ;右下角
      (setq ul (list (car ur) (cadr ll) (caddr ur)))            ;左上角
      (setq b (Make3dPoly (list ll lr ur ul)))                        ;构造边框
      (if IsUCS                                                        ;如果UCS
        (vla-TransformBy (vlax-ename->vla-object b) matrix)     ;变换边框到UCS
      )
      (vla-EndUndoMark doc)
    )
  )
  (princ)
)

;;;-----------------------------------------------------------;;
;;; 从一个坐标系统到另一个坐标系统的变换矩阵                  ;;
;;; 输入：from - 源坐标系；to - 目的坐标系                    ;;
;;; 输出：一个4X4的变换CAD的标准变换矩阵                      ;;
;;;-----------------------------------------------------------;;
(defun MAT:Trans (from to)
  (append
    (MAT:trp
      (mapcar
        (function (lambda (v d) (trans v from to d)))
        '((1. 0. 0.) (0. 1. 0.) (0. 0. 1.) (0. 0. 0.))
        (list t t t nil)
      )
    )
    '((0. 0. 0. 1.))
  )
)

;;;-----------------------------------------------------------;;
;;; 矩阵转置   MAT:trp Transpose a matrix -Doug Wilson-       ;;
;;; 输入：矩阵                                                ;;
;;; 输出：转置后的矩阵                                        ;;
;;;-----------------------------------------------------------;;
(defun MAT:trp (m)
  (apply 'mapcar (cons 'list m))
)

;;;-----------------------------------------------------------;;
;;; 画3d多段线                                                ;;
;;; draw a closed 3d Polyline                                 ;;
;;;-----------------------------------------------------------;;
(defun Make3dPoly (pts / e)
  (setq e (Entmake (list '(0 . "POLYLINE")'(70 . 9))))
  (foreach p Pts
    (entmake (list '(0 . "VERTEX") '(70 . 32) (cons 10 p)))
  )
  (entmake '((0 . "SEQEND")))
  (entlast)
)

(vl-load-com)
(prompt "\n请输入命令test")
(princ)[/pcode]

Lispboy

XDSoft 发表于 2013-4-28 11:26

                               
登录/注册后可看大图

在你机器上测试的包围盒，截取个图片贴论坛吧。

测试了下 夜来风雨声和高飞鸟的代码，夜来风雨声的代码有错误。

夜来风雨声的图片



高飞鸟的图片

userzhl

再发现BUG，对裁剪过的图块也有误。

XDSoft

userzhl 发表于 2013-4-28 14:30

                               
登录/注册后可看大图

再发现BUG，对裁剪过的图块也有误。

像LISPBOY那样，你截取个图片贴上来吧，并把有BUG的DWG传上来。高飞鸟版主和夜来风雨声的图片都贴下，现在不知道你说哪个代码有错误了。