[求助]：怎么才能更快地显示隐藏的实体

snsj · 发表于 2003-12-2 16:46:54

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

(defun c:apple_object_off (/ apple_ss apple_ss_name apple_i i)
(vl-load-com);| 加载 ActiveX 支持|;
(setq apple_ss (ssget)
apple_ss_name nil
i 0)
;|得到选择集，定义备用函数|;
(while
(setq apple_i (ssname apple_ss i))
(setq apple_ss_name (cons apple_i apple_ss_name))
(setq i (+ i 1))
)
;|遍历选择集，得到各个元素的名称|;
(mapcar
'(lambda (x)
(vla-put-visible
(vlax-ename->vla-object x)
0)
)
apple_ss_name
);|将选择集内的每个元素的可见性设为不可见|;
(princ)
);|结束|;
;|------------------------------------------|;
(defun c:apple_object_on (/ apple_getactive apple_mdon apple_pson)
(vl-load-com);| 加载 ActiveX 支持|;
(setq apple_getactive
(vla-get-activedocument (vlax-get-acad-object))
)
(vlax-for apple_mdon
(vla-get-modelspace apple_getactive)
(vla-put-visible apple_mdon -1)
)
;|显示模型空间的所有实体|;
(vlax-for apple_pson
(vla-get-paperspace apple_getactive)
(vla-put-visible apple_pson -1)
)
;|显示图纸空间的所有实体|;
(princ "\n###---显示全部实体完成---###")
(princ)
);|---结束---|;

(defun c:apple_object_off (/ apple_ss apple_ss_name apple_i i) 
(vl-load-com);| 加载 ActiveX 支持|; 
(setq apple_ss (ssget) 
      apple_ss_name nil 
      i 0) 
  ;|得到选择集，定义备用函数|; 
(while 
  (setq apple_i (ssname apple_ss i)) 
  (setq apple_ss_name (cons apple_i apple_ss_name)) 
        (setq i (+ i 1)) 
  ) 
  ;|遍历选择集，得到各个元素的名称|; 
(mapcar 
  '(lambda (x) 
     (vla-put-visible 
      (vlax-ename->vla-object x) 
        0) 
     ) 
  apple_ss_name 
  );|将选择集内的每个元素的可见性设为不可见|; 
(princ) 
);|结束|; 
;|------------------------------------------|; 
(defun c:apple_object_on (/ apple_getactive apple_mdon apple_pson) 
  (vl-load-com);| 加载 ActiveX 支持|; 
      (setq apple_getactive 
           (vla-get-activedocument (vlax-get-acad-object)) 
   ) 
  (vlax-for apple_mdon 
            (vla-get-modelspace apple_getactive) 
  (vla-put-visible apple_mdon -1) 
  ) 
  ;|显示模型空间的所有实体|; 
   (vlax-for apple_pson 
            (vla-get-paperspace apple_getactive) 
  (vla-put-visible apple_pson -1) 
  ) 
  ;|显示图纸空间的所有实体|; 
  (princ "\n###---显示全部实体完成---###") 
  (princ) 
  );|---结束---|;

由于XD工具不支持2004，自己写了简单写了个隐藏、显示实体的LISP，但是显示实体的程序我用的是通杀法，碰到大文件就超慢，
工作太忙没有时间考虑，希望各位朋友帮忙提供比较好的方法～～

LUCAS · 发表于 2003-12-3 07:56:20

;;隱藏物件有dxf 60碼
;;(setq ss(ssget "x" '((60 . 1))))

zhynt · 发表于 2003-12-2 18:13:46

我想是不是可以用信息数据的方法？将上一次隐藏实体的信息写入数据库，在反隐藏时调用。

陌生人 · 发表于 2003-12-2 21:12:09

可以考虑用组分次处理

zhynt · 发表于 2003-12-3 09:50:14

看来用纯lsp也可以实现这个功能：

(defun c:show_obj ()
(setq hidese (ssget "x" '((60 . 1))))
(setq n (sslength hidese))
(setq m 0)
(while (/= m n)
(setq se (ssname hidese m))
(setq hide_ent (entget se))
(setq hide_ent_n (length hide_ent))
(setq mm 0)
(setq hide_ent_new '())
(while (/= mm hide_ent_n)
(if (/= (car (setq hide_ent_tmp (nth mm hide_ent))) 60)
(setq hide_ent_new (cons hide_ent_tmp hide_ent_new))
)
(setq mm (1+ mm))
)
(setq hide_ent (reverse hide_ent_new))
(entdel se)
(entmake hide_ent)
(redraw)
(setq m (1+ m))
)
)

snsj · 发表于 2003-12-3 10:12:24

谢谢龙兄、雷锋、梦生人，用龙兄的60码先过滤隐藏实体再处理节约了不少时间，如果再快的话就是雷锋说的方法了，省去过滤的时间，估计小东工具里就是采用这样的方法

snsj · 发表于 2003-12-3 10:16:37

谢谢雷锋，领悟到60组码的威力了
改过后供不想费事的朋友使用吧

;;;----------------隐藏和显示实体程序--------------;;;
;;;----隐藏实体在命令行输入命令APPLE_OBJECT_OFF----;;;
;;;----恢复实体在命令行输入命令APPLE_OBJECT_ON-----;;;
;;;--------------------制作：snsj------------------;;;
;;;----APPLE_OBJECT_OFF.LSP/APPLE_OBJECT_OFN.LSP---;;;
(defun c:apple_object_off (/ apple_ss apple_ss_name apple_i i)
(vl-load-com);| 加载 ActiveX 支持|;
(setq apple_ss (ssget)
apple_ss_name nil
i 0)
;|得到选择集，定义备用函数|;
(while
(setq apple_i (ssname apple_ss i))
(setq apple_ss_name (cons apple_i apple_ss_name))
(setq i (+ i 1))
)
;|遍历选择集，得到各个元素的名称|;
(mapcar
'(lambda (x)
(vla-put-visible
(vlax-ename->vla-object x)
0)
)
apple_ss_name
);|将选择集内的每个元素的可见性设为不可见|;
(princ)
);|结束|;
;|------------------------------------------|;
(defun c:apple_object_on (/ apple_ss1 apple_ss_name1 apple_ii ii)
(setq apple_ss1 (ssget "x" '((60 . 1)))
apple_ss_name1 nil
ii 0)
(while
(setq apple_ii (ssname apple_ss1 ii))
(setq apple_ss_name1 (cons apple_ii apple_ss_name1))
(setq ii (+ ii 1))
)
;|遍历选择集，得到各个元素的名称|;
(mapcar
'(lambda (x)
(vla-put-visible
(vlax-ename->vla-object x)
-1)
)
apple_ss_name1
);|将选择集内的每个元素的可见性设为不可见|;
(princ)
);|结束|;

;;;----------------隐藏和显示实体程序--------------;;; 
;;;----隐藏实体在命令行输入命令APPLE_OBJECT_OFF----;;; 
;;;----恢复实体在命令行输入命令APPLE_OBJECT_ON-----;;; 
;;;--------------------制作：snsj------------------;;; 
;;;----APPLE_OBJECT_OFF.LSP/APPLE_OBJECT_OFN.LSP---;;; 
(defun c:apple_object_off (/ apple_ss apple_ss_name apple_i i) 
(vl-load-com);| 加载 ActiveX 支持|; 
(setq apple_ss (ssget) 
      apple_ss_name nil 
      i 0) 
  ;|得到选择集，定义备用函数|; 
(while 
  (setq apple_i (ssname apple_ss i)) 
  (setq apple_ss_name (cons apple_i apple_ss_name)) 
        (setq i (+ i 1)) 
  ) 
  ;|遍历选择集，得到各个元素的名称|; 
(mapcar 
  '(lambda (x) 
     (vla-put-visible 
      (vlax-ename->vla-object x) 
        0) 
     ) 
  apple_ss_name 
  );|将选择集内的每个元素的可见性设为不可见|; 
(princ) 
);|结束|; 
;|------------------------------------------|; 
(defun c:apple_object_on (/ apple_ss1 apple_ss_name1 apple_ii ii) 
(setq apple_ss1 (ssget "x" '((60 . 1))) 
      apple_ss_name1 nil 
      ii 0) 
(while 
  (setq apple_ii (ssname apple_ss1 ii)) 
  (setq apple_ss_name1 (cons apple_ii apple_ss_name1)) 
        (setq ii (+ ii 1)) 
  ) 
  ;|遍历选择集，得到各个元素的名称|; 
(mapcar 
  '(lambda (x) 
     (vla-put-visible 
      (vlax-ename->vla-object x) 
        -1) 
     ) 
  apple_ss_name1 
  );|将选择集内的每个元素的可见性设为不可见|; 
(princ) 
);|结束|;

lsjjm · 发表于 2003-12-3 10:20:54

最初由 snsj 发布
[B][code]怎么才能更快地显示隐藏的实体... [/B]

(defun c:test ()
 (vl-load-com)
 (setq ss (ssget "x" '((60 . 1))) n 0)
 (if ss
(while (< n (sslength ss))
 (setq obj (vlax-ename->vla-object (ssname ss n)))
 (vla-put-visible obj 1)
 (setq n (1+ n))
)
 )
)

snsj · 发表于 2003-12-3 10:28:59

谢谢lsjjm精简的非常棒，瘦了好多

陌生人 · 发表于 2003-12-3 14:39:01

很好,今晚我也试试写一个

aeo · 发表于 2003-12-3 21:23:59

R14就:

(defun c:hideit( / j ss)
(if (setq j -1 ss(ssget '((-4 . "< not")(60 . 1)(-4 . "not >")) ))
(repeat (sslength ss)
(entmod(cons '(60 . 1)(entget (ssname ss(setq j(1+ j))))))
))(princ)
)
(defun c:showit( / j ss en)
(if (setq j -1 ss(ssget "x" '((60 . 1)) ))
(repeat (sslength ss)
(entmod(subst '(60 . 0)(assoc 60(setq en(entget(ssname ss(setq j(1+ j))))))en))
))(princ)
)

还是vla- 方便!
上面《为< ,》为> ,贴不出来，没办法

陌生人 · 发表于 2003-12-4 00:08:56

你试试 < > 与文字间加一个空格

LUCAS · 发表于 2003-12-4 08:04:09

;;By LUCAS
(defun C:OBJECT_ON (/ OBJ)
(vl-load-com)
(if (ssget "x" '((60 . 1)))
(vlax-for OBJ (vla-get-activeselectionset
(vla-get-activedocument (vlax-get-acad-object))
)
(vla-put-visible OBJ :vlax-true)
)
)
(princ)
)
(defun C:OBJECT_OFF (/ OBJ)
(vl-load-com)
(if (ssget)
(vlax-for OBJ (vla-get-activeselectionset
(vla-get-activedocument (vlax-get-acad-object))
)
(vla-put-visible OBJ :vlax-false)
)
)
(princ)
)

zhynt · 发表于 2003-12-4 09:09:26

最初由 aeo 发布
[B]R14就:
[code]
(defun c:hideit( / j ss)
(if (setq j -1 ss(ssget '((-4 . "< not")(60 . 1)(-4 . "not >")) ))
(repeat (sslength ss)
(entmod(cons '(60 . 1)(entget (ssname ss(setq j(1+ j))))))... [/B]

这个程序过于简单了，这对于简单图元是可以的，但是对于象多义线、填充、块等复杂图元(60 . 1)加在组码开头是无效的。

lockmyeye · 发表于 2003-12-4 09:10:00

好文章：）

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：怎么才能更快地显示隐藏的实体

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

Re: [求助]：怎么才能更快地显示隐藏的实体