[求助]：用lisp怎样判断一个vba工程已经加载？

hxg_888

用lisp怎样判断一个vba工程已经加载？

lsjjm

(defun test (vbapro / loaded)
  (vl-load-com)
  (setq vbe (vla-get-vbe (vlax-get-acad-object)))
  (setq vprojs (vlax-get-property vbe 'vbprojects))
  (setq nv (vlax-get-property vprojs 'count))
  (setq n 1)
  (while (<= n nv)
    (setq vfilen (vlax-get-property
                   (vlax-invoke-method vprojs 'Item n)
                   'fileName
                 ))   
    (if (= vfilen vbapro)(setq loaded T))
    (setq n (1+ n))
  )
  loaded
)

JOSDENNIS

試試這個


;;;========================================
;;;檢查VBA工程是否加載,如沒有加載則加載
;;;========================================
(defun loadProject (vabproject  fn /    acadObject
            acadVbe        acadVbeProjects  int2
            loaded        Item    pName
              )
  (vl-load-com)
  (setq acadObject (vlax-get-acad-object))
  (setq acadVbe (vla-get-vbe acadObject))
  (setq acadVbeProjects (vlax-get-property acadVbe 'VBProjects))
  (setq int1 (vlax-get-property acadVbeProjects 'count))
  (setq int2 1)
  (setq loaded "False")
  (repeat int1
    (setq Item (vlax-invoke-method acadVbeProjects 'Item int2))
    (setq pName (vlax-get-property Item 'Name))
    (if    (= pName vabproject)
      (Setq Loaded "True")
    )
    (setq int2 (+ int2 1))
  )
  (if (= Loaded "False")
    (vl-vbaload fn)
  )
)