[求助]：怎样同时标上X和Y坐标?

yugarden511

我的意思是一个引线,上面同时有X和Y的坐标,而不是只能标X再标Y

liuzz2004

这个只有专用的软件才能起作用，CAD内部好象没有这样的功能，你应该在类似于理正建筑软件这样的建筑软件当中去找一下这方面的功能。

舍我其谁

小东里面有！不过没试过，还是用的老土办法id。

teyjzy_yl

一个朋友编的标注坐标的Lisp程序：
[PHP](defun c:xy()
   (setq CVAR(getvar "CMDECHO"))
   (setq lw0(getvar "plinewid"))
   (setvar "cmdecho" 0)
   (setq OVAR(getvar "OSMODE"))
   (setq xt "X=" yt "Y=")
   (setq sc(getreal "\nPlease input plot_scale 1:xxx[500]:"))
   (if (null sc)(setq sc 500))
   (setq yx(getstring "\nDo you like exchange X-Y[N]:"))
   (if (or (= yx "y")(= yx "Y"))(setq yt "X=" xt "Y="))
   (command "style" "" "" 0 0.66 0 "" "" "")
   ;---------------------------
   (setvar "OSMODE" 33)
   (setq p0(getpoint "Please pick point:"))
   (while p0
        (setvar "OSMODE" 0)
        (setq p1(getpoint p0 "Pick label position:"))
        (setq x0 (car p0)
              x1 (car p1)
              y0 (nth 1 p0)
              y1 (nth 1 p1)
        )
        (if (> x0 x1) (setq lr -1 tj "bL")(setq lr 1 tj "br"))
        (if (> y0 y1) (setq ud -1 )(setq ud 1))
       ; (setq x1 (+ x0 (* sc 5 lr))
       ;       y1 (+ y0 (* sc 5 ud))
        (setq xti (strcat xt (rtos (/ x0 1.000) 2 3))
              yti (strcat yt (rtos (/ y0 1.000) 2 3))
              lx (strlen xti)
        )
        (if (< lx (strlen yti))(setq lx (strlen yti)))
        (setq lx (* 1.67 (+ 3 lx) sc lr)
              x2 (+ x1 lx)
              y3 (- y1 (* 4.5 sc))
              y4 (+ y1 (* 0.5 sc))
              p1 (list x1 y1 0)
              p2 (list x2 y1 0)
              p3 (list x2 y3 0)
              p4 (list x2 y4 0)
        )
        (command "pline" p0 "w" 0 0 p1 p2 "")
        (command "text" tj p3 (* 3 sc) 0 xti)
        (command "text" tj p4 (* 3 sc) 0 yti)
        (setvar "OSMODE" 33)
        (setq p0(getpoint "Please pick point:"))
   )
   (setvar "plinewid" lw0)
   (setvar "CMDECHO" CVAR)
   (setvar "OSMODE"  OVAR)
   (princ "\n -- OK --")
   (princ)
)[/PHP]

yugarden511

多谢多谢