[VBA程序]：第一个VBA程序，请指教

麻雀

初学VBA,试着编写一个绘制螺孔的程序，请版主和各位dx指教：
Sub luokong()
    Dim insertPnt As Variant
    Dim prompt1 As String
    prompt1 = vbCrLf & "输入插入点："
    insertPnt = ThisDrawing.Utility.GetPoint(, prompt1)
    Dim rad As Double
    prompt1 = vbCrLf & "输入螺纹直径"
    rad = ThisDrawing.Utility.GetReal(prompt1) / 2
    ThisDrawing.ModelSpace.AddCircle insertPnt, rad
    ThisDrawing.ModelSpace.AddArc insertPnt, rad * 0.85, 280 * 3.1415926 / 180, 190 / 180 * 3.1415926
    Dim cntLineStartPnt(2) As Double
    Dim cntLineEndPnt(2) As Double
    cntLineStartPnt(0) = insertPnt(0) - rad - 2
    cntLineStartPnt(1) = insertPnt(1)
    cntLineStartPnt(2) = insertPnt(2)
    cntLineEndPnt(0) = insertPnt(0) + rad + 2
    cntLineEndPnt(1) = insertPnt(1)
    cntLineEndPnt(2) = insertPnt(2)
    ThisDrawing.ModelSpace.AddLine cntLineStartPnt, cntLineEndPnt
    cntLineStartPnt(0) = insertPnt(0)
    cntLineStartPnt(1) = insertPnt(1) - rad - 2
    cntLineEndPnt(0) = insertPnt(0)
    cntLineEndPnt(1) = insertPnt(1) + rad + 2
    ThisDrawing.ModelSpace.AddLine cntLineStartPnt, cntLineEndPnt
    ThisDrawing.Application.ZoomAll
End Sub


有几点不明白之处，请大家指教：
1。在绘图时，如何转换图层？
2。在画中心线时，感觉到有些复杂。还有没有更好的办法？

雪山飞狐(lzh)

1、
用直线的Layer属性
Dim pObj As AcadLine
Set pObj = ThisDrawing.ModelSpace.AddLine(cntLineStartPnt, cntLineEndPnt)
pObj.Layer = "01"
2、
用PolarPoint函数
dim p1,p2
p1 = ThisDrawing.Utility.GetPoint
p2 = ThisDrawing.Utility.PolarPoint(p1, 0, 12)
具体含义可以看帮助

麻雀

谢谢,再问一个问题：
VB中的π是怎么表示的，必须用3.1415表示吗？有没有常数或函数？

雪山飞狐(lzh)

pi=Atn(1)*4

麻雀

谢谢lzh741206  版主，修改后程序如下：

Sub luokong()
    Dim pi As Double
    pi = Atn(1) * 4
    Dim insertPnt As Variant
    Dim prompt1 As String
    prompt1 = vbCrLf & "输入插入点："
    insertPnt = ThisDrawing.Utility.GetPoint(, prompt1)
    Dim rad As Double
    prompt1 = vbCrLf & "输入螺纹直径:"
    rad = ThisDrawing.Utility.GetReal(prompt1) / 2
   
    Dim objCircle As AcadCircle
    Dim objArc As AcadArc
    Set objCircle = ThisDrawing.ModelSpace.AddCircle(insertPnt, rad * 0.85)
    objCircle.Layer = "粗线"
    Set objArc = ThisDrawing.ModelSpace.AddArc _
        (insertPnt, rad, 280 * pi / 180, 190 / 180 * pi)
    objArc.Layer = "细线"
   
    Dim cntLineStartPnt As Variant
    Dim cntLineEndPnt As Variant
    Dim objLine As AcadLine
    cntLineStartPnt = ThisDrawing.Utility.PolarPoint(insertPnt, 0, rad + 2)
    cntLineEndPnt = ThisDrawing.Utility.PolarPoint(insertPnt, 0, 0 - rad - 2)
    Set objLine = ThisDrawing.ModelSpace.AddLine(cntLineStartPnt, cntLineEndPnt)
    objLine.Layer = "中心线"
    cntLineStartPnt = ThisDrawing.Utility.PolarPoint(insertPnt, pi / 2, rad + 2)
    cntLineEndPnt = ThisDrawing.Utility.PolarPoint(insertPnt, pi * 3 / 2, rad + 2)
    Set objLine = ThisDrawing.ModelSpace.AddLine(cntLineStartPnt, cntLineEndPnt)
    objLine.Layer = "中心线"
    ThisDrawing.Application.ZoomAll

End Sub

莫之非

我不是太懂，看起来有点像vb，可以告诉我怎么运行吗？详细的讲一下呗，谢谢

雪山飞狐(lzh)

to 莫之非
看看置顶的帖子