[求助]：关于标注对齐标注尺寸界线

toddth · 发表于 2004-6-12 15:41:09

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

大家如何使那两条线和标注对象有足够的距离的？尺寸线偏移好像不太好用

cdhua001 · 发表于 2004-6-12 18:20:04

不大懂你的意思，你看看是不是这样的：

jerry_bj · 发表于 2004-6-12 19:11:48

td 是什么工具能分享吗？

toddth · 发表于 2004-6-14 15:40:37

最初由 cdhua001 发布
[B]不大懂你的意思，你看看是不是这样的： [/B]

是这样的，你用什么东西，能修剪标注线？

民工 · 发表于 2004-6-14 15:44:40

这个就是你要的lisp程序，将下面的程序存成td.lsp文件，在acad里面加载。

[FONT=courier new]
(defun c:td (/ ang e en j len olderr os pt1 pt2 pt3 pt4 ss aeoerr
trim-dim dxf
)
(defun dxf(a b)(cdr(assoc a b)))
(defun aeoerr (msg)
(command "_.undo" "end" ^c)
(setvar "osmode" os)
(setq *error* olderr)
)
(defun trim-dim (pt1 pt2 ss / ent entl i np13 np14 p10 p13 p14 ptt)
; 这一; 段改自"程序（函数）库"
(setq pt1 (trans pt1 1 0)
pt2 (trans pt2 1 0)
i 0
)
(repeat (sslength ss)
(setq ent (ssname ss i)
entl (entget ent)
p10 (cdr (assoc 10 entl))
p13 (cdr (assoc 13 entl))
p14 (cdr (assoc 14 entl))
ptt (cdr (assoc 11 entl))
i (1+ i)
np14 (inters
pt1
pt2
p14
p10
nil
)
)
(if (not (member '(100 . "AcDbRotatedDimension") entl))
(setq np13 (polar np14 (angle p14 p13) (distance p14 p13)))
(setq np13 (inters
pt1
pt2
p13
(polar p13 (angle p14 p10) 100)
nil
)
)
)
(setq entl (subst
(cons 13 np13)
(assoc 13 entl)
entl
)
entl (subst
(cons 14 np14)
(assoc 14 entl)
entl
)
)
(entmod entl)
)
)
;;;;;;;
(setq os (getvar "osmode")
olderr *error*
*error* aeoerr
)
(setvar "osmode" 0)
(command "undo" "group")
(prompt "\nby aeo")
(prompt "\n不要修改的标注不要选在里面")
(if (setq ss (ssget '((0 . "DIMENSION"))))
(progn
(setq en (entget (ssname ss 0)))
(if (member '(100 . "AcDbRotatedDimension") en)
(setq ang (dxf 50 en))
(setq ang (angle (dxf 13 en) (dxf 14 en)))
)
)
)
(if (and
ang
(setq pt1 (getpoint "\n标注线位置(回车不改):"))
)
(progn
(setq pt2 (polar pt1 ang 1000)
j 0
len (sslength ss)
)
(while (< j len)
(setq e (ssname ss j)
en (entget (ssname ss j))
pt3 (dxf 10 en)
pt4 (inters
pt1
pt2
pt3
(polar pt3 (+ ang (* 0.5 pi)) 100)
nil
)
j (1+ j)
)
(command "move" e "" pt3 pt4)
)
)
)
(if (and
ang
(setq pt1 (getpoint "\n引出线位置(回车不改):"))
)
(trim-dim pt1 (polar pt1 ang 100) ss)
)
(setvar "osmode" os)
(setq *error* olderr)
(command "_.undo" "end")
(princ)
)
[/FONT]

[FONT=courier new] 
(defun c:td (/ ang e en j len olderr os pt1 pt2 pt3 pt4 ss aeoerr 
                     trim-dim dxf 
                  ) 
  (defun dxf(a b)(cdr(assoc a b))) 
  (defun aeoerr (msg) 
    (command "_.undo" "end" ^c) 
    (setvar "osmode" os) 
    (setq *error* olderr) 
  ) 
  (defun trim-dim (pt1 pt2 ss / ent entl i np13 np14 p10 p13 p14 ptt) 
  ; 这一; 段改自"程序（函数）库" 
    (setq pt1 (trans pt1 1 0) 
          pt2 (trans pt2 1 0) 
          i 0 
    ) 
    (repeat (sslength ss) 
      (setq ent (ssname ss i) 
            entl (entget ent) 
            p10 (cdr (assoc 10 entl)) 
            p13 (cdr (assoc 13 entl)) 
            p14 (cdr (assoc 14 entl)) 
            ptt (cdr (assoc 11 entl)) 
            i (1+ i) 
            np14 (inters 
                   pt1 
                   pt2 
                   p14 
                   p10 
                   nil 
                 ) 
      ) 
      (if (not (member '(100 . "AcDbRotatedDimension") entl)) 
        (setq np13 (polar np14 (angle p14 p13) (distance p14 p13))) 
        (setq np13 (inters 
                     pt1 
                     pt2 
                     p13 
                     (polar p13 (angle p14 p10) 100) 
                     nil 
                   ) 
        ) 
      ) 
      (setq entl (subst 
                   (cons 13 np13) 
                   (assoc 13 entl) 
                   entl 
                 ) 
            entl (subst 
                   (cons 14 np14) 
                   (assoc 14 entl) 
                   entl 
                 ) 
      ) 
      (entmod entl) 
    ) 
  )                                        
  ;;;;;;; 
  (setq os (getvar "osmode") 
        olderr *error* 
        *error* aeoerr 
  ) 
  (setvar "osmode" 0) 
  (command "undo" "group") 
  (prompt "\nby aeo") 
  (prompt "\n不要修改的标注不要选在里面") 
  (if (setq ss (ssget '((0 . "DIMENSION")))) 
    (progn 
      (setq en (entget (ssname ss 0))) 
      (if (member '(100 . "AcDbRotatedDimension") en) 
        (setq ang (dxf 50 en)) 
        (setq ang (angle (dxf 13 en) (dxf 14 en))) 
      ) 
    ) 
  ) 
  (if (and 
        ang 
        (setq pt1 (getpoint "\n标注线位置(回车不改):")) 
      ) 
    (progn 
      (setq pt2 (polar pt1 ang 1000) 
            j 0 
            len (sslength ss) 
      ) 
      (while (< j len) 
        (setq e (ssname ss j) 
              en (entget (ssname ss j)) 
              pt3 (dxf 10 en) 
              pt4 (inters 
                    pt1 
                    pt2 
                    pt3 
                    (polar pt3 (+ ang (* 0.5 pi)) 100) 
                    nil 
                  ) 
              j (1+ j) 
        ) 
        (command "move" e "" pt3 pt4) 
      ) 
    ) 
  ) 
  (if (and 
        ang 
        (setq pt1 (getpoint "\n引出线位置(回车不改):")) 
      ) 
    (trim-dim pt1 (polar pt1 ang 100) ss) 
  ) 
  (setvar "osmode" os) 
  (setq *error* olderr) 
  (command "_.undo" "end") 
  (princ) 
) 
 
  [/FONT]

toddth · 发表于 2004-6-14 15:48:45

谢了先，我去试试

degucn · 发表于 2004-6-15 20:06:59

请问“民工”
你给的LISP程序，每次运行后，对象捕捉就会丢失，每次还要按Shift去重新开启，能不能解决一下这个问题啊？

wtult · 发表于 2004-6-16 08:40:15

我输入TD怎么提示未知命令！

潜龙在渊 · 发表于 2004-6-16 09:01:37

民工,请问你所给的程序要如何才能用得上呀,如何加载到CAD里面呀,我对LISP简直是一窍不通,还望你能多多指教,这个程序是我非常想要的,麻烦了

民工 · 发表于 2004-6-16 09:39:42

最初由 dugecn 发布
[B]请问“民工”
你给的LISP程序，每次运行后，对象捕捉就会丢失，每次还要按Shift去重新开启，能不能解决一下这个问题啊？[/B]

我又试了几遍，没有发现这种情况啊，真是奇怪了。要不你下载后面的程序再试试看。

最初由潜龙在渊发布
[B]民工,请问你所给的程序要如何才能用得上呀,如何加载到CAD里面呀,我对LISP简直是一窍不通,还望你能多多指教,这个程序是我非常想要的,麻烦了 [/B]

将附件里的lsp文件，存到你的acad安装目录下的\suppout目录下面
运行acad，“工具”菜单，“加载应用程序”，弹出“加载/卸载应用程序”，在上面的窗口中找到要加载的lsp程序，点击“加载”

也可以加入到“启动组”里，每次启动acad就自动加载了，方法是点击弹出窗口右下角的公文包，把要自动启动的文件放进去就行了。

不会做演示，只得多打字

degucn · 发表于 2004-6-16 11:40:12

我重新下载了，加载进去，又出现了运行“TD”命令，捕捉全没了，奇怪？哪道是我CAD有问题，我其它的命令不会有这种情况啊!

潜龙在渊 · 发表于 2004-6-16 11:41:40

呵呵,多谢民工,我成功了,真的很高兴,假如你不是上传的附件,而是只有那个附码,我是不是可以复制到记事本里面自已保存呢,不过好像记事本不能保存成LISP的文件吧

民工 · 发表于 2004-6-16 17:23:00

最初由潜龙在渊发布
[B]呵呵,多谢民工,我成功了,真的很高兴,假如你不是上传的附件,而是只有那个附码,我是不是可以复制到记事本里面自已保存呢,不过好像记事本不能保存成LISP的文件吧 [/B]

用记事本就可以了，选择“另存为”，在文件类型中选择“所有文件”，直接输入文件名.后缀

捕捉设置清空的现象有点奇怪，程序尾部已经有命令“(setvar "osmode" os)”啊

gp8117 · 发表于 2004-6-16 19:12:44

等了好久终于等到了!心情万分高兴!斑竹谢谢,万分感谢!

xgwl · 发表于 2004-6-16 19:45:52

能不能给天正6的标注尺寸线来个加强呢, 比如说两个不想连的尺寸线来个基线对齐,或者标注长短匹配, 或者三道尺寸线之间不均布的来个均匀布置! 呵呵~~~~ 只是个想法!

账号		自动登录	找回密码
密码			立即注册

[求助]：关于标注对齐标注尺寸界线

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

浏览过的版块