[求助]：如何一次性获取多义线的所有顶点

maplesu

用lsjjm的方法修改了一下，可以得到z坐标了

lsjjm

最初由 maplesu 发布
[B]...我认为autolisp没有办法解决这个问题... [/B]

先不要清易下结论, 怎么会没有办法呢?

纯LISP返回三维多义线顶点:
(defun c:test ( )
  (setq n 0)
  (setq elist (entget (car (entsel))))
  (setq ename (cdr (assoc -1 elist)))
  (while (/= (cdr (assoc 0 elist)) "SEQEND")
    (setq elist (entget (setq ename (entnext ename))))
    (if (assoc 10 elist)
      (setq pts (cons (cdr (assoc 10 elist)) pts))
    )
    (setq n (+ 1 n))
  )
  pts
)

maplesu

呵呵，还真的没有想到这个方法！
谢谢lsjjm！！

zxdcad

提取多段线与多义线的控制点，以上各位高手说的太好了，解决的也彻底了。

我遇到过需要加工用的曲线数据，光控制点的话可实在是少的可怜，而且曲线类型决定了曲线不一定通过控制点时怎么办？因此必须取曲线上的众多点才能满足要求。

采取两个步骤即可完成。
1、先用定数或等距点的方式在曲线上作出足够精度的等分点（曲线可以是平面的，也可以是空间的）。

2、将点坐标用下面程序提取出来即可。(若不需Z坐标，可将程序中的相关行删除即可）

精度我在程序中设的是小数据点后三位，可根据需要重新调整

(defun C:pointxy ()
  (setq ss (ssget "X" '((0 . "POINT")))) ;选择全部点
  (setq leng (sslength ss))
  (setq index (- leng 1))
  (setq f (open "D:\pointxy.txt" "w"))
  (REPEAT leng
    (setq b1 (entget (ssname ss index)))
    (setq xy (cdr (assoc 10 b1)))
    (setq x (rtos (car xy) 2 3))
    (setq y (rtos (cadr xy) 2 3))
    (setq z (rtos (caddr xy) 2 3))   ;精度取小数点后三位
    (princ x f)
    (princ "," f)
    (princ y f)
    (princ "," f)
    (princ z f)
    (princ "\n" f)
    (setq index (- index 1))
  )
  (close f)
)

陌生人

凑个热闹，一个子函数,不管是2d的还是3d的
[php]
;|
(xl-vertexs e) = 提取 lwpolyline,polyline类的顶点含xyz.----陌生人!
|;
(defun xl-vertexs (e / pts z i lst)
   (setq obj (vlax-ename->vla-object e)
         pts (vlax-get obj 'Coordinates )
         z   (if (= "AcDbPolyline"  (vla-get-objectname obj)) (vlax-get obj 'Elevation ))
         i   0)
   (while  pts
     (setq lst (cons (list (car pts) (cadr pts) (if z z (caddr pts))) lst)
           pts (if z (cddr pts)(cdddr pts)))
   )(reverse lst)
)

[/php]

lsjjm

内部函数(acet-geom-vertex-list pl) 返回多义线(二维和三维)诸顶点.

陌生人

我知道，不过我觉得你应该说
“et工具的内部函数(acet-geom-vertex-list pl) 返回多义线(二维和三维)诸顶点. ”

柔柔

19楼的思路不错。
过去我在编一个曲面展开程序时，开始采用提取曲线的控制点，后来发现不同程序生成的曲线差别太大，有一位博士生编的曲线生成程序，其控制点多到完全脱离实际，把这些点提出来用在我的程序上，只有死机的份。于是我只好放弃这些点，用定数或等距点的方式（精度由用户控制）自己生成点，也就是说只利用原有曲线来生成自己需要的点，并不涉及原曲线的数据，这样，原来是什么曲线就无所谓了。

maplesu

对于样条曲线来说的确先等分在取出等分点的坐标是一个很好的思路！

对于et工具的内部函数(acet-geom-vertex-list pl)这个取得样条曲线的时候是取得控制点，而控制点并非一定在曲线上的，样条曲线的拟和点才是曲线上的点。但是拟和点是如果你这个样条曲线不是通过描点画出来的，应该就是没有拟和点了！

lsjjm

返回样条曲线拟和点: (vla-get-fitpoints spobj)

tdgc

我有一个类似的问题，就是一条线路，在放线的时候，需要提取百米标和一些控制点的坐标，并导入到EXCEL表中。原程序我看不懂，不知哪位能解决一下？ 谢谢！

yovz

汗，这些天来在这个论坛中看了这么多高手对于CAD的分析，真没有想到CAD可以用很多地方呢，改变了原先CAD只用于二维绘图的看法，看来要向各位好好学习，学好CAD！！！

taner

(defun vertexs (ename / plist pp n)        
  (setq obj (vlax-ename->vla-object ename))
  (setq plist (vlax-safearray->list
(vlax-variant-value
  (vla-get-coordinates obj))))
  (setq n 0)
  (repeat (/ (length plist) 2)
    (setq pp (append pp (list (list (nth n plist)(nth (1+ n) plist)))))
    (setq n (+ n 2))
  )
  pp
)

lxg_lhr

有点用，学习了。

zjlszw

vba和lisp语言博大精深。学习了。