[求助]：怎样通过几点来通过算法求其形心?

LUCAS · 发表于 2003-1-9 08:51:29

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

;;; 修正版BY LUCAS
;;; VxGetMassProps - Returns a list of all mass properties of the object
;;; -- Function VxGetMassProps
;;; Returns a list of all mass properties of the object.
;;; Copyright:
;;; 2001 MENZI ENGINEERING GmbH, Switzerland
;;; Arguments [Typ]:
;;; Obj = Object [VLA-OBJECT]
;;; Return [Typ]:
;;; > Mass properties '({Area Perimeter} {Mass Volume}
;;; Centroid MomentOfInertia
;;; ProductOfInertia RadiiOfGyration
;;; PrincipalMoments PrincipalDirections
;;; ) [LIST]
;;; Notes:
;;; - VxGetMassProps is designed to handle closed *Polylines,
;;; Regions and 3dsolids.
;;; - *Polylines and Regions returns 2D-lists in some parameters.
;;; - 2D-objects returns '({Area Perimeter}. . . . . . )
;;; - 3D-objects returns '({Mass Volume}. . . . . . )
;;; - Use a DocManagerReactor with a 'vlr-documentToBeDestroyed'-event
;;; to release the Gb:AcO and Gb:AcD objects at the end of a
;;; AutoCAD session - otherwise AutoCAD maybe crashes...
;;; USAGE: (VXGETMASSPROPS (vlax-ename->vla-object (car (entsel))))
(defun VXGETMASSPROPS (OBJ / DELFLG RESLST TMPOBJ)
(setq GB:ACO (cond (GB:ACO)
((vlax-get-acad-object))
)
GB:ACD (cond (GB:ACD)
((vla-get-activedocument GB:ACO))
)
)
(if (member (vla-get-objectname OBJ)
'("AcDb2dPolyline" "AcDbPolyline")
)
(setq DELFLG t
TMPOBJ (vlax-safearray-get-element
(vlax-variant-value
(vla-addregion
(vla-get-modelspace GB:ACD)
(VXLISTTOARRAY vlax-vbobject (list OBJ))
)
)
0
)
)
(setq TMPOBJ OBJ)
)
(setq RESLST
(append
(list
(if (= (vla-get-objectname TMPOBJ) "AcDbRegion")
(list (vla-get-area TMPOBJ) (vla-get-perimeter TMPOBJ))
(list (vla-get-volume TMPOBJ) (vla-get-volume TMPOBJ))
)
(vlax-get TMPOBJ "centroid")
(vlax-get TMPOBJ "momentofinertia")
(if (= (vla-get-objectname TMPOBJ) "AcDbRegion")
(list (vlax-get TMPOBJ "productofinertia"))
(vlax-get TMPOBJ "productofinertia")
)
(vlax-get TMPOBJ "radiiofgyration")
(vlax-get TMPOBJ "principalmoments")
(vlax-get TMPOBJ "principaldirections")
)
)
)
(if DELFLG
(vla-delete TMPOBJ)
)
RESLST
)
;;; (vlax-safearray->list (vlax-variant-value (vla-get-radiiofgyration TMPOBJ)))
;;; =
;;; (vlax-get TMPOBJ "radiiofgyration")
;;;VxListToArray - Converts a list into an array
;;; -- Function VxListToArray
;;; Converts a list into an array.
;;; Copyright:
;;; ?000 MENZI ENGINEERING GmbH, Switzerland
;;; Arguments [Typ]:
;;; Lst = Standard list [LIST]
;;; Typ = Datatype [INT]
;;; Constants:
;;; - vlax-vbBoolean
;;; - vlax-vbDecimal *)
;;; - vlax-vbDouble
;;; - vlax-vbInteger
;;; - vlax-vbLong
;;; - vlax-vbObject
;;; - vlax-vbSingle
;;; - vlax-vbString
;;; - vlax-vbVariant
;;; Return [Typ]:
;;; > Array [VARIANT]
;;; Notes:
;;; *)Missing datatype in Visual LISP, initialize it in your Autoloader.
;;; - Can't be used for dotted pair or nested lists.
;;;
(defun VXLISTTOARRAY (TYP LST)
(vlax-make-variant
(vlax-safearray-fill
(vlax-make-safearray TYP (cons 0 (1- (length LST))))
LST
)
)
)

;;; 修正版BY LUCAS 
;;; VxGetMassProps - Returns a list of all mass properties of the object 
;;; -- Function VxGetMassProps 
;;; Returns a list of all mass properties of the object. 
;;; Copyright: 
;;;   2001 MENZI ENGINEERING GmbH, Switzerland 
;;; Arguments [Typ]: 
;;;   Obj = Object [VLA-OBJECT] 
;;; Return [Typ]: 
;;;   > Mass properties '({Area Perimeter} {Mass Volume} 
;;;                            Centroid          MomentOfInertia 
;;;                            ProductOfInertia  RadiiOfGyration 
;;;                            PrincipalMoments  PrincipalDirections 
;;;                       ) [LIST] 
;;; Notes: 
;;; - VxGetMassProps is designed to handle closed *Polylines, 
;;;   Regions and 3dsolids. 
;;; - *Polylines and Regions returns 2D-lists in some parameters. 
;;; - 2D-objects returns '({Area Perimeter}. . . . . . ) 
;;; - 3D-objects returns '({Mass Volume}. . . . . . ) 
;;; - Use a DocManagerReactor with a 'vlr-documentToBeDestroyed'-event 
;;;   to release the Gb:AcO and Gb:AcD objects at the end of a 
;;;   AutoCAD session - otherwise AutoCAD maybe crashes... 
;;; USAGE: (VXGETMASSPROPS (vlax-ename->vla-object (car (entsel)))) 
 
(defun VXGETMASSPROPS (OBJ / DELFLG RESLST TMPOBJ) 
  (setq        GB:ACO (cond (GB:ACO) 
                     ((vlax-get-acad-object)) 
               ) 
        GB:ACD (cond (GB:ACD) 
                     ((vla-get-activedocument GB:ACO)) 
               ) 
  ) 
  (if (member (vla-get-objectname OBJ) 
              '("AcDb2dPolyline" "AcDbPolyline") 
      ) 
    (setq DELFLG t 
          TMPOBJ (vlax-safearray-get-element 
                   (vlax-variant-value 
                     (vla-addregion 
                       (vla-get-modelspace GB:ACD) 
                       (VXLISTTOARRAY vlax-vbobject (list OBJ)) 
                     ) 
                   ) 
                   0 
                 ) 
    ) 
    (setq TMPOBJ OBJ) 
  ) 
  (setq        RESLST 
         (append 
           (list 
             (if (= (vla-get-objectname TMPOBJ) "AcDbRegion") 
               (list (vla-get-area TMPOBJ) (vla-get-perimeter TMPOBJ)) 
               (list (vla-get-volume TMPOBJ) (vla-get-volume TMPOBJ)) 
             ) 
             (vlax-get TMPOBJ "centroid") 
             (vlax-get TMPOBJ "momentofinertia") 
             (if (= (vla-get-objectname TMPOBJ) "AcDbRegion") 
               (list (vlax-get TMPOBJ "productofinertia")) 
               (vlax-get TMPOBJ "productofinertia") 
             ) 
             (vlax-get TMPOBJ "radiiofgyration") 
             (vlax-get TMPOBJ "principalmoments") 
             (vlax-get TMPOBJ "principaldirections") 
           ) 
         ) 
  ) 
  (if DELFLG 
    (vla-delete TMPOBJ) 
  ) 
  RESLST 
) 
 
 
;;; (vlax-safearray->list (vlax-variant-value (vla-get-radiiofgyration TMPOBJ))) 
;;; = 
;;; (vlax-get TMPOBJ "radiiofgyration") 
 
 
;;;VxListToArray - Converts a list into an array 
;;; -- Function VxListToArray 
;;; Converts a list into an array. 
;;; Copyright: 
;;;   ?000 MENZI ENGINEERING GmbH, Switzerland 
;;; Arguments [Typ]: 
;;;   Lst = Standard list [LIST] 
;;;   Typ = Datatype [INT] 
;;;         Constants: 
;;;         - vlax-vbBoolean 
;;;         - vlax-vbDecimal *) 
;;;         - vlax-vbDouble 
;;;         - vlax-vbInteger 
;;;         - vlax-vbLong 
;;;        - vlax-vbObject 
;;;         - vlax-vbSingle 
;;;         - vlax-vbString 
;;;         - vlax-vbVariant 
;;; Return [Typ]: 
;;;   > Array [VARIANT] 
;;; Notes: 
;;;   *)Missing datatype in Visual LISP, initialize it in your Autoloader. 
;;;   - Can't be used for dotted pair or nested lists. 
;;; 
(defun VXLISTTOARRAY (TYP LST) 
  (vlax-make-variant 
    (vlax-safearray-fill 
      (vlax-make-safearray TYP (cons 0 (1- (length LST)))) 
      LST 
    ) 
  ) 
)

秋枫 · 发表于 2003-1-9 09:17:55

黄兄求的是算法啊。数学上的算法。他不是说得很清楚了么。

黄卫文 · 发表于 2003-1-9 14:29:53

谢了谢了，谢谢LUCAS 你有好多好东西嘛：）
下面这个也能得到一个PL的形心点，它也是间接方法：）

(defun pl_cen (poly / pl ms va reg cen)
(setq pl (vlax-ename->vla-object poly)
ms (vla-get-modelspace
(vla-get-activedocument (vlax-get-acad-object))
)
va (vlax-make-safearray vlax-vbObject '(0 . 0))
)
(vlax-safearray-put-element va 0 pl)
(setq reg (car (vlax-safearray->list
(vlax-variant-value (vla-addregion ms va))
)
)
cen (vla-get-centroid reg)
)
(vla-delete reg)
(vlax-safearray->list (vlax-variant-value cen))
)

ll_j · 发表于 2003-1-9 16:27:37

看看这是你要的吗？（详见《实用土木工程手册》）

黄卫文 · 发表于 2003-1-10 09:24:49

最初由 ll_j 发布
[B]看看这是你要的吗？（详见《实用土木工程手册》） [/B]

对我要的就是这个东西！谢谢你，我的没有你那本手册。我那《建筑结构静力计算手册》中没有这个公式。

账号		自动登录	找回密码
密码			立即注册

[求助]：怎样通过几点来通过算法求其形心?

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子