[求助]：怎样一次性选择汉字？

xbx7920 · 发表于 2004-9-20 22:04:44

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

现在图面上有有很多单行文字，如“卧室”，“客厅”
“厨房”，“0.000”，“3.000”，“4.500”等等，现在我想一次
性就选择好那些汉字，能不能用LISP实现这个想法，我
使用的是AUTOCAD R14。在线等。

yi.gao · 发表于 2004-9-20 22:19:32

可以使用对象过滤器，选择文字值=XXX的对象过滤条件，然后应用选择即可。

xbx7920 · 发表于 2004-9-20 22:58:13

yi.gao长老大概没有看清题意。
我是想一次选择所有的中文单行文本，而不需要数字。

yi.gao · 发表于 2004-9-20 23:07:51

都是单行文本对象，区分有一定难度，即便是lsp编程也需要判断ASCII码值然后断定是数字、字母还是其它。可以考虑用对象过滤器中的“或”组合选择，当然中文文本比较多的情况下仍然不是很简便！

柔柔 · 发表于 2004-9-20 23:10:48

编程可以实现，只是这样的程序千年用一次的话，似乎不值得动脑筋，呵呵。。。。：）
*-*7 *-*7 *-*7 *-*7 *-*7 *-*7

xbx7920 · 发表于 2004-9-21 00:00:29

柔兄，这千年用一次的程序恰巧就陪我碰到了，大概明天买彩票一定会中。呵呵
我说一下我的思路:在命令行上输入(atof "卧室")或(atof "客厅")返回的是0.0，而输入
(atof "-0.300")会返回-0.300，那能不能建立一个ATOF后返回的都是0的文字的选择集？
在下抛红砖一块待引玉。

柔柔 · 发表于 2004-9-21 00:13:42

那数字0.0呢？
编程思路是这样的：
把文字全部选到选择集内，然后对每个文字对象进行分析：字符的ASCII码大于127的保留，小于127的继续查下去，直到最后还是小于127，说明它不是中文，就把它请出选择集。

xbx7920 · 发表于 2004-9-21 00:23:53

那接下来，你就露一手吧！呵呵

柔柔 · 发表于 2004-9-21 00:39:32

临时编一个，没测试过，错了不负责。*-*7 *-*7 *-*7

[FONT=courier new]
(defun c:xbx7920 (/ sset ssl nsset elist str asc_a chn n temp)
(setq sset (ssget "X" (list (cons 0 "TEXT")))
ssl (sslength sset)
nsset (ssadd)
)
(while (> ssl 0)
(setq temp (ssname sset (setq ssl (1- ssl))))
(setq elist (entget temp))
(setq str (cdr (assoc 1 elist)) chn nil n 1)
(while (and (/= (substr str n 1) "") (= chn nil))
(setq asc_a (ascii (substr str n 1)))
(if (> asc_a 127)
(progn (setq chn T) (ssadd temp nsset))
(setq n (1+ n))
)
)
)
; nsset就是汉字的选择集，接下来你要干什么？我不知道了，呵呵。。。
) [/FONT]

xbx7920 · 发表于 2004-9-21 00:54:48

柔兄，好象不对哦，我研究研究先。

柔柔 · 发表于 2004-9-21 01:01:39

找到以前一个小程序，可以参考

[FONT=courier new]
;;REMOVEhz.LSP 删除汉字 CYN 2000.4
;;
;; 功能:删除图中的所有汉字
;; 用途:向国外用电子邮件传送图纸
;; 原因:国外没有汉字字体,可能打不开文件
(defun c:removehz(/ chk sset sslen elist str sl n nsl
str1 asc strb stre)
(initget "Yes No")
(setq chk (getkword "\n警告! 你确实想删除图上的所有汉字吗? (Y/N) <N>"))
(if (= chk "Yes")
(progn
(setq sset (ssget "X" (List (cons 0 "*TEXT" )))
sslen (sslength sset)
)
(while (> sslen 0)
(setq ename (ssname sset (setq sslen (1- sslen)))
elist (entget ename)
str (cdr (assoc 1 elist))
sl (strlen str)
n 1
stre str
nsl sl
)
(while (< n nsl)
(setq str1 (substr str n 1)
asc (ascii str1)
)
(if (> asc 127) ;如果是汉字
(setq strb (substr str 1 (- n 1))
stre (substr str (+ n 2))
str (strcat strb stre)
nsl (strlen str)
)
(setq n (1+ n))
)
)
(entmod (append elist (list (cons 1 str))))
)
)
)
(princ)
) [/FONT]

[FONT=courier new] 
;;REMOVEhz.LSP 删除汉字  CYN  2000.4 
;; 
;; 功能:删除图中的所有汉字 
;; 用途:向国外用电子邮件传送图纸 
;; 原因:国外没有汉字字体,可能打不开文件 
 
(defun c:removehz(/ chk sset sslen elist str sl n nsl 
                    str1 asc strb stre) 
  (initget "Yes No") 
  (setq chk (getkword "\n警告! 你确实想删除图上的所有汉字吗? (Y/N) <N>")) 
  (if (= chk "Yes") 
   (progn 
     (setq sset (ssget "X" (List (cons 0 "*TEXT" ))) 
          sslen (sslength sset) 
     ) 
     (while (> sslen 0)    
       (setq ename (ssname sset (setq sslen (1- sslen))) 
             elist (entget ename) 
               str (cdr (assoc 1 elist)) 
                sl (strlen str) 
                 n 1 
              stre str 
               nsl sl 
       ) 
       (while (< n nsl)    
         (setq str1 (substr str n 1) 
                asc (ascii str1) 
         ) 
         (if (> asc 127)  ;如果是汉字 
           (setq strb (substr str 1 (- n 1)) 
                 stre (substr str (+ n 2)) 
                  str (strcat strb stre) 
                  nsl (strlen str) 
           ) 
           (setq n (1+ n)) 
         )    
       )    
       (entmod (append elist (list (cons 1 str)))) 
     ) 
   ) 
  ) 
  (princ) 
)  [/FONT]

Robbie · 发表于 2004-9-21 09:01:06

很厉害。如果文字串中既有中文又有别的，会有问题吗？没有试

aeo · 发表于 2004-9-23 00:46:48

(distof "ABC") -->nil
(distof "123") -->123

选没有数字的文字:
(ssget '((1 . "~*#*")))

xbx7920 · 发表于 2004-9-23 01:03:56

万分感谢aeo斑竹和柔兄的鼎力相助。

梦断江南 · 发表于 2004-9-23 02:56:54

试试这个，一般情况下可用

;;选取不包含字母及数字的字符串.
(ssget '((0 . "TEXT")(-4 . "< AND")(1 . "~*@*")(1 . "~*#*")(-4 . "AND >")))

复制代码

注意，因显示冲突原因，< >与AND之间加了空格，使用时候将< >与AND之间的空格去掉。

账号		自动登录	找回密码
密码			立即注册

[求助]：怎样一次性选择汉字？

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子