[求助]：如何加宽R14下的POLYLINE。

oyxx_1023

我拷贝了一个LWPOLYLINE，拷贝后的实体却是一个POLYLINE，我看了一下，POLYLINE的属性列表没有代表线宽的群码。该怎么给他加宽呢？

xyp1964

[php]批量改POLYLINE、LWPOLYLINE、LINE、ARC的线宽
加载gxk.lsp，运行gxk。
;|
GXK.lsp 改线宽
* C:GXK
-- XYP@bsedi.com
2004.10.21 修改
|;
(prompt "\n\r      加载改线宽程序。")
;-------------------------------------------
;;;主程序

(defun C:GXK (/ ss n-ss n s1)
  (CMDla0)
  (while(not(setq no1 (ureal 1 "" "\n\t线宽" no1))))
  (while(not(setq ss (ssget)))
    (princ"\n\t请选择被改线: "))
  (setq n 0 n-ss (sslength ss))
  (princ"\n\t共有 ")(princ n-ss)(princ " 条线被选择.")
  (prompt"\n\t稍候 ")
  (while (< n n-ss)
    (setq s1 (ssname ss n))
    (if (or
          (equal (cdr (assoc 0 (entget s1))) "POLYLINE")
          (equal (cdr (assoc 0 (entget s1))) "LWPOLYLINE")
          )
      (progn
        (command "pedit" s1 "w" no1 "")
        (princ".")(princ)
        )
      )
    (if (or
          (equal (cdr (assoc 0 (entget s1))) "LINE")
          (equal (cdr (assoc 0 (entget s1))) "ARC")
          )
      (progn
        (command "pedit" s1 "Y" "w" no1 "")
       (princ".")(princ)
      )
     )
    (setq n (1+ n))
    )
  (princ"完毕。")
  (CMDla1)
  )

;;;-------------------------------------------
;;;通用子程序
;;;
(defun CMDLA0 ()
  (setq cmdech (getvar "CMDECHO"))
  (setq oom (getvar "orthomode"))
  (setq osm (getvar "osmode"))
  (SETQ LA (getvar "clayer"))
  (setq rmode (getvar "regenmode"))
  (setq pw (getvar "plinewid"))
  (setvar "regenmode" 0)
  (setvar "CMDECHO" 0)
  (princ)
  )

;;;
(defun CMDLA1 ()
  (setvar "CMDECHO" cmdech)
  (setvar "orthomode" oom)
  (setvar "osmode" osm)
  (setvar "clayer" LA)
  (setvar "regenmode" rmode)
  (setvar "plinewid" pw)
  (princ)
  )

; ----------------------- UREAL --------------------------
;                    数字格式化输入
;;Example:(setq NO1 (ureal 1 "" "\n\t??" no1))  
(defun ureal (bit kwd msg def / inp)
  (if def
    (setq msg (strcat "\n" msg "<" (rtos def 2) ">: ")
          bit (* 2 (fix (/ bit 2)))
    )
    (setq msg (strcat "\n" msg ": "))
  )
  (initget bit kwd)
  (setq inp (getreal msg))
  (if inp inp def)
  )

;;;
(DEFUN PXYP (TXT1)
  (SETQ        TXT1 (STRCAT "\n\r      程序命令: "  TXT1 "      -- xyp@bsedi.com"))
  (PRINC TXT1)
  (Princ)
  );defun

;;;
(pxyp"GXK  (改线宽)")
(princ)
;-------------------------------------------
;;;END[/php]

xxxyzxx

非常实用，谢谢楼主提问及楼上兄弟提供源码，不用下载也可以使用了，高兴：）