[求助]：跪求各位大侠帮帮小弟？？？

dracula63

各位大侠能否帮小弟编一个lisp：
1，可以一下提取n个圆的中心点坐标
2，可以计算这些坐标到一条直线的垂直距离
尽快传给我 不胜感激！！！
顺便问一下选取时只能是方型吗？如何不规则的选取？
再次谢谢大家 辛苦了

ll_j

不知需要什么输出形式，就写到图上吧。
[php]defun mktext (:str :pt10 / :sty)        ;写文字
  (entmake
    (list
      '(0 . "TEXT")
      (cons 1 :str)
      (cons 10 :pt10)
      (cons 11 :pt10)
      (cons 7 (setq :sty (getvar "textstyle")))
      (cons 40 (getvar "textsize"))
      (cons 41 (cdr (assoc 41 (tblsearch "style" :sty))))
      (cons 51 (cdr (assoc 50 (tblsearch "style" :sty))))
      '(71 . 0)
      '(72 . 0)
    )
  )
)

(defun c:test (/ ss li pt10 pt11 ang len i en pt pt1 dis)
  (princ "\n选择需要计算的圆")
  (setq ss (ssget '((0 . "circle"))))
  (if ss
    (setq li (entsel "\n计算目标直线："))
  )
  (if (and ss
           (= (cdr (assoc 0 (setq li (entget (car li))))) "LINE")
      )
    (progn
      (setq pt10 (cdr (assoc 10 li))
            pt11 (cdr (assoc 11 li))
            ang         (angle pt10 pt11)
            len         (sslength ss)
      )
      (setq i -1)
      (repeat len
        (setq i          (1+ i)
              en  (entget (ssname ss i)) ;圆心
              pt  (cdr (assoc 10 en))
              pt1 (inters pt10 pt11 pt (polar pt (+ ang (/ pi 2)) 1) nil)
              dis (distance pt pt1)        ;距离
        )
        (mktext        (strcat        "圆心："
                        (rtos (car pt))
                        ","
                        (rtos (cadr pt))
                        ";距离："
                        (rtos dis)
                )
                pt
        )
      )
    )
  )
  (princ)
)[/php]

另：
多边形选取可以使用“wp”、“cp”选项，栅栏选取可以使用“f”选项。

dracula63

太感谢了

yjtdkj

黄金长老太厉害了，不到一个小时就写好了，无比佩服!!!

xyp1964

试试：
[php]
(defun c:test ()
  (princ "\n选圆 : ")
  (setq        ss (ssget '((0 . "CIRCLE")))
        s2 (entsel "\n选线 : ")
        n  -1
  )
  (setq        pt01 (dxf 10 (entget (car s2)))
        pt02 (dxf 11 (entget (car s2)))
        ang  (+ (angle pt01 pt02) (/ pi 2))
  )
  (while (setq s1 (ssname ss (setq n (+ 1 n))))
    (setq pt1 (dxf 10 (entget s1)))
    (princ "\nR")
    (princ (+ n 1))
    (princ " = ")
    (princ pt1)
    (setq pt2  (polar pt1 ang 100)
          pt3  (inters pt01 pt02 pt1 pt2 nil)
          dist (distance pt1 pt3)
    )
    (grvecs (list 2 pt1 pt3))
    (princ "\n距离")
    (princ (+ n 1))
    (princ " = ")
    (princ dist)
    (princ "\n")
  )
  (princ)
)
(defun dxf (code elist) (cdr (assoc code elist)))
[/php]

sdwy19691229

2 楼太厉害了，不胜佩服。