[讨论]：有没有这样一种程序！

cadtiger

可以将一条直线以a,b两个长度分割,例如
一个十米的线段,将其分割成一段为0.5米,一段为2米,并以此分割循环既是0.5/2/0.5/2/0.5/2/0.5/2

ivysoft

我开发的小工具（常青藤）不知道能不能帮助你
查询菜单下的等分曲线长度，支持不等距划分，但不能将线打断，只能做标记。你或许可以试一试。
具体请查阅帖子：http://www.xdcad.net/forum/showthread.php?s=&threadid=322975

xyp1964

试试：
[php]
;;;分割线
(defun c:test037 ()
  (princ"\n选择线 : ")
  (setq        SS    (ssget '((0 . "LINE")))
        dist1 (udist 1 "" "\n\t线长1" dist1 (list 0 0))
        dist2 (udist 1 "" "\n\t线长2" dist2 (list 0 0))
        i     -1
  )
  (vl-cmdf ".undo" "BE")
  (while (setq s1 (ssname ss (setq i (1+ i))))
    (setq pt1 (dxf 10 (entget s1))
          pt2 (dxf 11 (entget s1))
          ang (angle pt1 pt2)
          n1  (fix (/ (distance pt1 pt2) (+ dist1 dist2)))
    )
    (repeat (fix n1)
      (setq pt2        (polar pt1 ang dist1)
            pt3        (polar pt2 ang dist2)
      )
      (command "line" pt1 pt2 pt3 "")
      (setq pt1 pt3)
    )
    (entdel s1)
  )
  (vl-cmdf ".undo" "E")
  (princ)
)
(defun udist (bit kwd msg def bpt / inp)
  (if def
    (setq msg (strcat "\n" msg "<" (rtos def) ">:")
          bit (* 2 (fix (/ bit 2)))
    )
    (setq msg (strcat "\n" msg ":"))
  )
  (initget bit kwd)
  (setq        inp
         (if bpt
           (getdist msg bpt)
           (getdist msg)
         )
  )
  (if inp
    inp
    def
  )
)
(defun dxf (code elist) (cdr (assoc code elist)))
[/php]