[求助]：“打开文件”对话框

winabcd

在VBA中，如何利用“打开文件”对话框，让用户选择一个文件，并得到文件名。

雪山飞狐(lzh)

用CommonDialog控件或CommonDialog类

winabcd

lzh741206 ，你好，先谢谢你的帮助。
我曾经问过怎样用CommonDialog控件或类的问题，也是你给了我一定的帮助，可我下载的一个CommonDialog类文件，安装后用不起来，不知是我下载的不对，还是安装的不对，又或是使用方法不对。我问CommonDialog控件或类的问题就是为了做一个“打开文件”对话框，还请你能帮忙。
我这里又提出“打开文件”对话框的问题，是因我看到过一个使用获取颜色对话框的例子，例子中用的是“acad.exe”文件中的一个函数，所以我抱着试试看的目的，问了这个问题，如果谁知道“acad.exe”中有这样的函数，请指教。谢谢！

gdzhou

工程,引用..

月后船影

在VBAIDE中，“工具”菜单下的“引用”勾选“Microsoft  common dialog cotrol 6.0”，如果找不到此选项，点击“浏览”就自动打开了“\windows\sysyem32\”文件夹，选择“comdlg32.ocx”就可以添加CommonDialog控件了……
部分代码如下：

winabcd

各位讲的方法我都有试过，可我一加CommandDialog控件就提示：“无法创建控件，因为它未经正确授权”。不知是什么原因。

月后船影

最初由 winabcd 发布
[B]各位讲的方法我都有试过，可我一加CommandDialog控件就提示：“无法创建控件，因为它未经正确授权”。不知是什么原因。 [/B]

那是不是cad或vb软件本身的原因，建议卸载后重装……按我说的方法一定可以的……

ps122

Public Declare Function GetOpenFileName Lib "comdlg32.dll" Alias "GetOpenFileNameA" _
    (pOpenfilename As OPENFILENAME) As Long
Public Const OFN_PATHMUSTEXIST = &H800
Public Const OFN_FILEMUSTEXIST = &H1000
Public Const OFN_HIDEREADONLY = &H4 '隐蔽只读复选框

Public Type OPENFILENAME
    lStructSize As Long
    hwndOwner As Long '拥有对话框的窗口
    hInstance As Long
    lpstrFilter As String '装载文件过滤器的缓冲区
    lpstrCustomFilter As String
    nMaxCustFilter As Long
    nFilterIndex As Long
    lpstrFile As String
    nMaxFile As Long
    lpstrFileTitle As String
    nMaxFileTitle As Long
    lpstrInitialDir As String
    lpstrTitle As String '对话框的标题
    flags As Long
    nFileOffset As Integer
    nFileExtension As Integer
    lpstrDefExt As String
    lCustData As Long
    lpfnHook As Long
    lpTemplateName As String
End Type

Function GetFile(strTitle As String, strFilter As String, Optional strIniDir As String) As String

On Error Resume Next
Dim FileName As String
Dim OFileBox As OPENFILENAME
With OFileBox
    .lpstrTitle = strTitle '对话框标题
    .lpstrInitialDir = strIniDir '初始目录
    .lStructSize = Len(OFileBox)
    .hwndOwner = ThisDrawing.HWND
    .flags = OFN_PATHMUSTEXIST Or OFN_FILEMUSTEXIST Or OFN_HIDEREADONLY
    .lpstrFile = String$(255, 0)
    .nMaxFile = 255
    .lpstrFileTitle = String$(255, 0)
    .nMaxFileTitle = 255
    .lpstrFilter = strFilter  '过滤器
    .nFilterIndex = 1
End With

lntFile = GetOpenFileName(OFileBox) '执行打开对话框
If lntFile <> 0 Then
    FileName = Left(OFileBox.lpstrFile, InStr(OFileBox.lpstrFile, vbNullChar) - 1)
    GetFile = FileName
Else
    GetFile = ""
End If

End Function