[其他]：怎样才能快速的一次完成修剪

SGP007 · 发表于 2005-3-18 11:28:03

最初由 yugarden511 发布
[B]方法一：用lsp程序能做到，不过缺点是要你的机很强才行，我在我的P4 1.8G，512内存机上试过，能用，不过比起一个个剪也快不了多少，因为电脑要判断边界。也许改良一下会好点。
方法二：trim-空格－f-(如图) [/B]

回方法一：能不能把这个LSP发上来，我的机子还算强，2.6G，1024M。
回方法二：如果有100个需要修剪，还是能把人累死，不妥。

qyangxj · 发表于 2005-3-18 12:05:24

谁能具体说说啊

SGP007 · 发表于 2005-3-25 15:22:43

老问题还是没有解决继续顶一下。
最近我又感到一点不如意。我在作图过程中需要很多不同的线型，而且不同线型之间需要不同的线型比例，虽然可以用当前比例因子或者特性进行修改，不免还是麻烦。我想能不能比例因子定义到图层当中呢？免得每次关来关去的选择修改

大江东去 · 发表于 2005-3-25 17:03:17

是啊，老兄，我们也希望能这样一次剪出来啊，呵呵，最好脑袋里想怎么样就能出来。

shiyangaosong · 发表于 2005-3-25 20:25:36

回答1楼：在第一次提示选择时，全部选种，第二次提示选择时，点击你想剪掉的部位；
回答9楼：先把矩形制作成图块，然后用measure命令，选择B选项，输入距离，就可以用矩形定距等分。

zbj19771108 · 发表于 2005-3-25 21:08:55

很好，，很好，，又学了一点，很有价值，改天我也来点，，做点贡献，今天是没时间了

lbq163 · 发表于 2005-3-25 21:48:31

试了多次，还是不行，一个一个剪，如果有好的方法一定要告诉我，谢谢

mmmm · 发表于 2005-3-26 20:17:45

如果你的块仅仅是一个矩形，那简单，在矩形内做个WIPEOUT，再定义成块，曲线根本不用剪切，自动就会被遮挡了。

如果图块内含有复杂实体，编程也能解决。
1：根据图块的外框选定曲线。
2：UNDO-GROUP
3：EXPLODE BLOCK
4：得到块内曲线和选定曲线的所有交点表
5：遍历焦点表，分别找到距离曲线的两个端点最近的角点，
6： UNDO-END/U
7：在两个交点处打断曲线

lbp205 · 发表于 2005-3-26 21:53:27

我也想知道能不能一次修剪好多不需要的线条之类的！

mmmm · 发表于 2005-3-27 11:53:16

发现一个错误，没有交点时会出错。已经改正。

;|
自动将穿过图块的曲线打断 Copyright(C) 1994-2005 KozMos Inc. | All rights reserved
Revision: 2005/03/26[27]
此程序可以编译成ARX后运行在R14.0下，但是由于部分曲线的vlax-intersectwith函数还不成熟，
复杂曲线的交点经常会漏掉。因此有可能会出现不可预计的结果。在2004+没有这个问题。
命令列表
========
BCUTP: 选取图块
BCUTP: 点取图块
注意: 没有设计错误捕捉函数.
|;
(Defun C:BCUTP (/ vllist-divide xsub-block-cut blk osmode pickbox
highlight)
(defun vllist-divide (lst n / element item new)
(foreach element (reverse lst)
(setq item (cons element item))
(if (= (length item) n)
(setq new (cons item new)
item nil
)
)
)
new
)
(Defun xsub-block-cut (block / ll ur ssx ssp
curve kkk mindis maxdis minpt maxpt
i cvv int intx brk idx
dis pick
)
(setq pick (getvar "pickbox"))
(setvar "pickbox" 0)
(vla-getboundingbox (vlax-ename->vla-object Block) 'll 'ur)
(if vlax-safearray->list
(setq ll (vlax-safearray->list ll)
ur (vlax-safearray->list ur)
)
)
(if
(and (setq ll (trans ll 0 1)
ur (trans ur 0 1)
)
(setq
cvv (ssget "_c" ll ur '((0 . "*line,arc,circle,ellipse")))
)
(setq idx -1)
)
(progn
(command "_.Undo" "_Group")
(command "_.Explode" block)
(setq ssx (ssget "_p" '((0 . "*line,arc,circle,ellipse")))
brk nil
i -1
)
(repeat (sslength ssx)
(setq ssp
(cons (vlax-ename->vla-object (ssname ssx (setq i (1+ i))))
ssp
)
)
)
(repeat (sslength cvv)
(setq curve (vlax-ename->vla-object
(ssname cvv (setq idx (1+ idx)))
)
kkk nil
)
(foreach ssx ssp
(if
(and (setq int (vla-intersectwith curve ssx acextendnone))
vlax-safearray-get-u-bound
(setq int (vlax-variant-value int))
(> (vlax-safearray-get-u-bound int 1) 0)
)
(setq int (vlax-safearray->list int))
(setq int nil)
)
(if (> (length int) 3)
(setq intx (vllist-divide int 3))
(setq intx (list int))
)
(foreach int intx
(if (and int
(null (member int kkk))
)
(setq kkk (cons int kkk))
)
)
)
(setq brk (cons (cons curve kkk) brk))
)
(command "_.Undo" "_End")
(command "_U")
(foreach kkk brk
(setq curve (car kkk)
kkk (cdr kkk)
)
(cond ((= (length kkk) 1)
(princ)
)
((= (length kkk) 2)
(setq minpt (car kkk)
maxpt (cadr kkk)
)
)
(t
(foreach ssx kkk
(setq dis (vlax-curve-getDistAtPoint curve ssx))
(if (or (null mindis)
(< dis mindis)
)
(setq mindis dis
minpt ssx
)
)
(if (or (null maxdis)
(> dis maxdis)
)
(setq maxdis dis
maxpt ssx
)
)
)
)
)
(if (and minpt maxpt)
(command "_.break"
(list (setq curve (vlax-vla-object->ename curve))
(trans minpt 0 1)
)
(trans maxpt 0 1)
)
)
)
)
)
(setvar "pickbox" pick)
)
(command "_.Undo" "_Group")
(setq osmode (getvar "osmode")
pickbox (getvar "pickbox")
highlight (getvar "highlight")
)
(setvar "osmode" 0)
(setvar "pickbox" 5)
(setvar "highlight" 1)
(while (and (setq blk (entsel "\n剪除穿过图块的曲线, 请点取图块 <退出>:"))
(setq blk (car blk))
(= (cdr (assoc 0 (entget blk))) "INSERT")
(/= (substr (cdr (assoc 2 (entget blk))) 1 1) "*")
)
(xsub-block-cut blk)
)
(setvar "osmode" osmode)
(setvar "pickbox" pickbox)
(setvar "highlight" highlight)
(command "_.Undo" "_End")
(princ)
)
(Defun C:BCUTS (/ vllist-divide xsub-block-cut
sss iii blk osmode
pickbox highlight
)
(defun vllist-divide (lst n / element item new)
(foreach element (reverse lst)
(setq item (cons element item))
(if (= (length item) n)
(setq new (cons item new)
item nil
)
)
)
new
)
(Defun xsub-block-cut (block / ll ur ssx ssp
curve kkk mindis maxdis minpt maxpt
i cvv int intx brk idx
dis pick
)
(setq pick (getvar "pickbox"))
(setvar "pickbox" 0)
(vla-getboundingbox (vlax-ename->vla-object Block) 'll 'ur)
(if vlax-safearray->list
(setq ll (vlax-safearray->list ll)
ur (vlax-safearray->list ur)
)
)
(if
(and (setq ll (trans ll 0 1)
ur (trans ur 0 1)
)
(setq
cvv (ssget "_c" ll ur '((0 . "*line,arc,circle,ellipse")))
)
(setq idx -1)
)
(progn
(command "_.Undo" "_Group")
(command "_.Explode" block)
(setq ssx (ssget "_p" '((0 . "*line,arc,circle,ellipse")))
brk nil
i -1
)
(repeat (sslength ssx)
(setq ssp
(cons (vlax-ename->vla-object (ssname ssx (setq i (1+ i))))
ssp
)
)
)
(repeat (sslength cvv)
(setq curve (vlax-ename->vla-object
(ssname cvv (setq idx (1+ idx)))
)
kkk nil
)
(foreach ssx ssp
(if
(and (setq int (vla-intersectwith curve ssx acextendnone))
vlax-safearray-get-u-bound
(setq int (vlax-variant-value int))
(> (vlax-safearray-get-u-bound int 1) 0)
)
(setq int (vlax-safearray->list int))
(setq int nil)
)
(if (> (length int) 3)
(setq intx (vllist-divide int 3))
(setq intx (list int))
)
(foreach int intx
(if (and int
(null (member int kkk))
)
(setq kkk (cons int kkk))
)
)
)
(setq brk (cons (cons curve kkk) brk))
)
(command "_.Undo" "_End")
(command "_U")
(foreach kkk brk
(setq curve (car kkk)
kkk (cdr kkk)
)
(cond ((= (length kkk) 1)
(princ)
)
((= (length kkk) 2)
(setq minpt (car kkk)
maxpt (cadr kkk)
)
)
(t
(foreach ssx kkk
(setq dis (vlax-curve-getDistAtPoint curve ssx))
(if (or (null mindis)
(< dis mindis)
)
(setq mindis dis
minpt ssx
)
)
(if (or (null maxdis)
(> dis maxdis)
)
(setq maxdis dis
maxpt ssx
)
)
)
)
)
(if (and minpt maxpt)
(command "_.break"
(list (setq curve (vlax-vla-object->ename curve))
(trans minpt 0 1)
)
(trans maxpt 0 1)
)
)
)
)
)
(setvar "pickbox" pick)
)
(command "_.Undo" "_Group")
(setq osmode (getvar "osmode")
pickbox (getvar "pickbox")
highlight (getvar "highlight")
)
(setvar "osmode" 0)
(setvar "pickbox" 5)
(setvar "highlight" 1)
(if (and (princ "\n剪除穿过图块的曲线, 请选取图块 <退出>:")
(setq sss (ssget '((0 . "insert"))))
(setq iii -1)
)
(repeat (sslength sss)
(setq blk (ssname sss (setq iii (1+ iii))))
(if (/= (substr (cdr (assoc 2 (entget blk))) 1 1) "*")
(xsub-block-cut blk)
)
)
)
(setvar "osmode" osmode)
(setvar "pickbox" pickbox)
(setvar "highlight" highlight)
(command "_.Undo" "_End")
(princ)
)

;| 
自动将穿过图块的曲线打断 Copyright(C) 1994-2005 KozMos Inc. | All rights reserved 
Revision: 2005/03/26[27] 
 
此程序可以编译成ARX后运行在R14.0下，但是由于部分曲线的vlax-intersectwith函数还不成熟， 
复杂曲线的交点经常会漏掉。因此有可能会出现不可预计的结果。在2004+没有这个问题。 
 
命令列表 
======== 
BCUTP: 选取图块 
BCUTP: 点取图块 
 
注意: 没有设计错误捕捉函数. 
|; 
(Defun C:BCUTP (/ vllist-divide        xsub-block-cut blk osmode pickbox 
                highlight) 
  (defun vllist-divide (lst n / element item new) 
    (foreach element (reverse lst) 
      (setq item (cons element item)) 
      (if (= (length item) n) 
        (setq new  (cons item new) 
              item nil 
        ) 
      ) 
    ) 
    new 
  ) 
  (Defun xsub-block-cut        (block        /      ll     ur     ssx    ssp 
                         curve        kkk    mindis maxdis minpt  maxpt 
                         i        cvv    int    intx   brk    idx 
                         dis        pick 
                        ) 
    (setq pick (getvar "pickbox")) 
    (setvar "pickbox" 0) 
    (vla-getboundingbox (vlax-ename->vla-object Block) 'll 'ur) 
    (if        vlax-safearray->list 
      (setq ll (vlax-safearray->list ll) 
            ur (vlax-safearray->list ur) 
      ) 
    ) 
    (if 
      (and (setq ll (trans ll 0 1) 
                 ur (trans ur 0 1) 
           ) 
           (setq 
             cvv (ssget "_c" ll ur '((0 . "*line,arc,circle,ellipse"))) 
           ) 
           (setq idx -1) 
      ) 
       (progn 
         (command "_.Undo" "_Group") 
         (command "_.Explode" block) 
         (setq ssx (ssget "_p" '((0 . "*line,arc,circle,ellipse"))) 
               brk nil 
               i   -1 
         ) 
         (repeat (sslength ssx) 
           (setq ssp 
                  (cons        (vlax-ename->vla-object (ssname ssx (setq i (1+ i)))) 
                        ssp 
                  ) 
           ) 
         ) 
         (repeat (sslength cvv) 
           (setq curve (vlax-ename->vla-object 
                         (ssname cvv (setq idx (1+ idx))) 
                       ) 
                 kkk   nil 
           ) 
           (foreach ssx        ssp 
             (if 
               (and (setq int (vla-intersectwith curve ssx acextendnone)) 
                    vlax-safearray-get-u-bound 
                    (setq int (vlax-variant-value int)) 
                    (> (vlax-safearray-get-u-bound int 1) 0) 
               ) 
                (setq int (vlax-safearray->list int)) 
                (setq int nil) 
             ) 
             (if (> (length int) 3) 
               (setq intx (vllist-divide int 3)) 
               (setq intx (list int)) 
             ) 
             (foreach int intx 
               (if (and        int 
                        (null (member int kkk)) 
                   ) 
                 (setq kkk (cons int kkk)) 
               ) 
             ) 
           ) 
           (setq brk (cons (cons curve kkk) brk)) 
         ) 
         (command "_.Undo" "_End") 
         (command "_U") 
         (foreach kkk brk 
           (setq curve (car kkk) 
                 kkk   (cdr kkk) 
           ) 
           (cond ((= (length kkk) 1) 
                  (princ) 
                 ) 
                 ((= (length kkk) 2) 
                  (setq        minpt (car kkk) 
                        maxpt (cadr kkk) 
                  ) 
                 ) 
                 (t 
                  (foreach ssx kkk 
                    (setq dis (vlax-curve-getDistAtPoint curve ssx)) 
                    (if        (or (null mindis) 
                            (< dis mindis) 
                        ) 
                      (setq mindis dis 
                            minpt ssx 
                      ) 
                    ) 
                    (if        (or (null maxdis) 
                            (> dis maxdis) 
                        ) 
                      (setq maxdis dis 
                            maxpt ssx 
                      ) 
                    ) 
                  ) 
                 ) 
           ) 
           (if (and minpt maxpt) 
             (command "_.break" 
                      (list (setq curve (vlax-vla-object->ename curve)) 
                            (trans minpt 0 1) 
                      ) 
                      (trans maxpt 0 1) 
             ) 
           ) 
         ) 
       ) 
    ) 
    (setvar "pickbox" pick) 
  ) 
  (command "_.Undo" "_Group") 
  (setq        osmode          (getvar "osmode") 
        pickbox          (getvar "pickbox") 
        highlight (getvar "highlight") 
  ) 
  (setvar "osmode" 0) 
  (setvar "pickbox" 5) 
  (setvar "highlight" 1) 
  (while (and (setq blk (entsel "\n剪除穿过图块的曲线, 请点取图块 <退出>:")) 
              (setq blk (car blk)) 
              (= (cdr (assoc 0 (entget blk))) "INSERT") 
              (/= (substr (cdr (assoc 2 (entget blk))) 1 1) "*") 
         ) 
    (xsub-block-cut blk) 
  ) 
  (setvar "osmode" osmode) 
  (setvar "pickbox" pickbox) 
  (setvar "highlight" highlight) 
  (command "_.Undo" "_End") 
  (princ) 
) 
(Defun C:BCUTS (/             vllist-divide               xsub-block-cut 
                sss             iii          blk               osmode 
                pickbox             highlight 
               ) 
  (defun vllist-divide (lst n / element item new) 
    (foreach element (reverse lst) 
      (setq item (cons element item)) 
      (if (= (length item) n) 
        (setq new  (cons item new) 
              item nil 
        ) 
      ) 
    ) 
    new 
  ) 
  (Defun xsub-block-cut        (block        /      ll     ur     ssx    ssp 
                         curve        kkk    mindis maxdis minpt  maxpt 
                         i        cvv    int    intx   brk    idx 
                         dis        pick 
                        ) 
    (setq pick (getvar "pickbox")) 
    (setvar "pickbox" 0) 
    (vla-getboundingbox (vlax-ename->vla-object Block) 'll 'ur) 
    (if        vlax-safearray->list 
      (setq ll (vlax-safearray->list ll) 
            ur (vlax-safearray->list ur) 
      ) 
    ) 
    (if 
      (and (setq ll (trans ll 0 1) 
                 ur (trans ur 0 1) 
           ) 
           (setq 
             cvv (ssget "_c" ll ur '((0 . "*line,arc,circle,ellipse"))) 
           ) 
           (setq idx -1) 
      ) 
       (progn 
         (command "_.Undo" "_Group") 
         (command "_.Explode" block) 
         (setq ssx (ssget "_p" '((0 . "*line,arc,circle,ellipse"))) 
               brk nil 
               i   -1 
         ) 
         (repeat (sslength ssx) 
           (setq ssp 
                  (cons        (vlax-ename->vla-object (ssname ssx (setq i (1+ i)))) 
                        ssp 
                  ) 
           ) 
         ) 
         (repeat (sslength cvv) 
           (setq curve (vlax-ename->vla-object 
                         (ssname cvv (setq idx (1+ idx))) 
                       ) 
                 kkk   nil 
           ) 
           (foreach ssx        ssp 
             (if 
               (and (setq int (vla-intersectwith curve ssx acextendnone)) 
                    vlax-safearray-get-u-bound 
                    (setq int (vlax-variant-value int)) 
                    (> (vlax-safearray-get-u-bound int 1) 0) 
               ) 
                (setq int (vlax-safearray->list int)) 
                (setq int nil) 
             ) 
             (if (> (length int) 3) 
               (setq intx (vllist-divide int 3)) 
               (setq intx (list int)) 
             ) 
             (foreach int intx 
               (if (and        int 
                        (null (member int kkk)) 
                   ) 
                 (setq kkk (cons int kkk)) 
               ) 
             ) 
           ) 
           (setq brk (cons (cons curve kkk) brk)) 
         ) 
         (command "_.Undo" "_End") 
         (command "_U") 
         (foreach kkk brk 
           (setq curve (car kkk) 
                 kkk   (cdr kkk) 
           ) 
           (cond ((= (length kkk) 1) 
                  (princ) 
                 ) 
                 ((= (length kkk) 2) 
                  (setq        minpt (car kkk) 
                        maxpt (cadr kkk) 
                  ) 
                 ) 
                 (t 
                  (foreach ssx kkk 
                    (setq dis (vlax-curve-getDistAtPoint curve ssx)) 
                    (if        (or (null mindis) 
                            (< dis mindis) 
                        ) 
                      (setq mindis dis 
                            minpt ssx 
                      ) 
                    ) 
                    (if        (or (null maxdis) 
                            (> dis maxdis) 
                        ) 
                      (setq maxdis dis 
                            maxpt ssx 
                      ) 
                    ) 
                  ) 
                 ) 
           ) 
           (if (and minpt maxpt) 
             (command "_.break" 
                      (list (setq curve (vlax-vla-object->ename curve)) 
                            (trans minpt 0 1) 
                      ) 
                      (trans maxpt 0 1) 
             ) 
           ) 
         ) 
       ) 
    ) 
    (setvar "pickbox" pick) 
  ) 
  (command "_.Undo" "_Group") 
  (setq        osmode          (getvar "osmode") 
        pickbox          (getvar "pickbox") 
        highlight (getvar "highlight") 
  ) 
  (setvar "osmode" 0) 
  (setvar "pickbox" 5) 
  (setvar "highlight" 1) 
  (if (and (princ "\n剪除穿过图块的曲线, 请选取图块 <退出>:") 
           (setq sss (ssget '((0 . "insert")))) 
           (setq iii -1) 
      ) 
    (repeat (sslength sss) 
      (setq blk (ssname sss (setq iii (1+ iii)))) 
      (if (/= (substr (cdr (assoc 2 (entget blk))) 1 1) "*") 
        (xsub-block-cut blk) 
      ) 
    ) 
  ) 
  (setvar "osmode" osmode) 
  (setvar "pickbox" pickbox) 
  (setvar "highlight" highlight) 
  (command "_.Undo" "_End") 
  (princ) 
)

dghgvjje · 发表于 2005-3-27 12:25:50

对啊，这个问题用遮挡命令应该可以实现的哦！！！

可以试试看的嘛！！！

yaopx0782 · 发表于 2005-3-27 13:30:28

只能编程实现。用LISP可以做一个小程序，只是你这样的情况多的话才合算。

mmmm · 发表于 2005-3-27 13:31:42

BCUTS 演示

lbp205 · 发表于 2005-4-9 14:49:02

我记得好像这样也可以完成“一次完成修剪”：
“tr“命令，后“f”，在就可以像划出一道线条对你要修剪得图形、线条进行修剪。

lh322 · 发表于 2005-4-9 15:15:12

按Ｆ键，可以一起修剪

账号		自动登录	找回密码
密码			立即注册